10. 視窗通用型控制項：第一部份
視窗通用控制項首見於Windows 95。最初這些控制項包含TreeView、ListView、ImageList、Toolbar、StatusBar、TabStrip以及Slider控制項。Visual Basic 4-第一個32位元版本的程式語言-提供以能存取資料的OLE Custom Control（OCX）為一大特色。隨著第一版的發行，微軟開始大量生產幾個新的、擁有更強大功能的通用控制項在原始的版本中。但是OCX隨著Visual Basic 5的到來（和它本身的三個service packs）已經不再做重大的改良了，這表示使用Visual Basic的程式設計師無法使用更新的控制項在他們的應用程式上（新的Animation和UpDown控制項例外）。直到最近，如果要使用較新的控制項或充分地運用原始控制項的能力，Visual Basic的程式開發者必須依靠協力廠商開發的ActiveX控制項或使用複雜的API程式。
Visual Basic 6已經補救了這個問題，它提供了您所需要的工具，以便運用所有現成控制項的功能。少數的視窗通用控制項仍然缺少新版的OCX檔案（尤其是IP位址控制項），但是在絕大多數的情況下，您不需購買任何額外的自訂控制項，就能建立現代化的使用者介面。
大部分的視窗控制項包含於MsComCtl.ocx檔案，這個檔案包含所有原來的通用控制項，再加上ImageCombo控制項。另外一個MsComCt2.ocx檔案，包含另外五個額外控制項：Animation、UpDown、MonthView、DateTimePicker和FlatScrollBar。這兩個檔案分別為Visual Basic 5中的ComCtl32.ocx和ComCt232.ocx檔案的更新版本。Visual Basic 6不會取代舊版的OCX檔案，而且還可以和平的與Visual Basic 5共存，並且相容於用該版所開發的應用程式。
Visual Basic 6也包含支援另一個通用控制項（ CoolBar控制項 ，會在第十一章介紹）OCX檔案䊼omCt332.ocx。以前程式開發人員必須從微軟的網站去下載它，但是這個檔案目前已經包含在Visual Basic套裝軟體中了。
Visual Basic 6中的OCX檔案有一個很有趣的特色。較舊的ComCtl32.ocx和ComCt232.ocx檔案通常充當Visual Basic和包含實際運作的控制項程式碼的系統DLL檔之間的媒介，但新版則具備獨自性，並且包含操作控制項必要的程式碼。毋庸置疑的，新版的檔案較原先的為大－MsComCtl.ocx超過1MB大小－但是這樣會簡化Visual Basic應用程式散播的複雜性並且跟其他安裝在使用者電腦上的程式衝突較小。
本章說明了所有包含在MsComCtr.ocx的視窗控制項的特色，下一章將涵蓋MsComCt2.ocx和ComCt232.ocx內的所有控制項。為了測試目前的程式碼，首先必須使控制項能夠出現Visual Basic環境。為了達成這個目的，先從專案選單中執行 設定引用元件 指令（或按下Ctrl+T組合鍵），顯現 設定引用元件 對話方塊，如圖10-1所示，然後選取您要的OCX相關選項，如圖10-2所示。
當您進入Visual Basic 6環境，若您的專案是由先前版本的程式所建立、且包含舊版的視窗控制項，將會彈出一個訊息方塊詢問您是否要更新為較新版的控制項，為了使現存的應用程式達到最大的相容性，可以決定繼續使用舊版的控制項，您可以在 專案屬性 的對話方塊中的 一般 頁籤上取消這個升級ActiveX控制項的警告訊息。
| 圖10-1 設定引用元件對話方塊，包含所有的視窗控制元件OCX選項。 |
| 圖10-2 工具列中的通用控制項。 |
ImageList控制項
ImageList控制項最大的用途是做為圖庫，收納被其他控制項（例如TreeView、ListView、TabStrip、ImageCombo等）所使用的影像與圖示。也因為如此，在介紹其他控制項之前，得先探討這個控制項。ImageList控制項在執行階段是看不見的，且為了顯示其所包含的任一張影像，您需要將之描繪於Form、PictureBox控制項或Image控制項上、或甚至將之與其他控制項產生關聯。
使用ImageList控制項作為其他控制項的影像集合有許多好處。事實上，假若不使用這個控制項的話，則需要在執行階段透過LoadPicture函數將所需要的影像自磁碟中載入，如此一來，將使表單載入的時間變慢。在設計時期便將所有需要的影像載入ImageList控制項，並將之指派給其他控制項或運用於程式等都是更簡單且有效率的。
增加圖像
ImageList控制項提供了ListImages集合物件，而此集合物件包含許多ListImage物件，每一個ListImage項目各有其獨立的影像。與其他集合物件相同，每個獨立的ListImage物件皆可由索引或索引鍵（假若有的話）來表示，其中索引為數字形態、索引鍵則為字串形態。每個ListImage物件可有一個影像，其格式可為下列之一：點陣圖（.bmp）、圖示(.ico)、游標(.cur)、JPEG(.jpg)、GIF(.gif)。Visual Basic 5中的ImageList控制項中並未提供最後兩種格式。
於設計階段加入影像
於設計階段加入影像是件很容易的事。把ImageList控制項放置於表單，然後在控制項上按下滑鼠右鍵，並在快捷選單中選取 屬性 選項，接著切換到 影像 頁籤，如圖10-3所示。然後只需要按下 插入圖片 按鈕，並自磁碟中挑選您要的影像即可。不過，應該要為每個影像取個索引鍵值，如此一來，往後便能正確地指定某個影像。因為可能在未來會增加或減少影像，這可是會影響到每個影像的索引值的。當然，這些索引鍵值是不可重複的。如果影像需要有文字的描述或包含其他資訊的話，可以將這些文字指派給影像的Tag屬性。Visual Basic不會直接使用Tag屬性，因此可以放心地存放任何文字資料。
| 圖10-3 ImageList控制項屬性頁的圖片頁籤 。 |
加入ListImages集合物件的影像可以是任意大小的。如果不使用其他通用控制項中的圖像，第一張之後的所有圖像將被延展為第一章圖像的大小。如果要顯現表單上（如PictureBox或Image控制項等）的圖像，將不會有這種問題。
如果ImageList控制項不包含任何影像的話，您可以在 屬性 對話視窗中的 一般 頁籤中設定影像的大小。假若在控制項已包含一張以上的影像時，進行上述的動作是會造成錯誤的。
於執行階段加入影像
於執行階段加入影像必須透過ListImages集合物件的Add方法，語法如下：
Add([Index], [Key], [Picture]) As ListImage
如果省略Index參數時，則影像會加在集合物件的最後。下列程式將建立一個新的ListImage項目並包含一張自磁碟中載入的點陣圖：
Dim li As ListImage
Set li = ImageList1.ListImages.Add(, "Cut", _
LoadPicture("d:\bitmaps\cut.bmp"))
除非有需要在剛剛建立之物件的Tag屬性中存放文字，否則並不需要將Add方法所傳回的值指派給一個ListImage物件。甚至，也不需要ListImage物件就能設定影像的Tag屬性，請見下例：
With ImageList1.ListImages.Add(, "Cut", LoadPicture("d:\bitmaps\cut.bmp"))
.Tag = "The Cut icon"
End With
要刪除一個ListImage物件（包含在設計或執行階段所加入），可透過ListImages集合物件的Remove方法。
' You can use a numerical index or a string key ' to remove the associated image. ImageList1.ListImages.Remove "Cut"
您也可藉由集合物件的Clear方法一次移除所有的影像：
' Remove all images. ImageList1.ListImages.Clear
透過ImageList的ImageWidth與ImageHeight屬性，可以得知存放於控制項中的影像大小。這兩種屬性的單位為Pixel，且只有當ListImages集合物件是空集合時方能改變其值，一旦增加影像後，就成了唯讀屬性。
擷取與顯示影像
假若把ImageList控制項連結至其他通用控制項時，通常無須考慮如何顯示影像的問題，因為程式會自動地進行這些工作。但若要手動地顯示這些影像的話，就必須了解一些關於ImageList控制項與ListImage物件的屬性與方法。
擷取影像
每個ListImage物件皆有個Picture屬性，這個屬性指出屬於ListImage物件的圖形，因此常可將此屬性值指派給PictureBox或Image等控制項，例如：
Set Picture1.Picture = ImageList1.ListImages("Cut").Picture
通常，當要使用PictureBox或Image控制項的Picture屬性時，也可以改用ListImage物件的Picture屬性，例如下例：
' Save an image to a disk file.
SavePicture ImageList1.ListImages("Cut").Picture, "C:\cut.bmp"
' Display an image on the current form, zooming it by a factor
' of 4 along the X-axis, and 8 along the Y-axis.
With ImageList1
PaintPicture .ListImages("Cut").Picture, 0, 0, _
ScaleX(.ImageWidth, vbPixels) * 4, ScaleY(.ImageHeight, vbPixels) * 8
End With
透過PaintPicture方法，可在表單或PictureBox控制項上顯示ListImage物件，也可以輸出到Printer物件上列印出來。關於PaintPicture方法的詳細說明，請參閱
第二章 。ListImage物件也包含ExtractIcon方法，這個方法可以產生一個對應其影像的圖示，並將此圖示傳回給呼叫者。因此當需要圖示時，可以使用此方法，例如：
Form1.MouseIcon = ImageList1.ListImages("Pointer").ExtractIcon
與其他標準集合物件不同的是，ListImages集合物件中的索引鍵值是有分大小寫的，意思是說，「Pointer」與「pointer」是全然不同的。
產生透明影像
ImageList控制項還有個MaskColor屬性，用來決定何種顏色要作為遮罩。其預設值為灰色（&HC0C0C0），不過您可以透過兩種方式改變它：於設計階段在 屬性 對話方塊的 色彩 頁籤可改變其值，或在執行階段透過程式來改變。
不過，若要使用遮罩來進行繪圖動作時，還得確定UseMarkColor屬性值為True（這也是預設值）才行。藉由屬性對話方塊的 一般 頁籤或程式碼可以改變之：
' Make white the transparent color. ImageList1.MaskColor = vbWhite ImageList1.UseMaskColor = True
使用Draw方法
ListImage物件提供Draw方法來繪圖，其語法如下：
Draw hDC, [x], [y], [Style]
其中，hDC為表單、PictureBox控制項或Printer物件的裝置代號，而x與y是影像位在目標物的座標（單位為pixel），style值可能為：0-imlNormal（預設值，在不改變影像的情況下顯示原圖）；1-imlTransparent（使用MaskColor屬性來進行遮罩作用）；2-imlSelected（使用系統高亮度色彩來顯示該圖）；3-imlFocus（與imlSelected相同，但會產生邊框效果表示該圖被選取），舉例如下：
' Show an image in the upper left corner of a PictureBox control.
ImageList1.ListImages("Cut").Draw Picture1.hDC, 0, 0
建立組合影像
ImageList控制項還可以將兩幅獨立的影像（已存在於各自的ListImage物件中）組合成一幅新的組合圖。建立組合圖的方法為Overlay。圖10-4顯示兩幅獨立的影像，而後將之組合成新的影像：
PaintPicture ImageList1.ListImages(1).Picture, 0, 10, 64, 64 PaintPicture ImageList1.ListImages(2).Picture, 100, 10, 64, 64 PaintPicture ImageList1.Overlay(1, 2), 200, 10, 64, 64
| 圖10-4 使用Overlay產生的效果 |
Overlay方法作用時可使用MarkColor屬性來作為影像組合時的遮罩，因此您必須確定UseMarkColor屬性值為True。
TreeView控制項
TreeView控制項可能是使用者熟悉的一個視窗通用控制項，因為在檔案總管中就可見到。基本上，TreeView控制項可表達資料項目的階層性。每個項目旁的加號表示其底下有一個以上的子項目。有子項目的資料項可被展開來顯示所有子資料項，亦可收起以便隱藏之。使用者可交替地進行這樣的行為，或透過程式亦可。
Visual Basic 6所附的TreeView控制項相較於舊版而言有許多的改進，且在每個項目旁提供核選方塊並可選取整列。甚至於每個Node的粗體、前景色、背景色等可有不同的設定。
TreeView控制項包含一個Node集合物件，其包含所有在此控制項內的Node物件。每個獨立的Node物件尚包含許多用來決定控制項外觀的屬性。一般而言，TreeView控制項有一個單一的根Node物件，但也可以建立多個根Node物件。
設定設計階段屬性
在表單上放置TreeView控制項之後，按下滑鼠右鍵並選取 屬性 選項會出現 屬性頁 （如圖10-5所示）。當然也可以於執行時再設定相關的屬性，然而這種情況是不多見的。
Style屬性影響控制項的圖形表示元素。TreeView控制項可以顯示四種圖形表示元素：每個Node物件的文字、顯示圖片、在Node物件旁的加號或減號（用來表示節點是展開或收起狀態），還有Node物件與其子物件間的連結線。Style屬性值共有八個，每個值表示上述圖示所表示元素的各類組合。絕大部份是採用預設值（7-tvwTreelinesPlusMinusPictureText）來表示所有的圖形表示元素。
| 圖10-5 TreeView控制項屬性頁的一般頁籤 |
LineStyle屬性表示連結線的顯示樣式。0-tvwTreeLines值（預設值）表示在根Node物件間不顯示連結線，而1-tvwRootLines值則顯示根節點之間的線，以及同層節點和它們的父節點之間的線。Indentation屬性表示節點間距，單位為pixel。
LabelEdit屬性表示使用者可否修改節點的顯示文字。如果其值為0-tvwAutomatic（預設值），則使用者於執行時可選取節點後再點選之來修改其顯示文字；如果其值為1-tvwManual，那若要修改節點文字，必須藉由程式碼中的StartLabelEdit方法才行。
ImageList下拉選單用來選擇節點影像位在哪個ImageList控制項內。下拉選單會列出在此表單上的所有ImageList控制項。
小秘訣
除了在設計階段便指定好TreeView控制項（或其他控制項）的ImageList屬性外，也可於執行時進行設定，程式如下：
Private Sub Form_Load()
Set TreeView1.ImageList = AnotherForm.ImageList1
End Sub
藉由這個技巧，您便無須在每個表單上皆放置ImageList控制項，只需將所有需要的影像存放於一個ImageList控制項，並放置於一個表單即可。如此一來，可減小執行檔的大小也節省執行時所需的記憶體與資源。
HideSelectio屬性決定當TreeView控制項失去焦點時，是否被選取的節點仍是高亮度的。PathSeparator屬性表示哪個字元或字串要被使用在FullPath屬性。預設的屬性值為「\」字元。例如，若有個根節點顯示為「Root」與其子節點顯示為「FirstChild」，則其子節點的FullPath屬性值則為「Root\FirstChild」。
Sorted屬性表示控制項內的節點是否要自動地以字母順序來排序。說明手冊中遺漏了一個重要說明：這個屬性僅影響根節點的排序，而不會影響次一層子節點的排序。如果您要所有的分枝皆是已排序的，必須設定每個節點的Sorted屬性為True。
Visual Basic 6所附的TreeView控制項增加了幾個有趣的屬性。FullRowSelect屬性值若為True，表示只要點選節點該列的任意位置便可選取該節點。其預設值為False，表示只有點選該節點或其加減號時才能選取之。
如果CheckBoxes屬性為True，在每個節點旁會出現一個核選方塊，使用者可以藉此選擇多個節點。
在預設情況下，您需要雙擊節點方能展開或收起此項目（或點選加減號），且每個節點的展開或收起皆是互不相影響的。然而若將SingleSel屬性設定為True時，控制項的行為就有了變化：若要展開或收起節點，只需點選之即可。此外，一旦展開某個節點，則其他節點將會全數收起。
Scroll屬性決定TreeView控制項是否要顯示垂直或水平捲軸。預設值為True，但可以將之設定為False以便取消捲軸的顯示（然而筆者找不出任何需要取消的理由）。
最後，HotTracking屬性可建立類似Web的外觀。若設定此屬性為True，當滑鼠移到節點上方時，滑鼠圖示會變成手狀且節點文字會出現底線。
執行階段的運作
為了要完全掌控TreeView控制項，還必須學會Nodes集合物件與Node物件的屬性與方法。
增加Node物件
TreeView控制項有個缺點就是不能像ListBox與ComboBox控制項一樣於設計階段增加資料項目。僅能在執行階段藉由Nodes集合物件的Add方法增加資料項。Add方法的語法如下：
Add([Relative],[Relationship],[Key],[Text],[Image],[SelectedImage]) As Node
Relative與Relationship表示新增加的節點位置。索引鍵為此新Node在Nodes集合物件的字串表示式，Text為顯示於其上的文字，而Image表示顯示於節點旁的影像在關聯的ImageList控制項中的索引。SelectedImage表示當節點被選取時的影像在關聯的ImageList控制項中的索引。例如，若要用TreeView建立如同檔案總管中的目錄結構時，類似的程式碼如下：
Dim nd As Node Set nd = Add(, , ,"C:\System", "Folder", "OpenFolder")
為了安置這個新的Node在整個Tree裡面指定的位置上，必須在前面提供兩個參數。第一個參數明確的指出有個經由數值索引或其字串表示式證實確定存在一個項目在Nodes集合中；第二個參數說明Node和其他相似Node之間的關係。如此的關係可以是新的Node變成其他相似Node的第一個項目0-tvwFirst－換句話說，它變成其相似Node中的第一個。或者這個關係也可以是1-tvwLast（這個新的Node變成其他相似Node的最後一個）；而2-tvwNext（預設值，新的Node會直接附加在同樣層級上的下一個相似Node上）；3-tvwPrevious新的Node將插入至同樣層級的相似Node前面）；或者最後一個4-tvwChild（這個新的Node將變成其相似Node的下屬，而且會排在其他下屬之後）。
這裡有一個合理的、擁有一個MDB檔案結構的TreeView控制項例子－由此可看出它所含有的資料表與各資料表的欄位。這個副程式的第二個參數可接受TreeView控制項，藉此可以容易地在應用程式中重複利用。第三個參數表示是否要顯示系統資料表：
Sub ShowDatabaseStructure(MdbFile As String, TV As TreeView, _
ShowSystemTables As Boolean)
Dim db As DAO.Database, td As DAO.TableDef, fld As DAO.Field
Dim nd As Node, nd2 As Node
' Clear the current contents of the TreeView control.
TV.Nodes.Clear
' Open the database.
Set db = DBEngine.OpenDatabase(MdbFile)
' Add the root Node, and then expand it to show the tables.
Set nd = TV.Nodes.Add(, , "Root", db.Name, "Database")
nd.Expanded = True
' Explore all the tables in the database.
For Each td In db.TableDefs
' Discard system tables if user isn't interested in them.
If (td.Attributes And dbSystemObject) = 0 Or ShowSystemTables Then
' Add the table under the Root object.
Set nd = TV.Nodes.Add("Root", tvwChild, , td.Name, "Table")
' Now add all the fields.
For Each fld In td.Fields
Set nd2 = TV.Nodes.Add(nd.Index, tvwChild, , _
fld.Name, "Field")
Next
End If
Next
db.Close
End Sub
注意這個例子不允許任何錯誤的操作：如果這個檔案不存在或是非法的MDB資料檔，這個錯誤會傳回給呼叫者。通常會展開TreeView控制項的Root物件以便節省使用者再按一下滑鼠鍵。這個例子會藉由把Root Node物件的Expanded屬性設為True來達成此效果。
外觀與可視性
經由設定其ForeColor、BackColor和Bold屬性可控制單獨Node物件的外觀，這個效果如圖10-6所示。此新的特性可改變更多關於每個Node的資料。一般而言，可以在增加項目到Nodes集合中時設定這些屬性：
With TV.Nodes.Add(, , , "New Node")
.Bold = True
.ForeColor = vbRed
.BackColor = vbYellow
End With
| 圖10-6 ForeColor、BackColor和Bold的Node物件屬性所顯示的效果，包含TreeView控制項的Checkboxes屬性。 |
每個Node物件都由三個相關的圖像所組合，而且Node的實際狀態決定該圖像是否展示。Image屬性設定、傳回預設圖像的索引值；SelectedImage屬性則負責Node選定時使用的圖像索引值；ExpandedImage屬性則負責Node所發展的圖像索引值。可經由Node集合中的Add方法設定前兩個屬性，但是必須在增加項目到集合之後，才能明確地設定EnpandedImage屬性。
經由查詢Visible屬性可得知一個特定的Node現在是否為可見的。Node項目能夠被看見是因為它是Tree收起的支點或因為它被捲動到看得見的地方。這個屬性是唯讀的，但是可經由EnsureVisible方法強迫改變這個Node的可見性。
' Scroll the TreeView, and expand any parent Node if necessary. If aNode.Visible = False Then aNode.EnsureVisible
可藉由TreeView的GetVisibleCount方法來得知有多少可看見的Node在這個控制項中。
有兩種方法去得知在控制項中的Node是否正被選擇－藉由查詢它的Selected屬性或去測試TreeView的SelectedItem屬性：
' Check whether aNode is the Node currently selected (two ' equivalent ways). ' First way: If aNode.Selected Then MsgBox "Selected" ' Second way: If TreeView1.SelectedItem Is aNode Then MsgBox "Selected" ' Make aNode the currently selected Node (two equivalent ways). ' First way: aNode.Selected = True ' Second way: Set TreeView1.SelectedItem = anode
顯示Node的資訊
使用者期望當他們點選TreeView控制項上的Node物件時，程式便會自動執行𠪴|例來說，會顯示一些該物件的訊息。為了得知Node何時被點選，必須去觸發NodeClick事件。可藉由Index或Key屬性以得知哪個Node被點選。典型的情形是將Node的資訊儲存在一個字串陣列或UDT（使用者自定形態）項目上：
Private Sub TreeView1_NodeClick(ByVal Node As MSComctlLib.Node)
' info() is an array of strings that hold nodes' descriptions.
lblData.Caption = info(Node.Index)
End Sub
NodeClick事件會與使用者點選TreeView控制項時所引發的Click事件不同。前一個事件是只有當使用者選取一個Node物件時才會觸發。
先前的程式碼可能會有問題：一般來說，一個Node物件的Index屬性是不該被信任的，因為會因其他Node物件從Node集合中移動而改變。基於這個理由，應該依靠專一的Key屬性，該屬性不會因集合中的Node增加而修改。舉個例子，可使用Key屬性去尋找一個用來儲存Node相關資料的標準集合物件中的項目。隨書光碟內的BrowMdb.vbp專案包括ShowDatabaseStructure修正版，其會以TreeView控制項顯示所有Field及TableDef物件的屬性與特質，如圖10-7所示：
| 圖10-7 微軟Jet資料庫的概略瀏覽。 |
編修Node文字
在預設的情況下，使用者可以點選Node物件進入編輯模式和間接地去修改Node物件的Text屬性。如果您不喜歡這樣，可以重設LabelEdit屬性為1-tvwManual。如此一來，將變成只有經由執行StartLabelEdit方法才能進入編輯模式。
不管LabelEdit屬性的值是多少，都能捕捉到使用者開始修改Text屬性值的時間（藉由BeforeLabelEdit事件）。當這個事件觸發時，可以透過TreeView的SelectedItem屬性來得知哪個Node被選取，而且還可以藉由將Cancel屬性設為True的方式來取消這些動作：
Private Sub TreeView1_BeforeLabelEdit(Cancel As Integer)
' Prevent the root Node's Text property from editing.
If TreeView1.SelectedItem.Key = "Root" Then Cancel = True
End Sub
同樣地，也可以找出使用者何時結束編輯和藉由擷取AfterLabelEdit事件得知Text的新值。一般可用此事件來檢查所輸入的資料是否為正確並可接受的。舉例來說，可以由下面的程式來拒絕空的字串：
Private Sub TreeView1_AfterLabelEdit(Cancel As Integer, _
NewString As String)
If Len(NewString) = 0 Then Cancel = True
End Sub
使用核選方塊
要列出TreeView控制項中每個Node的選取方塊，必須設Checkboxes屬性為True，無論是在設計階段或在執行程式。可以使用Checked的屬性來查詢或修正各個Node的狀態：
' Count how many Node objects are checked, and then reset all check boxes.
Dim i As Long, SelCount As Long
For i = 1 To TreeView1.Nodes.Count
If TreeView1.Nodes(i).Checked Then
SelCount = SelCount + 1
TreeView1.Nodes(i).Checked = False
End If
Next
只要藉由寫入控制項的NodeChecked事件來確定Node，將可以強制執行較為嚴謹的控制項。如果修改Node的Checked屬性的程式碼，則這個事件將不會啟動：
Dim SelCount As Long ' The number of selected items
Private Sub TreeView1_NodeCheck(ByVal Node As MSComctlLib.Node)
' Display the number of selected Nodes.
If Node.Checked Then
SelCount = SelCount + 1
Else
SelCount = SelCount _ 1
End If
lblStatus = "Selected Items = " & SelCount
End Sub
小秘訣
如果想要預防使用者修改Node物件的Checked狀態，則不能隨意地以NodeCheck事件來重設Checked屬性，因為經過變動的所有屬性將會隨著事件的過程而遺失。可藉著增加表單上Timer的控制項和寫入程式碼來解決這個問題：
Dim CheckedNode As Node ' A form-level variable
Private Sub TreeView1_NodeCheck(ByVal Node As MSComctlLib.Node)
' Prevent the user from checking the first Node.
If Node.Index = 1 Then
' Remember which Node has been clicked on.
Set CheckedNode = Node
' Let the Timer routine do the job.
Timer1.Enabled = True
End If
End Sub
Private Sub Timer1_Timer()
' Reset the Checked property, and then go to sleep.
CheckedNode.Checked = False
Timer1.Enabled = False
End Sub
如果Timer的Interval屬性是設置在一個極小的值的話，如10毫秒，會有較好的效率。
深入技巧
TreeView控制項擁有很好的彈性，但是有時候您必須藉助更深入的技巧和少用些直覺來操縱它。
需要時方載入Node
理論上來說，您能夠讀取到上千筆TreeView控制項項目。而實際上，只讀取幾百筆的項目便會使程式慢得不太能忍受。舉例來說，讀取結構目錄至TreeView控制項，檔案總管會這樣子做：這個簡單的任務會需要很多的時間來掃描系統的硬碟，但不能讓使用者等候如此長的時間。在這種情況下，得採取需要時才載入的方法。
需要時才載入的方法表示當其上層被展開，有需要顯示下層項目才增加Nodes物件。您能藉由擷取TreeView控制項的Expand事件來決定何時展開一個Node（也可藉由該控制項的Collapse事件找出一個Node物件何時收回）。至於其他難處理的細部是要讓使用者了解一個Node如何擁有一個或多個下屬物件，而不需要實際去增加它們。換句話說，我們需要顯示加號，若Node項目有下層資料時。
要證明TreeView通用控制項能夠在Node旁顯示一個加號而無需子Nodes是很容易的：只要執行檔案總管然後看到「軟碟機A: 」；那就是了，即使它沒有子目錄在這磁碟中（即使沒有任何的磁片在A槽中）。不幸地，如果沒有增加下屬Nodes，則展示一個加號的能力並未涵蓋在Visual Basic內附的OCX檔中，因而需要些API程式。然而，有個技巧並不需要任何API。
為了在Node旁顯示一個加號，必須做的就是去增加一個下屬Node。筆者將之稱為仿造的子Node。必須用一個清楚的方法設計一個仿造的Node項目𠪴|例來說，將特定的Text或Tag屬性數值做排序。當一個Node終於被展開的時候，程式會確定該Node有個仿造的下屬項目。如此一來，這個程式碼會移除這個仿造的子Node而且增加所有真正的子Nodes。如您所看到的，這個技巧相當簡明，然而完成它需包含一些極重要的程式碼。
圖10-8為範例程式執行的圖形。它完整的程式碼在隨書光碟中，所以筆者只說明關鍵處。這種形式包括tvwDir（TreeView控制項）和使用FileSystemObject來獲得這個目錄結構。
| 圖10-8 目錄瀏覽器程式正在讀取所需的TreeView Nodes。 |
下列的DirRefresh程序會在Form_Load事件中引用：
Private Sub DirRefresh()
Dim dr As Scripting.Drive
Dim rootNode As node, nd As Node
On Error Resume Next
' Add the "My Computer" root Node (expanded).
Set rootNode = tvwDir.Nodes.Add(, , "\\MyComputer", _
"My Computer", 1)
rootNode.Expanded = True
' Add all the drives; display a plus sign beside them.
For Each dr In FSO.Drives
' Error handling is needed to account for not-ready drives.
Err.Clear
Set nd = tvwDir.Nodes.Add(rootNode.Key, tvwChild, dr.Path & "\", _
dr.Path & " " & dr.VolumeName, 2)
If Err = 0 Then AddDummyChild nd
Next
End Sub
Sub AddDummyChild(nd As node)
' Add a dummy child Node if necessary.
If nd.Children = 0 Then
' Dummy nodes' Text property is "***".
tvwDir.Nodes.Add nd.index, tvwChild, , "***"
End If
End Sub
先前的程序確保這種形式會顯示「我的電腦」Root Node以及所有屬於它的設備。當使用者展開Node，下面的事件將會啟動：
Private Sub tvwDir_Expand(ByVal node As ComctlLib.node)
' A Node is being expanded.
Dim nd As Node
' Exit if the Node had already been expanded or has no children.
If node.Children = 0 Or node.Children > 1 Then Exit Sub
' Also exit if it doesn't have a dummy child Node.
If node.Child.text <> "***" Then Exit Sub
' Remove the dummy child item.
tvwDir.Nodes.Remove node.Child.index
' Add all the subdirs of this Node object.
AddSubdirs node
End Sub
TvwDir_Expand程序使用Node物件的Children屬性，即將它的子Nodes數目傳回，而且Child屬性傳回它的第一個子Node。AddSubdirs程序增加屬於一個被指定Node的全部子目錄。因為每個Node的Key屬性總是擁有和Node相符的路徑，所以取得Script.Folder物件和重複它的SubFolders集合是很容易的：
Private Sub AddSubdirs(ByVal node As ComctlLib.node)
' Add all the subdirectories under a Node.
Dim fld As Scripting.Folder
Dim nd As Node
' The path in the Node is held in its key property, so it's easy
' to cycle on all its subdirectories.
For Each fld In FSO.GetFolder(node.Key).SubFolders
Set nd = tvwDir.Nodes.Add(node, tvwChild, fld.Path, fld.Name, 3)
nd.ExpandedImage = 4
' If this directory has subfolders, add a plus sign.
If fld.SubFolders.Count Then AddDummyChild nd
Next
End Sub
即使這程式碼只能讀取和展示目錄樹，您還是可以簡單地修正它以使用TreeView控制項來處理其他形態的資料。
好的使用方法是用階層式的格式來瀏覽資料庫。以到處都有的Biblio.Mdb舉例：當使用者展開Node時，可以讀取所有發行者的名字在TreeView控制項中而且顯現相關的標題。這樣會比重複讀取所有控制項中的資料快很多，而且查看這些記錄會較清楚。在隨書光碟中己有範例程式來表現這個技巧。
尋找Nodes集合物件
當需要得知TreeView控制項的資訊時，必須尋找Nodes集合。大部分的例子，不能單只從第一個項目一直搜尋到最後一個項目，因為這順序為Nodes加入的先後順序，對這些Nodes而言並無任何關聯。
要按照次序檢視TreeView控制項的所有項目，每個Node物件需包含關於與其他Nodes有相對關係的屬性。我們已經看過Child屬性，其關聯到第一個子Node，而Children屬性傳回子Nodes的總數。Next屬性則傳回同樣層級的下一個Node的相關值（下一個親屬Node），而Previous屬性則傳回同樣層級中的前一個Node的相關值（前一個親屬Node）。FirstSibling和LastSibling屬性分別傳回第一個和最後一個Node的相關值，它們在相同的層級。最後Parent屬性傳回Node的上層相關值，而Root屬性傳回Node所屬的最頂階級。（請記得，可以有很多個Root Nodes。）可以使用這些屬性去測試指定的Node在哪個階層。這裡有些範例：
' Check whether a Node has no children (two possible approaches). If Node.Children = 0 Then MsgBox "Has no children" If Node.Child Is Nothing Then MsgBox "Has no children" ' Check whether a Node is the first child of its parent (two approaches). If Node.Previous Is Nothing Then MsgBox "First Child" If Node.FirstSibling Is Node Then MsgBox "First Child" ' Check whether a Node is the last child of its parent (two approaches). If Node.Next Is Nothing Then MsgBox "Last Child" If Node.LastSibling Is Node Then MsgBox "Last Child" ' Check whether a Node is the root of its own tree (two approaches). If Node.Parent Is Nothing Then MsgBox "Root Node" If Node.Root Is Node Then MsgBox "Root Node" ' Get a reference to the first root Node in the control. Set RootNode = TreeView1.Nodes(1).Root.FirstSibling
不要驚訝，大多數寫尋找Nodes集合的都是用遞迴的方式。通常，您以一個Node物件為開始，獲取它的第一個子Node，然後用遞迴法來呼叫它的所有下屬。下面的敘述是這個方法的範例。它的目的是建立一個字串代表一個TreeView控制項或其中之一個subtree的內容字串。字串中的每一行都代表一個Node物件，或是許多反映巢狀層級的tab字元。這個例子會傳回一個字串，內容為所有Nodes或可看見的項目（換言之，其上層是展開的）：
' Convert the contents of a TreeView control into a string.
' If a Node is provided, it only searches a subtree.
' If last argument is False or omitted, all items are included.
Function TreeViewToString(TV As TreeView, Optional StartNode As Node, _
Optional OnlyVisible As Boolean) As String
Dim nd As Node, childND As Node
Dim res As String, i As Long
Static Level As Integer
' Exit if there are no Nodes to search.
If TV.Nodes.Count = 0 Then Exit Function
' If StartNode is omitted, start from the first root Node.
If StartNode Is Nothing Then
Set nd = TV.Nodes(1).Root.FirstSibling
Else
Set nd = StartNode
End If
' Output the starting Node.
res = String$(Level, vbTab) & nd.Text & vbCrLf
' Then call this routine recursively to output all child Nodes.
' If OnlyVisible = True, do this only if this Node is expanded.
If nd.Children And (nd.Expanded Or OnlyVisible = False) Then
Level = Level + 1
Set childND = nd.Child
For i = 1 To nd.Children
res = res & TreeViewToString(TV, childND, OnlyVisible)
Set childND = childND.Next
Next
Level = Level - 1
End If
' If searching the whole tree, we must account for multiple roots.
If StartNode Is Nothing Then
Set nd = nd.Next
Do Until nd Is Nothing
res = res & TreeViewToString(TV, nd, OnlyVisible)
Set nd = nd.Next
Loop
End If
TreeViewToString = res
End Function
圖10-9為使用這個例子的範例程式和讀取「記事本」中字串的效果。您可以用很多方法來美化TreeViewToString的過程。舉例來說，能建立一個用來列印TreeView控制項內容的程式（包括所有的連結線、點陣圖等等）。使用類似的方法，可以寫一個能儲存和讀取TreeView實際狀況的程式，其中包含所有Node物件的Expanded屬性。
| 圖10-9 使用TreeViewToString的程式。 |
實作拖曳
另一個常見的操作就是TreeView控制項的拖曳，是用來複製或移動部份階層。拖曳的實作並非極為容易。首先必須了解Node拖拉運作的開始與結束，然後您要複製或移動部份的Nodes集合。還要預防錯誤的操作，如當使用檔案總管時，如果拖拉一個目錄到它的內層目錄的話，就不會運作。
TreeView控制項提供一些屬性和方法來執行拖曳功能。您可以使用HitTest的方法來得知Node物件的指定座標（一般來說，使用MouseDown事件來對準要拖拉的Node起始位址）。使用DropHighlight屬性來突出滑鼠所指的Node，所以您可以提供給使用者可能目標的Node運作。
圖10-10就是個CD中的範例，能試驗從TreeView控制項或在同樣的TreeView控制項中進行拖曳。格式上的兩個控制項屬於一個控制項陣列，所以相同的程式碼可在無論是程式碼或目的控制項運作。
| 圖10-10 可使用拖曳來移動或複製控制項間或附屬於相同TreeView控制項中的子樹。 |
一般而言，這個拖拉的動作以MouseDown事件做啟動：
' The source control
Dim SourceTreeView As TreeView
' The source Node object
Dim SourceNode As Node
' The state of Shift key during the drag-and-drop operation
Dim ShiftState As Integer
Private Sub TreeView1_MouseDown(Index As Integer, _
Button As Integer, Shift As Integer, x As Single, y As Single)
' Check whether we are starting a drag operation.
If Button <> 2 Then Exit Sub
' Set the Node being dragged, or exit if there is none.
Set SourceNode = TreeView1(Index).HitTest(x, y)
If SourceNode Is Nothing Then Exit Sub
' Save values for later.
Set SourceTreeView = TreeView1(Index)
ShiftState = Shift
' Start the drag operation.
TreeView1(Index).OLEDrag
End Sub
OLEStartDrag事件程序依靠Ctrl鍵的狀態來決定移動或複製項目：
Private Sub TreeView1_OLEStartDrag(Index As Integer, _
Data As MSComctlLib.DataObject, AllowedEffects As Long)
' Pass the Key property of the Node being dragged.
' (This value is not used; we can actually pass anything.)
Data.SetData SourceNode.Key
If ShiftState And vbCtrlMask Then
AllowedEffects = vbDropEffectCopy
Else
AllowedEffects = vbDropEffectMove
End If
End Sub
在OLEDragOver事件程序中，您提供使用者回饋(feedback)，藉由突出滑鼠指向的Node。（程式碼和目的控制項會同時發生。）
Private Sub TreeView1_OLEDragOver(Index As Integer, _
Data As MSComctlLib.DataObject, Effect As Long, Button As Integer, _
Shift As Integer, x As Single, y As Single, State As Integer)
' Highlight the Node the mouse is over.
Set TreeView1(Index).DropHighlight = TreeView1(Index).HitTest(x, y)
End Sub
最後必須去履行群體中最為複雜的OLEDragDrop。首先必須了解滑鼠是否移到目標控制項的Node。如果是的話，Node的程式碼會變成目標Node的下屬；如果不是，則程式碼會變成目標控制項中的Root Node。如果程式和目標控制項同時發生，也必須要擔保目標Node並非為Node原始程式的下屬，不然會陷入無限循環。
Private Sub TreeView1_OLEDragDrop(Index As Integer, _
Data As MSComctlLib.DataObject, Effect As Long, Button As Integer, _
Shift As Integer, x As Single, y As Single)
Dim dest As Node, nd As Node
' Get the target Node.
Set dest = TreeView1(Index).DropHighlight
If dest Is Nothing Then
' Add the Node as the root of the target TreeView.
Set nd = TreeView1(Index).Nodes.Add(, , , SourceNode.Text, _
SourceNode.Image)
Else
' Check that the destination isn't a descendant of the source
' Node.
If SourceTreeView Is TreeView1(Index) Then
Set nd = dest
Do
If nd Is SourceNode Then
MsgBox "Unable to drag Nodes here", vbExclamation
Exit Sub
End If
Set nd = nd.Parent
Loop Until nd Is Nothing
End If
Set nd = TreeView1(Index).Nodes.Add(dest.Index, tvwChild, , _
SourceNode.Text, SourceNode.Image)
End If
nd.ExpandedImage = 2: nd.Expanded = True
' Copy the subtree from source to target control.
CopySubTree SourceTreeView, SourceNode, TreeView1(Index), nd
' If this is a move operation, delete the source subtree.
If Effect = vbDropEffectMove Then
SourceTreeView.Nodes.Remove SourceNode.Index
End If
Set TreeView1(Index).DropHighlight = Nothing
End Sub
CopySubTree遞迴程序執行實際的複製指令（一個由複製組成的移動行為會伴隨著刪除指令）。它允許引用相關的原始碼和目標TreeView控制項，所以可以容易地在其他程式中反覆執行。
Sub CopySubTree(SourceTV As TreeView, sourceND As Node, _
DestTV As TreeView, destND As Node)
' Copy or move all children of a Node to another Node.
Dim i As Long, so As Node, de As Node
If sourceND.Children = 0 Then Exit Sub
Set so = sourceND.Child
For i = 1 To sourceND.Children
' Add a Node in the destination TreeView control.
Set de = DestTV.Nodes.Add(destND, tvwChild, , so.Text, _
so.Image, so.SelectedImage)
de.ExpandedImage = so.ExpandedImage
' Now add all the children of this Node in a recursive manner.
CopySubTree SourceTV, so, DestTV, de
' Get a reference to the next sibling.
Set so = so.Next
Next
End Sub
不需要遞迴程序來刪除一個子樹，因為只要刪除了Node物件，它的所有下屬Nodes也會自動的刪除。
ListView控制項
與TreeView控制項相同，ListView控制項也隨著檔案總管而為人熟知。現在許多的視窗軟體使用這種並排的控制項，而且它們都被稱為類似檔案總管的應用程式。在這些應用程式中，使用者選擇了一個左方TreeView控制項的Node，接著將會在最右方的ListView控制項中看到其相關資訊。
ListView控制項支援四個基本檢視指令：大圖示、小圖示、清單和詳細資料。為了解每一個模式如何顯示，試試檔案總管中的檢視選單裡的相關項目（詳細資料模式提供極詳盡的選單指令）。為了明白這些控制項的靈活性，您應該了解Windows桌面可看成是個使用大圖示模式的ListView控制項，且圖示的背景為透明的。當選擇詳細資料時，ListView控制項如同表格的控制項，而且較有組織的顯示所有項目的資訊。
Visual Basic 6的ListView控制項有許多新特性：它可以在行標題或儲存格來顯示圖示；它支援自動追蹤、整列選取和允許資料行重新排列；而且它的項目擁有獨立的Bold和Color參數。新的ListView控制項能夠顯示背景圖、格線與核選方塊。
ListView控制項延伸出兩個不同的集合：ListItems集合包含獨立的ListItem物件，每一個都跟控制項中的項目有關；ColumnHeaders集合包含在詳細資料模式中與標題有關係的ColumnHeaders物件。第三個集合，ListSubItems，包含所有在詳細模式中的方格資訊。
設定設計階段屬性
當您使用屬性視窗去建立ListView控制項中大部分的屬性時，使用ListView控制項的屬性頁去設定會更好，請看圖10-11所示。
| 圖10-11 ListView控制項屬性頁的一般頁籤。 |
一般性屬性
先前已經提到過View屬性了，它可以是下列參數中的一個：0-lvwIcon、1-lvwSmallIcon、2-lvwList或是3-lvwReport。可在執行的時候改變它的屬性和讓使用者來改變（一般藉由提供四個選項在應用程式中的View選單）。Arrange屬性決定是否圖示要自動對齊：靠左對齊（1-lvwAutoLeft）、靠上對齊（2-lvwAutoTop）、或不對齊（0-lvwNone，預設值）。只有在大圖示與小圖示模式此屬性才有效用。
LabelEdit屬性決定使用者是否能編輯關於控制項中的項目文件。如果這個屬性設為0-lvwAutomatic，則編輯的動作只有用StartLabelEdit的方法才能啟動。而LabelWrap布林屬性明確地指出在大圖示模式下較長的文字標籤會自動換行。HideColumnHeaders布林屬性決定在詳細資料模式中的行標題是否顯示。（預設值是Flase，會讓行顯示。）如果MultiSelect屬性為真，則ListView控制項將如同ListBox控制項，其MultiSelect屬性為2-Extended。
Visual Basic 6有一些新的屬性。如果設AllowColumnReorder為True，則在詳細資料模式下，使用者可拖移標題來重新排設資料行。還可以將GridLines設為True來改變ListView控制項的顯示（會增加水平和垂直的格線）。第三個新的屬性，FlatScrollBar，能改變ListView控制項是否顯示，不過它似乎有點問題：如果設它為True，則捲動軸將不會顯示。ListView控制項與TreeView控制項有部份新屬性是相同的。之前筆者敘述過CheckBoxes屬性（可以顯示每個項目的選取方塊）和FullRowSelect屬性（選取整列來代替一列中第一個項目）。而HotTracking布林屬性如果為True，則使用者將滑鼠移到某個項目之上時便能改變顯示情況。HoverSelection布林屬性如果為True，則只要使用者移動滑鼠到項目的上方，就能夠選取該項目。看看圖10-12的例子，就能了解這些新的屬性。
| 圖10-12 ListView控制項新特性的列表：選取方塊、格線、和每個項目的Bold以及ForeColor屬性。列與列的變化是用磚瓦背景圖來呈現。 |
可將三個輔助ListView控制項的ImageList做這樣的聯想：第一個ImageList在大圖示的時候使用，第二個則可以在任何模式中使用，而第三個則用在行標題的圖示。可在設計階段以屬性頁的影像庫頁籤來設定這些相關的ImageList控制項，或是在執行時將ListView的Icons、SmallIcons和ColumnHeaderIcons屬性分別設定為相對的ImageList控制項。
ColumnHeaders屬性是Visual Basic 6提供的新屬性，因為先前的ListView版本沒有提供行標題的功能：
' You can use the same ImageList control for different properties. Set ListView1.Icons = ImageList1 Set ListView1.SmallIcons = ImageList2 Set ListView1.ColumnHeaderIcons = ImageList2
可以勾選屬性對話方塊中的排序頁籤的一些屬性來讓ListView控制項的項目自動排序。如果想要排序項目，就要將Sorted屬性設為True。SortKey則是想要被排序的行的索引（第一行為0），而SortOrder則是排序的順序（0-lvwAscending或1-lvwDescending），您可以在執行時調整這些屬性。
資料行行首
設計階段時，可建立一個或多個ColumnHeader物件，只要用屬性對話方塊的資料行行首頁籤。只需按一下插入資料行按鈕，然後輸入Text屬性的值（用來顯示標題），Alignment屬性（左、右或中央，雖然第一個行標題只能靠左對齊），和Width（單位為twip）。也可以指定給Key和Tag屬性一個值，然後設置標題需要用到的圖示的索引值。（這是關於ImageList控制項的ColumnHeaderIcons屬性的索引值，而如果行標題沒有任何圖示的話就為0。）
背景圖像
Visual Basic 6的ListView控制項支援背景圖。想要讀取一張圖片到控制項中，只要在設計時選取位於屬性對話方塊裡的圖片頁籤最左方的Picture屬性。可載入為PictureBox控制項所支援的圖檔格式。另外有兩個附加的屬性跟背景圖像如何顯示有關，但只能在一般屬性視窗中做調整。PictureAlignment屬性讓您調整圖片在控制項四個角落之一的位置，中央，或者擴張為整個控制項大小。TextBackground則是調整ListView的項目背景圖像的透明（預設值為0lvwTransparent）與否（1-lvwOpaque）；後者只有在產生ListItem物件時才會顯現。
背景圖像可以交替背景色的方法來顯示，如圖10-12所示。而所要做的就是建立一個兩行高的點陣圖，然後設PictureAlignment值為5-lvwTile和TextBackground值為0-lvwTransparent。
執行階段的運作
在設計階段僅能定義ListView控制項的外貌，若要填入資料則須經由程式碼。在這裡，筆者將會說明如何增加和控制這個控制項的資料。
增加ListItem物件
藉由ListItems集合的Add方法可增加新的項目到ListView控制項中，語法如下：
Add([Index], [Key], [Text], [Icon], [SmallIcon]) As ListItem
Index是新項目的位置（如果忽略Index，該項目將會增加在整個集合的末端）。Key是ListItems集合中新插入項目的額外索引鍵，Text為顯示的字串，Icon則是ImageList控制項中表示大圖示的一個索引或索引鍵，而SmallIcon是小圖示的索引或索引鍵。所有的參數都是可選擇的。
Add方法會傳回所建立的ListItem物件，可以用此來設定一些不會傳送給Add方法的屬性，以下就是個例子：
' Create a new item with a "ghosted" appearance. Dim li As ListItem Set li = ListView1.ListItems.Add(, , "First item", 1) li.Ghosted = True
ListItem物件支援一些新的屬性。Bold和ForeColor屬性控制物件的粗體和顏色。ToolTipText屬性能定義每個項目不同的提示字串，而Checked屬性可設定或傳回項目選取方塊的狀態（如果ListView的CheckBoxes屬性為True的話）。當需要設定多個屬性時，可使用With關鍵字伴隨著Add方法：
With ListView1.ListItems.Add(, , "John Ross", 1)
.Bold = True
.ForeColor = vbRed
.ToolTipText = "Manager of the Sales Dept."
End With
當ListView控制項的MultiSelect屬性為True時，使用者可以按住Ctrl或Shift鍵來選取多個項目。經由在程式碼中調整Selected為適當值就能修改ListItem物件的選取狀態。不過對於這類的ListView控制項而言，還必須設定SelectedItem屬性使之成為現行的ListItem項目：
' Make the first ListItem object the current one. Set ListView1.SelectedItem = ListView1.ListItems(1) ' Select it. ListView1.ListItems(1).Selected = True
增加ColumnHeader物件
有時在設計階段並不知道哪些ListView控制項的資料行該顯現。舉例來說，可能要顯示使用者自定查詢的結果，此時並不知道欄位的數量與名稱。在這種情況下，需要在執行時以ColumnHeaders集合中的Add方法來建立ColumnHeader物件，語法如下：
Add([Index], [Key], [Text], [Width], [Alignment], [Icon]) _
As ColumnHeader
Index是在集合的位置，Key是額外的索引鍵，Text是顯示在標題的字串，而Width則是單位為twips的行寬。Alignment為下列值其中之一：0-lvwColumnLeft、1-lvwColumnRight或2-lvwColumnCenter。Icon是參考自ColumnHeaderIcons屬性的ListImage控制項內圖片的索引或索引鍵。Tag屬性是唯一可在ColumnHeader物件建立後調整的屬性，所以通常可以放棄Add方法傳回的值。
' Clear any existing column header. ListView1.ColumnHeaders.Clear ' The alignment for the first column header must be lvwColumnLeft. ListView1.ColumnHeaders.Add , , "Last Name", 2000, lvwColumnLeft ListView1.ColumnHeaders.Add , , "First Name", 2000, lvwColumnLeft ListView1.ColumnHeaders.Add , , "Salary", 1500, lvwColumnRight
增加ListSubItems
每一個ListItem物件包含一個ListSubItems集合，能建立與主要ListItem物件中位於相同列的顯示值（當控制項在詳細資料模式下時）。這個集合取代舊版控制項的SubItems陣列（為了相容性，該陣列仍然支援）。可以使用ListSubItems集合中的Add方法來建立新的ListSubItem物件：
Add([Index], [Key], [Text], [ReportIcon], [ToolTipText]) _
As ListSubItem
Index是集合中新項目的位置，Key是額外的索引鍵，Text是顯示在方格中的字串，ReportIcon是參考自SmallIcons屬性的ImageList控制項內圖片的索引或索引鍵。也可以調整每一個ListSubItem的Bold和ForeColor參數：
' This ListItem goes under ColumnHeader(1).
With ListView1.ListItems.Add(, , "Ross", 1)
.Bold = True
' This ListSubItem goes under ColumnHeader(2).
With .ListSubItems.Add(, , "John")
.Bold = True
End With
' This ListSubItem goes under ColumnHeader(3).
With .ListSubItems.Add(, , "80,000")
.Bold = True
.ForeColor = vbRed
End With
End With
ListSubItem物件只有在ListView控制項為詳細資料模式和有足夠的ColumnHeader物件時才會真正的顯示。舉個例子，如果ColumnHeaders集合只包含三個元素，ListView控制項將只會顯示三個項目在每一行中。因為最左方的ColumnHeader物件位在ListItem元素上，因此只有ListSubItems集合的前兩個元素才會顯現。
ListSubItem物件也支援Tag屬性，如此能用來儲存跟資料項有關的附加資訊。
從資料庫中載入資料
ListView控制項不會自動地與RemoteDate或ADO資料控制項進行資料連結。換句話說，如果想要讀取資料庫中的資料到控制項的話，必須手動進行。讀取資料到ListView控制項中在觀念上並不困難，但必須注意些細節。首先需取得Recordset的欄位清單和建立相對應且合適寬度的ColumnHeader物件。還有必須放棄不能在ListView控制項中顯示的欄位（例如BLOB類的），且必須決定每個欄位最佳的位置（數字和日期須靠右，其他則靠左）。下列程式說明這些用法，可在您的程式中使用此方法，如下：
Sub LoadListViewFromRecordset(LV As ListView, rs As ADODB.Recordset, _
Optional MaxRecords As Long)
Dim fld As ADODB.Field, alignment As Integer
Dim recCount As Long, i As Long, fldName As String
Dim li As ListItem
' Clear the contents of the ListView control.
LV.ListItems.Clear
LV.ColumnHeaders.Clear
' Create the ColumnHeader collection.
For Each fld In rs.Fields
' Filter out undesired field types.
Select Case fld.Type
Case adBoolean, adCurrency, adDate, adDecimal, adDouble
alignment = lvwColumnRight
Case adInteger, adNumeric, adSingle, adSmallInt, adVarNumeric
alignment = lvwColumnRight
Case adBSTR, adChar, adVarChar, adVariant
alignment = lvwColumnLeft
Case Else
alignment = -1 ' This means "Unsupported field type".
End Select
' If field type is OK, create a column with the correct alignment.
If alignment <> -1 Then
' The first column must be left-aligned.
If LV.ColumnHeaders.Count = 0 Then alignment = lvwColumnLeft
LV.ColumnHeaders.Add , , fld.Name, fld.DefinedSize * 200, _
alignment
End If
Next
' Exit if there are no fields that can be shown.
If LV.ColumnHeaders.Count = 0 Then Exit Sub
' Add all the records in the recordset.
rs.MoveFirst
Do Until rs.EOF
recCount = recCount + 1
' Add the main ListItem object.
fldName = LV.ColumnHeaders(1).Text
Set li = LV.ListItems.Add(, , rs.Fields(fldName) & "")
' Add all subsequent ListSubItem objects.
For i = 2 To LV.ColumnHeaders.Count
fldName = LV.ColumnHeaders(i)
li.ListSubItems.Add , , rs.Fields(fldName) & ""
Next
If recCount = MaxRecords Then Exit Do
rs.MoveNext
Loop
End Sub
LoadListViewFromRecordset函式需要一個ADO Recordset和選擇性的MaxRecords參數，其用來限制記錄顯示的數量。這是必需的，因為𤩐蛫鴭鏏ound控制項，只需載入真正要顯示的資訊𠲸麂蝳◎|讀取Recordset的所有資料列，這可能會是極為冗長的過程。建議設定MaxRecords為100或200，相信這樣會提升連結資料庫的時間和CPU的效率。
另一個問題是從資料庫中讀取資料時，可能需要手動調整每一個行寬。LoadListViewFromRecordset會使所有ColumnHeader物件使用該欄位最大的寬度，但是在大部分的情況下，存在資料庫中的值會比該值短很多。為了避免讓使用者進行繁瑣的調整寬度程序，可用下述的方法來改變所有的行寬：
Sub ListViewAdjustColumnWidth(LV As ListView, _
Optional AccountForHeaders As Boolean)
Dim row As Long, col As Long
Dim width As Single, maxWidth As Single
Dim saveFont As StdFont, saveScaleMode As Integer, cellText As String
' Exit if there aren't any items.
If LV.ListItems.Count = 0 Then Exit Sub
' Save the font used by the parent form, and enforce ListView's
' font. (We need this in order to use the form's TextWidth
' method.)
Set saveFont = LV.Parent.Font
Set LV.Parent.Font = LV.Font
' Enforce ScaleMode = vbTwips for the parent.
saveScaleMode = LV.Parent.ScaleMode
LV.Parent.ScaleMode = vbTwips
For col = 1 To LV.ColumnHeaders.Count
maxWidth = 0
If AccountForHeaders Then
maxWidth = LV.Parent.TextWidth(LV.ColumnHeaders(col).Text)+200
End If
For row = 1 To LV.ListItems.Count
' Retrieve the text string from ListItems or ListSubItems.
If col = 1 Then
cellText = LV.ListItems(row).Text
Else
cellText = LV.ListItems(row).ListSubItems(col - 1).Text
End If
' Calculate its width, and account for margins.
' Note: doesn't account for multiple-line text fields.
width = LV.Parent.TextWidth(cellText) + 200
' Update maxWidth if we've found a larger string.
If width > maxWidth Then maxWidth = width
Next
' Change the column's width.
LV.ColumnHeaders(col).width = maxWidth
Next
' Restore parent form's properties.
Set LV.Parent.Font = saveFont
LV.Parent.ScaleMode = saveScaleMode
End Sub
為了確定每個給定行所儲存值的最佳欄寬，ListViewAdjustColumnWidth函式求出所有儲存在行內字串的最大寬度。問題是由於ListView不支援TextWidth方法，所以這個程序依靠控制項所屬表單的TextWidth方法。如果以True值作為第二個參數，此程序也會計算所有ColumnHeader物件的Text屬性，所以標題也不會被截掉。
ListView控制項已能夠自動地調整適合的大小，即使Visual Basic ActiveX控制項尚未提供這個功能。事實上，您能調整成該項目最大的內容，連續在行標題的邊緣按兩下（如同在檔案總管的詳細資料模式上）。在隨書光碟中的範例，您將發現另一個ListViewAdjustColumnWidth版本，使用API呼叫代替原始的Visdual Basic程式碼來調節大小。下述的程式範例將展示如何使用ListViewAdjustColumnWidth來顯示NorthWind.Mdb中所有在Orders資料表的所有記錄，如圖10-13所示：
Private Sub Form_Load()
Dim cn As New ADODB.Connection, rs As New ADODB.Recordset
' WARNING: you might need to modify the DB path in the next line.
cn.Open "Provider=Microsoft.Jet.OLEDB.3.51;" _
& "Data Source=C:\VisStudio\VB98\NWind.mdb"
rs.Open "Orders", cn, adOpenForwardOnly, adLockReadOnly
LoadListViewFromRecordset ListView1, rs
ListViewAdjustColumnWidth ListView1, True
End Sub
在筆者的233-MHz機器中，這段程式花了15秒才完成，大部分使用者恐怕沒這樣的耐心。因此，應該明智地使用此技術且設定一個讀取資料庫數目的上限。
| 圖10-13 這個範例會讀取NorthWind的Orders資料表到ListView控制項，而且當點選行標題時會自動排序其行之資料。 |
資料行的排序以及重新排列
之前已介紹過在設計階段如何來定義排序鍵值和排序順序。於執行時可調整Sorted、SortKey和SortOrder屬性來達到同樣的效果。通常當使用者按下行標題時才做這件事，此動作會引發ColumnClick事件：
Private Sub ListView1_ColumnClick(ByVal ColumnHeader As _
MSComctlLib.ColumnHeader)
ListView1.SortKey = ColumnHeader.Index - 1
ListView1.Sorted = True
End Sub
如果想要以此種方法來提供不同方向的排序能力時，會稍微複雜些：第一次點選會導致升冪的排序功能，第二次點選則會導致降冪排序。想達到此作用，必須檢查被點選的行是否已排序：
Private Sub ListView1_ColumnClick(ByVal ColumnHeader As _
MSComctlLib.ColumnHeader)
' Sort according to data in this column.
If ListView1.Sorted And _
ColumnHeader.Index - 1 = ListView1.SortKey Then
' Already sorted on this column, just invert the sort order.
ListView1.SortOrder = 1 - ListView1.SortOrder
Else
ListView1.SortOrder = lvwAscending
ListView1.SortKey = ColumnHeader.Index - 1
End If
ListView1.Sorted = True
End Sub
ListView控制項只能排序字串資料。如果想要針對數字或日期做排序，必須用些技巧。建立一個新的ColumnHeader物件，以字串來填入，而此字串來自想要排序的數字或日期，接著排序該行，最後刪除那些項目。這裡有個函式可達成此效果：
Sub ListViewSortOnNonStringField(LV As ListView, ByVal ColumnIndex As _
Integer, SortOrder As Integer, Optional IsDateValue As Boolean)
Dim li As ListItem, number As Double, newIndex As Integer
' This speeds up things by a factor of 10 or more.
LV.Visible = False
LV.Sorted = False
' Create a new, hidden field.
LV.ColumnHeaders.Add , , "dummy column", 1
newIndex = LV.ColumnHeaders.Count - 1
For Each li In LV.ListItems
' Extract a number from the field.
If IsDateValue Then
number = DateValue(li.ListSubItems(ColumnIndex - 1))
Else
number = CDbl(li.ListSubItems(ColumnIndex - 1))
End If
' Add a string that can be sorted using the Sorted property.
li.ListSubItems.Add , , Format$(number, "000000000000000.000")
Next
' Sort on this hidden field.
LV.SortKey = newIndex
LV.SortOrder = SortOrder
LV.Sorted = True
' Remove data from the hidden column.
LV.ColumnHeaders.Remove newIndex + 1
For Each li In LV.ListItems
li.ListSubItems.Remove newIndex
Next
LV.Visible = True
End Sub
如先前所說的，可使用在ColumnClick事件程序的ListViewSortOnNonStringField函式。上述的程式無法處理負數，但隨書光碟中的完整程式已經解決了這個問題。
小秘訣
當Sorted屬性為True時，插入或移除動作需要很久的時間。當要更新資料時，可先將Sorted屬性設為False，完成後再重設為True。視ListView控制項項目的多寡，可輕易地提升龐大程式的執行速度。
資料行可在執行時移動或重排。將AllowColumnReorder屬性設為True就能讓使用者拖曳資料行到新的位置。然而，當ListView控制項的CheckBoxes屬性為True時不該如此做。如果使用者移動第一行，則控制項的內容將會變得不一樣，因為選取方塊會隨著第一行而移動。
從程式碼中來控制哪一行要移動且移動到哪兒會比較好。在這種情形下，只需指定新值給ColumnHeader物件的Position屬性。例如，可以交換下列程式前兩行的位置：
ListView1.ColumnHeaders(1).Position = ListView1.ColumnHeaders(1).Position _
+ 1
' You need to refresh after reordering one or more columns.
ListView1.Refresh
搜尋項目
可用FindItem法快速地搜尋ListView控制項中的字串，語法如下：
FindItem(Search, [Where], [Start], [Match]) As ListItem
Search參數為要搜索的字串。Where參數表示哪類字串要被搜尋：0-lvwText針對ListItem物件的Text屬性；1-lvwSubItem針對ListSubItem的Text屬性；而2-lvwTag則針對ListItem物件的Tag屬性。Start參數為要從哪個索引或索引鍵的ListItem物件開始搜尋起。Match可以是0-lvwWholeWord或1-lvwPartial，其定義是否要完全符合或部份符合。（Match只能用在Where值為0-lvwText時。）
要注意的是無法在ListSubItem物件的Tag屬性搜尋，也不能限制搜尋ListItems的單一行。所有的搜尋行為都是分大小寫的。
其他的屬性、方法、事件
ListView控制項所支援的屬性、方法和事件與TreeView控制項的雷同，所以在這裡就不再做詳細的介紹。
可藉由BeforeLabelEdit和AfterLabelEdit事件，控制使用者何時編輯控制項的值。無論使用者按下列的何處，只有位處最左方資料行的項目會被編輯。如果想要用程式來開始編輯行為，必須先讓某個ListItem物件成為被選取的項目，然後執行StartLabelEdit方法：
ListView1.SetFocus Set ListView1.SelectedItem = ListView1.ListItems(1) ListView1.StartLabelEdit
如果控制項的CheckBoxes屬性設為True，那麼可藉由ListItem物件的Checked屬性來讀取和修改每列的核取狀態。可在ItemCheck事件程序上撰寫程式來捕捉點選核取方塊的動作。相似地，當ListItem物件被點選時，則會引發ItemClick事件。
ListItem物件還包含EnsureVisible方法，如果需要的話，其可捲動控制項的內容而移動某項目到可見的控制項區域。可以查詢ListView的GetFirstVisible方法，其會傳回第一個可見的ListItem物件的引用。
ListView的HitTest方法會傳回ListItem物件的詳細座標。一般會在拖曳動作中使用此方法，並搭配DropHighlight屬性，這些在說明TreeView控制項已說明。不過，在詳細資料模式下時，並沒有簡單的方法可決定滑鼠點在哪個資料行。
Toolbar控制項
大多數的Windows應用程式都有一個以上的工具列，提供使用者用滑鼠點選來執行大部分常用的指令。工具列不至於取代選單，唯一的理由是：選單可以由鍵盤來執行；工作列不行的理由是，不過它們一定會讓程式更實用且更美觀。
Visual Basic的Toolbar控制項能包含按鈕和其他的控制項，且可讓使用者自訂。Visual Basic 6增加了平面樣式的工具列，其因為Microsoft Internet Explorer而廣為人知，且其內建下拉式選單。
Toolbar控制項有個Buttons集合，包含Button物件。每個Button物件可以是個按鈕、分隔區、或一個預備給其他控制項放置的位置（一般是TextBox和ComboBox控制項）。此外，Button物件包含ButtonsMenus集合，每個ButtonMenu物件皆是個下拉式選單項目。（如果Button物件不是下拉式選單，則該集合是空的。）
設定設計階段屬性
大部分的情況下，會於設計時定義Toolbar的外觀，然後對應使用者對按鈕的點選。設計時有兩種運作Toolbar的方法：使用Toolbar精靈或手動設定其屬性。這兩個方法並非互相排斥的：事實上絕大部份的時候，會先透過精靈來建立初始的Toolbar控制項，然後於其屬性頁再加以微調會更方便。
Toolbar精靈
Toolbar精靈是Visual Basic 6新的增益集功能，但在增益集管理對話方塊內的清單並沒有此精靈。其實是必須安裝應用程式精靈：完成後，您會在增益集選單中發現工具列精靈。如果選擇了該指令，精靈會增加一個新的Toolbar控制項於現行表單上，並可讓您自訂它。也可以手動放置Toolbar工具列於表單上，然後精靈會自動啟動。
Toolbar精靈的使用極為簡單。在左方的方塊中會有一排按鈕（見圖10-14），其可讓您選取要加到Toolbar控制項的按鈕。可在兩個方塊間移動項目與改變其在工具列的順序，方法為透過中間的按鈕或用拖曳的方式。此精靈同時也會建立對應的ImageList控制項。當完成工具列後，會出現對話方塊詢問是否要儲存成rwp檔，該檔能讓您在往後加速建立類似的工具列。
| 圖10-14用Toolbar精靈建立一個工具列。 |
一般性的屬性
在建立工具列後，於其上按下滑鼠右鍵並選擇 屬性 選單可開啟其 屬性頁 。 屬性頁 的 一般 頁籤中包含大部分設計階段用的屬性，能控制Toolbar控制項較佳的外觀和行為，如圖10-15和圖10-16所示。舉例來說，要做下列的決定：使用者是否可於執行時自訂工具列（AllowCustomize屬性），當表單大小變化時，工具列是否要自動換行（Wrappable屬性），是否要顯示ToolTips（ShowTips屬性），和按鈕的預設大小為何（ButtonWidth和ButtonHeight屬性）。若有需要的話，按鈕會自動地擴展以符合其標題或圖片，所以大部分的情況下，並不需要去修改後兩個屬性的預設值。
Visual Basic 6有一些有趣的新屬性，您可以建立平面式工具列，只要將Style屬性設為1-tbrFlat，且可使用TextAlignment屬性來改變按鈕上標題相對於圖片的對齊方式（0-tbrTextAlignBottom或1-tbrTextAlignRight）。
工具列上的按鈕可以有三種狀態：正常、無效或選取的。（如果Style是1-tbrFlat的話，當滑鼠移過某按鈕時，「選取」狀態就會發生）。Toolbar控制項並非用三個屬性來指向同一個ImageList控制項內的不同圖片，而是用另一種方法：每個按鈕只包含一個Image屬性－代表索引或索引鍵－而由按鈕的狀態表示要用哪個ImageList控制項。可在設計或執行時，指定三個ImageList控制項給ImageList、DisabledImageList和HotImageList屬性。舉個例子，可使用一組黑白圖示給正常狀態與一組有顏色的圖示給選擇狀態，來模仿Internet Explorer 4。如果不要指定後兩個屬性，則Toolbar會自動建立適合的圖片給無效或選取狀態。
| 圖10-15 Toolbar控制項屬性頁的一般頁籤。 |
| 圖10-16 Toolbar控制項屬性頁的按鈕頁籤。 |
Button物件
沒有按鈕的Toolbar控制項是沒用的。您可以用Toolbar精靈來增加Button物件，如先前所?述的，或在屬性頁的按鈕頁籤中設定，如圖10-16。每個按鈕都有個Caption屬性（如果只要顯示圖示，就不要輸入任何字串），一個非必要的自訂敘述、Tag屬性，Button集合的索引鍵（非必要的，但可用它來改善程式的可讀性），若Toolbar的ShowTips屬性為True時才會顯示的ToolTipText，以及一個Image索引或索引鍵，指向相關的ImageList控制項。
Style是Button物件中最感人興趣的屬性。此屬性決定Button的外觀與行為，可以是下列值之一：0-tbrDefault（一般按鈕，就像可按下的按鈕）、1-tbrCheck（按了之後會一直保持按住的情形的按鈕，如CheckBox控制項）、2-tbrButtonGroup（有許多屬於同一個群組的按鈕，但是只能選擇一個，如OptionButton控制項）、3-tbrSeparator（隔開固定的寬度）、4-tbrPlaceholder（由Width屬性來控制分隔區域的大小；通常用來建立一個可給其他控制項放置的空間）或5-tbrDropDown（有下拉箭頭的按鈕，類似下拉式選單）。
當Style屬性值設為5-tbrDropDown時，可以增加一個以上的ButtonMenu物件給該按鈕。（無論按鈕的Style為何都可建立ButtonMenu項目，但只有設為tbrDropDown的才看得見）。每個ButtonMenu物件都有個Text屬性（選單標題）、ButtonMenus集合中非必要的Key與Tag屬性。不幸地，ButtonMenu物件無法結合圖片：下拉式選單只能以純文字顯示，很明顯地與Toolbar感覺大不相同。見圖10-17的例子，Toolbar控制項的第一個按鈕就是個下拉式選單。
| 圖10-17 有下拉式選單的工具列。 |
執行階段的運作
一旦於表單上增加了一個Toolbar控制項後，必須捕捉使用者對它所做的動作。可能需要於執行時藉由程式來建立控制項，或讓使用者自訂之，並將新的版面存起來給後續的運作。
建立Button和ButtonMenu物件
可在執行階段以Button集合中的Add方法來建立新Button物件，語法如下：
Add([Index], [Key], [Caption], [Style], [Image]) As Button
Index是要被加到集合內Button物件的位置，Key則為其非必要性的字串索引鍵，Caption是顯示在工具列上的文字，Style決定該按鈕是何種形態（0-tbrNormal, 1-tbrCheck、2tbrButtonGroup、3-tbrSeparator、4-tbrPlaceholder或5-tbrDropDown），而Image則為在三個ImageList控制項內圖片的索引或索引鍵。
當建完按鈕物件後，還需要去設定些額外屬性，如Width（對預備空間的按鈕而言）和ToolTipText。Style為tbrCheck或tbrButtonGroup的按鈕可將其Value屬性設為1-tbrPressed，即可讓按鈕成為被按下的狀態。這裡有個增加按鈕的範例程式：
' A button that can be in an on or off state Dim btn As Button Set btn = Toolbar1.Buttons.Add(, , , tbrCheck, "Lock") btn.Value = tbrPressed ' A separator Toolbar1.Buttons.Add, , , tbrSeparator ' Two buttons that are mutually exclusive Set btn = Toolbar1.Buttons.Add(, , , tbrButtonGroup, "Green") Set btn = Toolbar1.Buttons.Add(, , , tbrButtonGroup, "Red") btn.Value = tbrPressed
想要放置任何控制項在工具列上，可先建立Style屬性設為tbrPlaceholder的Button物件，然後移動該控制項到適當位置。例如，要將cboFontSizes控制項放在工具列上：
' Create a placeholder of proper width. Dim btn As Button Set btn = Toolbar1.Buttons.Add(, , , tbrPlaceholder) btn.Width = cboFontSizes.Width ' Move the ComboBox control over the placeholder button. Set cboFontSizes.Container = Toolbar1 cboFontSizes.Move btn.Left, btn.Top
如果建立Style屬性為tbrDropDown的按鈕，則可用其ButtonMenus集合的Add方法增加一個以上的項目到集合內：
Add ([Index], [Key], [Text]) As ButtonMenu
Index表示在集合中的位置，Key為非必要的索引鍵，而Text則是選單項目的標題。下面程式即增加一個有三個選項的下拉式Button物件。
Dim btn As Button
Set btn = Toolbar1.Buttons.Add(, , , tbrDropDown, "New")
With btn.ButtonMenus
.Add , , "File"
.Add , , "Document"
.Add , , "Image"
End With
反應使用者的動作
當使用者點選按鈕時，Toolbar控制項會引發ButtonClick事件，此時執行的程式應為：
Private Sub Toolbar1_ButtonClick(ByVal Button As MSComCtlLib.Button)
Select Case Button.Key
Case "New"
Call mnuFileNew_Click
Case "Save"
Call mnuFileSave_Click
' And so on.
End Select
End Sub
Visual Basic 6引進了兩個新事件，兩個都跟下拉式選單有關聯。當使用者開啟下拉式選單時會引發ButtonDropDown事件。可以使用此事件來建立或修改作用中選單－例如，設定個別ButtonMenu項目的Visible或Enabled屬性或增加新的選單項目：
Private Sub Toolbar1_ButtonDropDown(ByVal Button As MSComctlLib.Button)
' Make the "Open | Image" command unavailable if necessary.
If Button.Caption = "Open" Then
Button.ButtonMenus("Image").Enabled = ImagesAreEnabled
End If
End Sub
當使用者選擇下拉式選單的指令後會引發ButtonMenuClick事件：
Private Sub Toolbar1_ButtonMenuClick(ByVal ButtonMenu As
MSComctlLib.ButtonMenu)
Select Case ButtonMenu.Key
Case "Document"
Call mnuFileNewDocument
Case "Image"
Call mnuFileNewImage
End Select
End Sub
自訂Toolbar控制項
您可讓使用者自訂Toolbar控制項。有兩個方法可以達到這個目的：設AllowCustomization屬性為True以便讓使用者在工具列上連按兩下滑鼠進入自訂模式，或藉由程式執行Toolbar的Customize方法來進入自訂模式。若只要提供此能力給有限的使用者時，就必須採用下面的方法了：
Private Sub Toolbar1_DblClick()
If UserIsAdministrator Then Toolbar1.Customize
End Sub
無論選擇哪個方法，最後都會關閉自訂工具列對話方塊，如圖10-18所示。
| 圖10-18自訂工具列對話方塊。 |
當使用者關閉此對話方塊時，Toolbar控制項會引發Change事件。（小心：即使使用者沒有改變工具列的版面時，仍會引發此事件）。在此事件處理程序中，應要執行SaveToolbar方法，其語法如下：
SaveToolbar Key, Subkey, Value
Key是Registry索引鍵名稱，SubKey是Registry子索引鍵名稱，而Value則是Registry值的名稱；這些參數定義一個在系統Registry的位置、其儲存工具列的版面。例如，可使用它們依據不同的應用程式名稱、登入的使用者與特定的工具列來儲存不同版面：
Private Sub Toolbar1_Change()
Toolbar1.SaveToolbar "MyApplication", UserName, "MainFormToolbar"
End Sub
使用RestoreToolbar方法來還原設定，一般都在Form_Load事件程序內執行：
Private Sub Form_Load()
Toolbar1.RestoreToolbar "MyApplication", UserName, "MainFormToolbar"
End Sub
說明
很奇怪的，RestoreToolbar方法會引發Change事件。這種行為通常沒關係，只是事件程序中的程式再度把工具列存到Registry內罷了（只不過在表單載入時增加些負荷而已）。然而，如果Toolbar物件的Change事件程序包含其他，如極費時的敘述，則可能會減慢程式，甚至引發不可預期的錯誤。
當自訂工具列對話方塊開啟時，使用者可刪除已存在的按鈕，恢復原先被刪除的按鈕，或改變工具列上按鈕的順序。如果要讓使用者增加按鈕，必須在設計時建立那些按鈕，執行該程式，納入自訂化Toolbar，並刪除這些額外的按鈕。被刪除的按鈕會在自訂工具列對話方塊的左方方塊列表中出現，以便讓使用者恢復之。
TabStrip控制項
頁籤式對話方塊已成為Windows應用程式的標準。Visual Basic擁有兩個控制項來實作這類對話方塊：TabStrip通用控制項和SSTab控制項。現在先介紹TabStrip控制項，
第十二章 再介紹SSTab控制項。關於TabStrip控制項最重要的一件事是：它並不是一個收納器（Container），換句話說，它提供一個介面，其只能顯示一些頁籤和反應使用者對於它的點選。開發者需依靠哪個頁籤被選取來決定哪一群的控制項是否顯示。如此會使得運用此控制項變得很麻煩且乏味，這也就是為什麼許多開發者寧可選用真正的收納器，且在設計時就可切換頁籤的SSTab控制項。不過依筆者的想法，TabStrip在其他方面還是很有用的。
TabStrip控制項包含Tabs集合，其依順序包含Tab物件。您必須了解其架構以便善用其能力。
設定設計階段屬性
在放置TabStrip控制項後，必須設定一般的屬性且增加些頁籤。可以在屬性頁完成這兩項工作，開啟的方式為在控制項上按右鍵並選擇屬性選項就能顯示。
一般性的屬性
屬性頁的一般頁籤可設定一般性的屬性，如圖10-19所示。第一個需要設定的屬性為Style，其能改變控制項的外貌。大部分的情況下保持為預設值0-tabTabs（控制項成為頁籤的集合）即可，也可以設為1-tabButtons（頁籤會由按鈕所取代，且無外框）或2-tabFlatButtons（如同tabButtons，但按鈕是平面的）。在後面兩個例子中，可以設定Separators屬性為True來隔開按鈕。這些樣式的組合如圖10-20所示。
TabFlatButton設定是首次出現在Visual Basic 6中，Separator屬性也是。其他Visual Basic 6的新屬性還有TabMinWidth、Placement、TabStyle、HotTracking和MultiSelect。
| 圖10-19 TabStrip控制項屬性頁的一般頁籤。 |
| 圖10-20 關於TabStrip控制項的各種style。 |
如果要讓頁籤不全在同一行出現的話，只要將MultiRow屬性設為True便可建立多行的頁籤。可將TabWidthStyle屬性設為0-tabJustified、1-tabNonJustified或2-tabFixed來選擇頁籤不同的樣式。如果要修正頁籤寬度，可調整TabFixedWidth和TabFixedHeight屬性。若頁籤寬度是須視情況而定的話，可設定TabMinWidth屬性來作為最小寬度。
Placement屬性決定頁籤出現的位置，在控制項的頂端（預設值）、底部、左方或右方邊框。TabStyle屬性會影響執行時具有多行TabStrip控制項的行為：當設此屬性為1-tabTabOpposite時，所有在現行列之前的列會顯示相對於控制項的另一邊。
一些設計階段的布林屬性會影響控制項的外貌。可設定HotTracking屬性為True來啟動即時追蹤（但只在Style為tabFlatButton時）。如果Multiselect屬性為True，則使用者能藉由按著Ctrl鍵來選擇多個頁籤。（只在Style為tabButton或tabFlatButton時）。最後，若ShowTips屬性為True時，控制項會顯示滑鼠所指向頁籤的ToolTipText。
Tab物件
當設定好重要的一般屬性後，就可在屬性頁的Tabs頁籤建立頁籤（有些混淆是嗎？那是第二個頁籤...）。唯一的非選擇性屬性是Caption。Key屬性是用來識別Tabs集合中的頁籤，而Tag和ToolTipText的意義和作用與以往相同。
在每個頁籤可顯示圖示。但必須載入所有的圖片到ImageList控制項內，然後在TabStrip的ImageList屬性中引用此控制項。然後，可以將要顯示圖片的索引指定給Tab的Image屬性。
準備子收納器
因為TabStrip控制項不是收納器控制項，所以無法直接將子控制項放置在其表面。這可能是此控制項最大的限制：這對於控制項執行時的能力沒有影響，但卻讓設計時變得有點麻煩。執行時，當某頁籤被點選時，必須顯示該頁籤內所有的控制項，和屬於其他頁籤的隱藏子控制項。
實際上，處理子控制項最合宜的方法是在表單上建立一些收納器控制項-例如，PictureBox或Frame控制項。這些控制項應作成控制陣列，以便容易管理。這些收納器放在表單的哪裡並不重要，因為執行時還會移動與改變其大小。
假設現在有個具有三個頁籤的TabStrip控制項。您可以建立三個PictureBox控制項，如圖Figure 10-21所示，然後把子控制項放置在每個PictureBox內。請把收納器放在不同的地方，以便在設計時可輕易地找到它們，並用Ctrl+J鍵讓它們移到最上層。若先設定收納器有可見的邊框，然後於執行時再隱藏邊框則會執行得較順暢些。
| 圖10-21 使用PictureBoxes來容納TabStrip控制項的子控制項。 |
執行階段的運作
大多數的情況中，只會使用TabStrip控制項的部份功能。事實上，大多數的應用程式只需要在設計時期顯示定義頁面，很少需要建立新的。本節將說明程式中關於此控制項最常使用的功能。
移動與改變收納器的大小
假如你照著之前的建議，使用Frame或PictrueBox控制項作為子控制項的收納器的話，那麼在表單變成可見前，必須移動及改變其大小。這些動作通常會在Form_Load事件中執行，並透過TabStrip控制項的ClientLeft、ClientTop、ClientWidth及ClientHeight屬性以控制那些收納器應要移到何處。假如它們有邊框的話，也需要隱藏。下列的程式假設所有的PictrueBox收納器控制項屬於一個picTab控制項陣列：
Private Sub Form_Load()
Dim pic As PictureBox
For Each pic In picTab
pic.Move TabStrip1.ClientLeft, TabStrip1.ClientTop, _
TabStrip1.ClientWidth, TabStrip1.ClientHeight
pic.BorderStyle = 0
Next
End Sub
選擇現行收納器
對於使用者的點選動作，要做出反應－讓被點選頁籤所對應的收納器成為可見。透過SelectItem屬性可得知哪個頁籤被點選。
Private Sub TabStrip1_Click()
Dim pic As PictureBox
For Each pic In picTab
' The expression on the right returns True for one picture box.
' (Control arrays are zero-based; Selected.Index is one-based.)
pic.Visible = (pic.Index = TabStrip1.SelectedItem.Index - 1)
Next
End Sub
當Click事件引發時，SelectedItem屬性表示現行的頁籤。若要知道點選前的頁籤為何，必須將此值存於表單層級的變數。或者可在Click事件引發前的BeforeClick事件中捕捉使用者的動作。此事件讓程式在離開現行頁籤前，檢查其資料的正確性，也可藉此取消此點選。下面為範例程式碼：
Private Sub TabStrip1_BeforeClick(Cancel As Integer)
Select Case TabStrip1.SelectedItem.Index
Case 1
' Refuse to move until the user types something in this field.
If txtUserName.Text = "" Then Cancel = True
Case 2
' Validation code for second tab
Case 3
' Validation code for third tab
End Select
End Sub
也可透過程式來選擇頁籤，藉由指定值給SelectedItem屬性即可。可使用下列其中之一的語法：
' Both statements select the second tab. Set TabStrip1.SelectedItem = TabStrip1.Tabs(2) TabStrip1.Tabs(2).Selected = True
當透過程式選擇頁籤時，BeforeClick與Click事件也會引發。
如果TabStrip的MultiSelect屬性為True的話，可同時讓多個Tab物件的Selected屬性為True。可用DeselectAll方式快速地取消選取所有頁籤。最後藉由設定Highlighted屬性為True，可強調一個以上的頁籤而無須顯示其內容：
' Highlight the second tab. TabStrip1.Tabs(2).Highlighted = True
新建與移除Tab物件
可在執行時期新建頁籤，方法為使用Tabs集合的Add方式，語法如下：
Add([Index], [Key], [Caption], [Image]) As Tab
Add方法的參數為要建立Tab物件的Index、Key、Caption與Image屬性。因為此方法會傳回新增物件的引用，因此可使用下列技術來設定其他屬性：
With TabStrip1.Add(, , "Authentication")
.ToolTipText = "Click here to change authentication settings"
.Tag = "ABC123"
End With
可在執行時期，用Tabs集合的Remove方式來移除存在的Tab物件，且可用集合的Clear方式來移除所有頁籤。
StatusBar控制項
許多應用程式會在視窗的底部顯示資訊。使用者在Visual Basic裡建立此種介面最簡單的方法是使用StatusBar控制項。
StatusBar控制項包含一個Panels集合，其內含Panel物件。Panel物件是狀態列的一個區域，可給定樣式來顯示訊息。StatusBar控制項提供數種自動的樣式（例如Date、Time與Shift鍵的狀態），加上通用的Text樣式，可在Panel物件中顯示任何字串。StatusBar控制項還有簡單文字（Simple Text）模式，其只有一個寬廣的Panel物件，用來顯示較長的文字訊息。
設定設計階段屬性
屬性頁的一般頁籤所包含的屬性沒什麼特別的。理論上，可設定Style屬性為0-sbrNormal（預設值）或是1-sbrSimpleText，且可指定SimpleText屬性，其顯示將如其名。不過在實作上，我們幾乎不會改變預設值，因為很少建立只顯示文字訊息的StatusBar控制項。事實上，假若要那樣做的話，最好用較單純的Label控制項或Align為vbAlignBottom的PictureBox控制項。在此頁籤上另一個屬性為ShowTips，其讓每個Panel物件的ToolTipText屬性變得可用。
現在到屬性頁的Panels頁籤來建立Panel物件，如圖10-22所示。每個Panel物件有許多屬性可決定其外觀與行為。其較有趣的屬性是Style，它決定了Panel內部要顯示的東西。其預設值是0-sbrText，顯示了Text屬性的字串。您可使用Panel物件作為特殊鍵狀態的指示，將之設定為1-sbrCaps、2-sbrNum、3-sbrIns或4-sbrScrl其一即可。也可以將之設成5-sbrTime或6-sbrDate來自動地顯示現在的時間或日期。
| 圖10-22 StatusBar控制項屬性頁的Panels頁籤。 |
如先前所說的，當Style為sbrText時，Text屬性是顯示在Panel物件上的字串。Key是用來識別在Panels集合中Panel物件之可選擇的索引鍵；Tag與ToolTipText的意義與以往相同。Alignment屬性決定Panel內容的位置（0-sbrLeft、1-sbrCenter或2-sbrRight）。Bevel屬性決定Pane邊界的形態：其預設值是1-sbrInset，但可改為2-sbrRaised或選擇沒有3-D邊界的0-sbrNoBevel。
MinWidth屬性是Panel物件的原始大小（單位為twips）。當表單的大小有變化時，AutoSize屬性會影響Panel物件的行為：而0-sbrNoAutoSize建立的是固定大小的Panel。1-sbrSpring表示Panels會隨著其父表單的大小而變化。（當許多Panels都如此設定時，它們會相對地收縮或展開）。2-sbrContents則表示Panels的寬度決定於其內容。
可以在Panel內顯示圖示或圖片。可於設計階段藉由從磁碟載入圖片來達成這個功能。注意在通用型控制項中，這是例外事項，一般來說，這個動作都是藉由ImageList控制項來完成。而這樣做的理由是每個Panel可能會載入不同大小的圖片，而ImageList控制項只能包含相同大小的圖片。
執行階段的運作
在執行階段，您不會想在StatusBar控制項上進行任何運作。不過可能需要去改變給定的Panel物件（Style屬性是0-sbrText）的Text屬性，如下面的例子：
' Display a message in the third panel. StatusBar1.Panels(3).Text = "Hello World!"
對於較長的訊息，可以改變StatusBar控制項的Style屬性，且指定該字串給其SimpleText屬性：
' Display a message in the entire status bar. StatusBar1.Style = sbrSimple StatusBar1.SimpleText = "Saving data to file..." ' A lengthy operation ' ... ' Remember to restore the Style property. StatusBar1.Style = sbrText
建立及移除Panel物件
在執行時期，很少會建立及移除Panel物件，不過還是得知道當需要時是可以這樣做的。您可使用Panels集合的Add方法達成此動作，其語法如下：
Add([Index], [Key], [Text], [Style], [Picture]) As Panel
每個參數對應到要被建立的Panel物件的屬性。例如，下列程式要在StatusBar控制項最左邊的位置建立一個新的Panel：
' Use Index = 1 to place this item before all other Panels.
With StatusBar1.Panels.Add(1, "temporary", "Hello World", sbrText)
.Alignment = sbrCenter
.Bevel = sbrNoBevel
.AutoSize = sbrContents
End With
可使用Panels集合的Remove方式移除單一Panel物件，且可用Clear方式移除所有Panel物件。
回應使用者的動作
StatusBar控制項包含一對事件，PanelClick與PanelDblClick。顧名思義，當使用者對Panel物件按一下或連續按二下滑鼠鍵時會引發這些事件。被按下的Panel會被當成此事件的參數傳入。下列程式說明了如何讓使用者藉由連續按二下來修改Panel內容。
Private Sub StatusBar1_PanelDblClick(ByVal Panel As MSComctlLib.Panel)
Dim s As String
If Panel.Style = sbrText Then
s = InputBox("Enter a new text for this panel")
If Len(s) Then Panel.Text = s
End If
End Sub
創造動態圖示
Panel物件包含Picture屬性。通常會在設計階段設定此屬性，但也可指定圖片給此屬性。例如可用不同的圖片建立動態圖示。這個竅門是先載入所有圖片到Image控制項陣列內，然後在Timer控制項的Timer事件函式中依序地指定。（見圖10-23.）
Private Sub Timer1_Timer()
Static n As Integer
' Show the next image.
StatusBar1.Panels("moon").Picture = imgMoon(n).Picture
n = (n + 1) Mod 8
End Sub
| 圖10-23 編輯面板文字並進行簡易動畫的範例程式。 |
鎖定鍵狀態的切換
雖然StatusBar控制項能顯示Caps、Num、Scroll及Insert鍵的狀態，但卻無法讓使用者透過滑鼠的點選來切換（而這可能是大多數使用者想要的）。很幸運地，只需要藉由API函數，並在Click或DblClick事件函式中撰寫些程式碼就可達成這項功能：
' API declarations.
Declare Function GetKeyboardState Lib "user32" (KeyState As Byte) As Long
Declare Function SetKeyboardState Lib "user32" (KeyState As Byte) As Long
Private Sub StatusBar1_PanelDblClick(ByVal Panel As MSComctlLib.Panel)
Select Case Panel.Style
Case sbrCaps: ToggleKey vbKeyCapital
Case sbrNum: ToggleKey vbKeyNumlock
Case sbrScrl: ToggleKey vbKeyScrollLock
Case sbrIns: ToggleKey vbKeyInsert
End Select
StatusBar1.Refresh
End Sub
Sub ToggleKey(vKey As KeyCodeConstants)
Dim keys(255) As Byte
' Read the current state of the keyboard.
GetKeyboardState keys(0)
' Toggle bit 0 of the virtual key we're interested in.
keys(vKey) = keys(vKey) Xor 1
' Enforce the new keyboard state.
SetKeyboardState keys(0)
End Sub
說明
雖說ToggleKey程序總是運作得很正常，不過筆者發現在Windows NT系統下，鍵盤LED指示並不會反應切換鍵的新狀態。
放置控制項在狀態列上
雖然StatusBar控制項提供許多屬性，但仍有些不足。例如，不能改變個別Panel物件的背景顏色，也不能在Panel內顯示ProgressBar，這是許多Windows應用程式都有的特色。很幸運地，有一個簡易的技巧可以讓你克服這些限制。
StatusBar控制項不是容納器，所以不能真的放置其他控制項-例如ProgressBar-到StatusBar內。但可將控制項放在StatusBar上，使之看起來就像在裡面一樣。透過Panel物件的Left及Width屬性可達成這樣的效果。下列程式放置ProgressBar控制項於特定的Panel上，模擬進行中的ProgressBar，然後再恢復Panel原始外觀：
Private Sub cmdProgress_Click()
Dim deltaY As Single, pnl As Panel, v As Single
' Account for two pixels around the Panel.
deltaY = ScaleY(2, vbPixels, vbTwips)
' Get a reference to the Panel object, and hide its bevel.
Set pnl = StatusBar1.Panels(1)
pnl.Bevel = sbrNoBevel
' Move the progress bar into position and in front of the status bar.
ProgressBar1.Move pnl.Left, StatusBar1.Top + deltaY, _
pnl.Width, StatusBar1.Height - deltaY
ProgressBar1.Visible = True
ProgressBar1.ZOrder
' Let the progress bar grow.
For v = 1 To 100 Step 0.1
ProgressBar1.Value = v
DoEvents
Next
' Restore original visibility state and bevel.
ProgressBar1.Visible = False
pnl.Bevel = sbrInset
End Sub
假如表單是不能變化大小的話，則此技巧是很完美的。除此之外，當表單是可變化大小時，也應該移動ProgressBar控制項，只要在Form_Resize事件中加入適當的程式碼即可。詳見隨書光碟的範例程式原始碼。
ProgressBar控制項
ProgressBar控制項的用途為告知使用者較長運算的進度。此控制項是MsComCtl.OCX檔案內的控制項中最簡單的，因為它沒有任何相關物件，且未包含任何自訂事件。
設定設計階段屬性
將ProgressBar控制項放置於表單後，必須於設計階段設定幾個屬性；大部份情況下，接受預設值即可。最重要的屬性是Min與Max，其決定ProgressBar可顯示的最小及最大值。
Visual Basic內的ProgressBar控制項包括兩個新屬性，Orientation及Scrolling。前者可建立垂直的ProgressBar；後者可選擇標準間隔狀或平滑狀的ProgressBar，如圖10-24。亦可於執行時期改變這些值。
執行階段的運作
關於ProgressBar控制項執行時期的作用沒什麼特別的。實作上，唯一須透過程式來作的只有設定Value屬性值（須介於Min到Max間）。若給定的值不在Min與Max範圍內，會導致錯誤380「不正確的屬性值」。如先前所提的，ProgressBar控制項沒有任何自訂事件。
| 圖10-24 ProgressBar控制項的Orientation、Scrolling、Appearance與BorderStyle屬性的作用。 |
只有兩個屬性會影響控制項的外觀-Appearance與BorderStyle。圖10-24顯示了這些屬性可能的組合結果。
Slider控制項
Slider控制項用來讓使用者選擇一定範圍的數值。觀念上，它近似ScrollBar控制項，許多屬性、事件也與它相同。主要的差別在於只有一種Slider控制項，其可建立垂直與水平的Slider。Slider控制項也支援範圍選取模式，其允許使用者選擇一個範圍值而不是單一值。
設定設計階段屬性
將Slider控制項放置於表單後，應該於其上按滑鼠右鍵並選擇屬性選項。在屬性頁的 一般 頁籤中，可設定Min、Max、SmallChange及LargeChange屬性，它們的意義與結果與HScrollBar及VscrollBar控制項一樣。在該頁籤，還可設定SelectRange屬性，但這項動作大多於執行時期才進行。（詳見本章稍後的
〈範圍選取模式〉 ）。在外觀頁籤，可設定少數特屬於此控制項的屬性。Orientation屬性設定Slider的方向。TickStyle屬性決定Slider是否要出現刻度與其顯示於何處。（允許的值是0-sldBottomRight、1-sldTopLeft、2-sldBoth與3-sldNoTicks）。TickFrequency屬性間接決定要顯示多少刻度。例如如果Min是0及Max是10（預設設定），TickFrequency若為2則會顯示6個刻度。TextPosition屬性會決定ToolTip要顯示在哪裡。(見本章稍後的 〈顯示ToolTip值〉 )。
執行階段的運作
在大部分的實作中，可在執行時期將Slider控制項當成是捲軸控制項：Slider控制項包含Value屬性及Change、Scroll事件，其作用和捲軸相同。下列章節簡短地說明Slider控制項的兩個特性。
顯示ToolTip值
當指示器被使用者拖曳時，Slider控制項可隨著指示器而顯示ToolTip。可使用Text與TextPosition兩個屬性去控制這個新的Visual Basic 6的特色。前者是顯示在ToolTip上的字串；後者決定ToolTip相對於指示器的位置。（其值可以是0-sldAboveLeft與1-sldBelowRight）。也可以在設計階段，於屬性頁的外觀頁籤中設定TextPosition屬性。
通常會使用這些屬性來顯示目前的ToolTip值。為了如此，只需在Scroll事件程序中加入下列敘述：
Private Sub Slider1_Scroll()
Slider1.Text = "Value = " & Slider1.Value
End Sub
範圍選取模式
Slider控制項可支援顯示範圍值而非單一值，如圖10-25所示。為了顯示一個範圍，須透過許多屬性。首先，藉由設定SelectRange屬性值為True進入範圍選取模式－例如，當使用者按著Shief鍵然後點選控制項時。
Dim StartSelection As Single
Private Sub Slider1_MouseDown(Button As Integer, Shift As Integer, _
x As Single, y As Single)
If Shift = vbShiftMask Then
' If the shift key is being pressed, enter select range mode.
Slider1.SelectRange = True
Slider1.SelLength = 0
StartSelection = Slider1.Value
Else
' Else cancel any active select range mode.
Slider1.SelectRange = False
End If
End Sub
| 圖10-25 可使用Slider控制項選擇一個範圍，也可在指示器被拖曳時於其旁顯示ToolTip。 |
在進入範圍選取模式後，可藉由SelStart及SelLength屬性控制選取間隔。可在Scroll事件程序中做這件事。因為SelLength不可是負值，所以必須分成兩種案例來處理：
Private Sub Slider1_Scroll()
If Slider1.SelectRange Then
' The indicator is being moved in SelectRange mode.
If Slider1.Value > StartSelection Then
Slider1.SelStart = StartSelection
Slider1.SelLength = Slider1.Value - StartSelection
Else
Slider1.SelStart = Slider1.Value
Slider1.SelLength = StartSelection - Slider1.Value
End If
End If
End Sub
ImageCombo控制項
ImageCombo控制項是初次包含在Visual Basic內。概括地說，ImageCombo控制項是個支援圖片的下拉式方塊，且對不同的項目可有不同的縮排。Windows內部所使用的檔案通用對話方塊就是使用此控制項。
自設計者的觀點來看， ImageCombo控制項及標準ComboBox控制項主要的不同是ImageCombo控制項使用物件導向結構，且包含ComboItems集合，它涵蓋了所有的ComboItem物件。
設定設計階段屬性
ImageCombo控制項與標準ComboBox控制項很類似，所以在此只討論其差異性。於設計階段，只需要設定兩個屬性。ImageList屬性是ImageList控制項的引用，其包含要顯示在每個ComboItem物件旁的圖片。Indentation屬性表示所有ComboItem物件預設的縮格，其值表示縮排的單位，每個單位為10 pixel。而各自的ComboItem物件可再給予不同的值於此屬性，如此會覆蓋預設值（預設值的設定可於設計時期在屬性視窗給定或執行時期透過程式撰寫）。
與ComboBox控制項一樣，ImageCombo控制項也可連結到某資料來源，以支援所有常見的Dataxxxx屬性。
執行階段的運作
ImageCombo控制項包含許多ComboBox控制項所支援的屬性，包括ForeColor、BackColor、Text、SelText、SelStart、SelLength與Locked。而它所支援的事件，ComboBox都有。
當增加項目於這個控制項時，會發現ImageCombo控制項及ComboBox控制項的差異。ImageCombo控制項不支援AddItem方法。相反地，可用ComboItems集合的Add方法來增加項目，語法如下：
Add([Index],[Key],[Text],[Image],[SelImage],[Indentation]) As ComboItem
Index決定新的ComboItem的位置，Key是其在集合的索引鍵，Text是顯示的字串，Image為關聯的圖像（為其在ImageList控制項內的索引或索引鍵），當此項目被選擇時，SelImage表示其顯示的圖像，Indentation為縮排等級（單位為10 pixel）。此語法可增加一個新的ComboItem且以一個動作設定其所有屬性。下列為載入所有的磁碟機代號與標籤到ImageCombo控制項的函式，結果如圖10-26所示：
Sub LoadDrivesIntoImageCombo(ImgCombo As ImageCombo)
Dim fso As New Scripting.FileSystemObject, dr As Scripting.Drive
Dim drLabel As String, drImage As String
' Assume that the ImageCombo control is linked to an ImageList
' control that includes three icons with the following key names.
ImgCombo.ComboItems.Add , , "My Computer", "MyComputer"
For Each dr In fso.Drives
' Use a different image for each type of drive.
Select Case dr.DriveType
Case Removable: drImage = "FloppyDrive"
Case CDRom: drImage = "CDDrive"
Case Else: drImage = "HardDrive"
End Select
' Retrieve the letter and (if possible) the volume label.
drLabel = dr.DriveLetter & ": "
If dr.IsReady Then
If Len(dr.VolumeName) Then drLabel = drLabel & "[" & _
dr.VolumeName & "]"
End If
' Add an indented item to the combo.
ImgCombo.ComboItems.Add , dr.DriveLetter, drLabel, drImage, , 2
Next
' Select the current drive.
Set ImgCombo.SelectedItem = ImgCombo.ComboItems(Left$(CurDir$, 1))
End Sub
| 圖10-26 ImageCombo展示程式顯示系統中所有磁碟機的資訊。 |
透過程式選擇ComboItem物件有兩種方法：可使用ImageCombo控制項的SelectedItem屬性（如先前的函式），或可設定個別ComboItem物件的Selected屬性。
' Select the current drive (alternative method). Set ImgCombo.ComboItems(Left$(CurDir$, 1)).Selected = True
以個別的ComboItem物件來運作時有個有趣的地方，那就是無須刪除或增加它便可修改其Text屬性，正如同對待標準ComboBox般：
' Change the text of the first item. ImgCombo.ComboItems(1).Text = "My Computer"
可使用ComboItems集合的Remove方式來刪除個別的ComboItem，而若要刪除所有的項目，則可使用集合的Clear方式。
ImageCombo控制項只包含一個方式，GetFirstVisible，其會傳回控制項清單區中第一個ComboItem物件的引用。不過此方法沒什麼作用，因為沒有方法讓此第一個項目成為可見，因此無法透過程式捲動清單區的內容。
以上為包含在MsComCtl.ocx檔案內所有控制項的說明。下一章，將說明其他Visual Basic 6所附的Windows通用型控制項。