11. 視窗通用型控制項：第二部份
Animation控制項
Animation控制項能播放AVI檔案，所以可以在您的程式中播放簡單的動畫。該控制項只支援不含聲音、也沒有壓縮的AVI檔，或以Run-Length Encoding格式壓縮的AVI檔。若想要播放非上述的AVI檔時，會顯示錯誤訊息35752：「無法開啟AVI檔案」。
Animation控制項對於播放簡單的動畫格外有用，例如在Microsoft Visual Basic主要安裝目錄下\Common\Graphics\AVIs子目錄的那些檔案。舉例來說，當要在背景執行檔案複製作業時，可使用此控制項顯示從一個資料夾複製到另一個資料夾時的紙張飛行動畫，如圖11-1所示。
| 圖11-1 在書附CD中的展示程式讓您體驗Animation控制項。 |
Animation控制項延伸出三個主要的屬性。其中的Center和BackStyle只能在設定階段加以設定，在執行階段卻是唯讀的。如果Center屬性為True，AVI檔會位在Animation控制視窗的中央（原本在左上角播放）。BackStyle屬性可以是0-cc2BackstyleTransparent（預設值，顯示控制項的背景色）或1-cc2BackstyleOpaque（顯示AVI背景）。第三個屬性，AutoPlay，可以在任何時候加以設定。若設其為True，則當檔案被載入控制項時，會自動播放AVI檔案。（如果做了這個設定，必須經由程式碼設定AutoPlay為False來停止播放）。
沒有設計階段的屬性將決定在執行階段哪個AVI檔案要被載入與顯示。為了要由程式碼來起始動畫，首先必須開啟AVI檔案，用的是Open方法：
Animation1.Open "d:\vb6\Graphics\AVIs\filecopy.avi"
如果AutoPlay屬性為True，AVI檔案會在被載入時開始播放。否則你就必須要透過程式碼（Play方法）去啟動它，下面是其語法：
Play [RepeatCount], [StartFrame], [EndFrame]
RepeatCount是動畫播放的次數；（預設值為-1，表示無限次。）StartFrame則是動畫的起始框架（預設值為0，第一個框架）；EndFrame是動畫的結尾框架（預設為-1，最後一個框架）。
有兩個方法可以停止播放動畫，而方法的選擇取決於用何種方法啟動該動畫。如果動畫為AutoPlay模式，便只能藉由設定AutoPlay屬性為False來停止它；如果用Play方法來啟動動畫，則可用Stop方法來停止它；如果不打算再重新播放同樣的AVI檔案，可以藉由Close方法來釋放記憶體空間，如下面的程式碼所示（假設AutoPlay屬性為False）：
Private Sub cmdStart_Click()
Animation1.Open "d:\vb5\graphics\AVIs\filecopy.avi"
Animation1.Play
End Sub
Private Sub cmdStop_Click()
Animation1.Stop
Animation1.Close
End Sub
Animation控制項不會包含任何事件。這表示您無法得知動畫何時結束。
UpDown控制項
UpDown控制項提供一個簡易卻有效的方法建立旋鈕，所謂旋鈕在一般Windows應用程式指的是：顯示在數字欄位右側，可以讓使用者用滑鼠點選來增加或減少欄位值的按鈕。建立這種旋鈕並不太難－不過可以使用小的VScrollBar控制項，或使用兩個Style為1-Graphical的小按鈕－不過UpDown控制項有更多好處，且其建立與使用遠較其他方法還要簡單。
UpDown控制項最詭異的特徵是：可以在設計階段連結其他的控制項－稱為協同（Buddy）控制項，且可以選擇UpDown控制項影響Buddy控制項的哪個特定屬性。此外，還可以設定捲動範圍與每次的增加量。所以在大部分情況下，並不需要撰寫程式。
設定設計階段屬性
在UpDown控制項的一般頁籤中，大致會設定Alignment屬性，用來決定UpDown控制項相對於其Buddy控制項的位置。（其值有0-cc2AlignmentLeft和1-cc2AlignmentRight）。在這個頁籤中，也可以設定Orientation屬性（0-cc2OrientationVertical或1cc2OrientationHorizontal）。Orientation屬性只能夠在設計階段加以設定，在執行階段是唯讀的。
在屬性頁的協同頁籤中選擇 buddy 控制項（參考圖11-2）。可在第一個欄位中鍵入控制項的名稱或點選 自動決定 核選方塊。若用後者，UpDown控制項會自動選擇前一個控制項（依據TabIndex順序）作為其Buddy控制項。在選了一個Buddy控制項後，另兩個欄位就變成可用狀態了。在協同屬性（BuddyProperty）下拉清單中，選擇Buddy控制項的哪個屬性是要被UpDown控制項所影響的。（若沒有選擇，會使用Buddy控制項的預設屬性。）您可以將與 協同控制項同步 （SyncBuddy）屬性設為True，如此會使得UpDown控制項自動修正Buddy控制項的協同屬性。
通常會選擇 TextBox 控制項作為 UpDown 控制項的協同控制項，且設定Text屬性為協同屬性。不過當然也能把UpDown控制項連結到其他種控制項的屬性（例如Left或Width）。不過不能使用輕量的無視窗控制項作為協同控制項。
| 圖11-2 UpDown控制項屬性頁中的協同頁籤可以讓您選擇協同控制項和協同屬性。 |
最後在屬性頁的捲動頁籤，UpDown控制項的Min和Max屬性表示Value屬性的允許範圍。Increment屬性是當使用者點選 UpDown 控制項的旋鈕，Value屬性的增加或減少量。如果Wrap屬性設為True，則當Value屬性超過Min或Max屬性時會循環。
執行階段的運作
如果UpDown控制項的SyncBuddy屬性設為True，您就不需要撰寫任何的程式來手動改變Buddy控制項的屬性。然而也有不能藉助此機制的時候，例如，UpDown控制項可能沒有協同控制項，或需要影響許多控制項或同一個控制項的多個屬性。（例如，藉由同時調整它的Width和Height屬性，可以放大或縮小控制項。）在這種情況下，您需要做的是在Change事件程序內撰寫程式碼，如同運作ScrollBar控制項般。
UpDown控制項包含兩個事件，可以有許多的靈活度：DownClick及UpClick事件。當滑鼠於UpDown控制項的任一個按鈕上放開時（在Change事件後）會引發這兩個事件。即使Value屬性已經達到它的Min或Max時，也會引發這些事件，如此使得DownClick和UpClick事件極為有用，特別是不想限制目前值的範圍時：
' Move all controls on the form pixel by pixel.
Private Sub UpDown1_DownClick()
Dim ctrl As Control
For Each ctrl In Controls
ctrl.Top = ctrl.Top + ScaleY(1, vbPixels, vbTwips)
Next
End Sub
Private Sub UpDown1_UpClick()
Dim ctrl As Control
For Each ctrl In Controls
ctrl.Top = ctrl.Top - ScaleY(1, vbPixels, vbTwips)
Next
End Sub
所有在設計階段所設定的屬性也能在執行階段經由程式碼來修改，除了Orientation屬性外。例如，可以用下列程式改變協同控制項和協同屬性：
Set UpDown1.BuddyControl = Text2 UpDown1.BuddyProperty = "Text"
BuddyControl屬性也能夠以協同控制項的名字來指定，例如：
UpDown1.BuddyControl = "Text2" ' This syntax even works with items of control arrays. UpDown1.BuddyControl = "Text3(0)"
當您在執行時改變協同控制項，UpDown控制項會自動移動到協同控制項的旁邊，此時該協同控制項會縮小以便容納UpDown控制項。
FlatScrollBar控制項
FlatScrollBar控制項取代原本的HscrollBar和VscrollBar：您可以用同樣的名字以FlatScrollBar控制項來代替HscrollBar或VscrollBar控制項，如此程式仍會如往常般的運行無誤。依照它Orientation屬性的值，這個控制項可成為水平或垂直的捲軸。此屬性也能在執行時被修改。
您可以在設計階段設定FlatScrollBar控制項的所有的屬性，如圖11-3所示。這個控制項支援三個圖像格式：平面、立體（類似原本的ScrollBar控制項）和Track3D（平面捲軸，但當滑鼠移過就會變成立體，極像Microsoft Encarta的捲軸）。在設計階段，可藉由設定Appearance屬性為下列其中的一個值：0-fsb3D、1-fsbFlat或2-fsbTrack3D來選擇圖像格式。
| 圖11-3 FlatScrollBar控制項屬性頁的一般頁籤。 |
Arrows屬性使您可以選擇是否讓捲軸末端的一個或兩個箭頭成為可用，可設定為1-cc2LeftUp或2-cc2RightDown；預設值為0-cc2Both，可讓兩個箭頭都是可用的。Min、Max、LargeChange、SmallChange和Value屬性有的意義與HScrollBar和VScrollBar控制項的相同屬性同義。
在執行階段要反應使用者對FlatScrollBar控制項的動作與一般捲軸一樣，要藉由Change和Scroll事件來執行程式碼。FlatScrollBar唯一在執行時需要修改的屬性是Arrows－例如，當捲軸已經抵達最小或最大值時，取消適當的箭頭。您通常在Change事件程序中會使用到這個方法：
Private Sub FlatScrollBar1_Change()
' This is a horizontal FlatScrollBar.
If FlatScrollBar1.Value = FlatScrollBar1.Min Then
FlatScrollBar1.Arrows = cc2RightDown
ElseIf FlatScrollBar1.Value = FlatScrollBar1.Max Then
FlatScrollBar1.Arrows = cc2LeftUp
Else
FlatScrollBar1.Arrows = cc2Both
End If
End Sub
MonthView控制項
Visual Basic 6有兩個關於日期的新通用控制項：MonthView控制項和DateTimePicker控制項。前一個是像月曆的控制項，而後者是個可輸入日期和時間的文字方塊控制項，兩者關係密切，因為當使用者在DataTimePicker控制項下拉鈕選擇日期時，使用的是MonthView控制項。
設定設計階段屬性
在配置MonthView控制項於表單後，可以在上面點選右鍵顯示它的屬性頁，如圖11-4所示。Value屬性即為控制項中所圈選的日期。（點選右邊的箭頭可先了解什麼是DateTimePicker控制項。）MinDate和MaxDate決定在MonthView控制項中，能被選擇的日期範圍；StartOfWeek屬性決定月曆最左側那行是星期幾。
| 圖11-4 設定MonthView控制項的設計階段屬性 |
許多布林屬性會影響控制項的外貌和功能。如果ShowWeekNumber為True，MonthView控制項會顯示各週週數。如果MultiSelect為True，使用者能選擇一個範圍的日期：這時，最多可連續選取的日數等於MaxSelCount屬性值。（預設為一星期。）ShowToday屬性決定是否要顯示「Today資訊」。
MonthView控制項最多能顯示12個月，而顯示的月數量是MonthRows和MonthColumns屬性的乘積。預設情況下，當使用者點選控制項的箭頭按鈕，所捲動的月數量等於顯示在控制項上的月數量，但可藉由把ScrollRate屬性設為非零值來改變此行為。
MonthView控制項還包含許多關於前景和背景顏色的屬性，而且容易搞混。圖11-5讓您了解如何使用ForeColor、TitleForeColor、TitleBackColor、MonthBackColor和TrailingForeColor屬性。（Trailing Days指屬於前個月或下個月的日子。）MonthBackColor屬性也影響星期幾名字的顏色和數目。奇怪的是，控制項也有標準的BackColor屬性，只是它幾乎沒有什麼作用，除了影響下方和右側邊框的線外。
| 圖11-5 關於MonthView控制項各獨立區域的顏色控制。 |
在這些設計階段的屬性中，可能需要注意幾個特殊屬性，包括DataSource、DataField、DataMember和DataFormat屬性。事實上，MonthView是個資料感知控制項，可以連結到標準Data控制項、RemoteDate控制項或任何ADO資料來源的日期欄位。
注意
若要將應用程式本土化，值得慶幸的是， MonthView控制項會自動調適自己到使用者的環境，而且正確地轉換所有月份和日期的名稱。不過實作上會有個小錯誤：Today資訊無法本土化，所以應該要設ShowToday屬性為False，然後提供別種形式的Today資訊。
執行階段的運作
使用MonthView有許多方法，不過有些並不明顯。大部分的人都知道可點選控制項標題附近的兩個箭頭來往後或往前一個月份。少數人還知道可在點選日期時，再按下[Shift]鍵便可選擇一定範圍的日期（如果MultiSelect為True）。然而，可能沒什麼人知道點選控制項標題的月份名稱會出現快捷功能表，用來選擇當年的任一月份。甚至點選年份會顯示兩個旋鈕讓使用者調整年份－前進或後退。（見圖11-6）。別忘了在操作手冊上提到這些隱藏功能，要不就把這些用法用Label控制項顯示在表單上。
| 圖11-6 此範例程式讓您了解MonthView控制項的所有進階特色。當您點選年份時，在標題區會顯示旋鈕。 |
取得當前的日期
除非需要執行特殊的運算，要不然在程式碼中使用MonthView控制項並不難。控制項有個Value屬性，可用來指定一個日期或讀取使用者所選擇的日期。您甚至不需要從Value屬性中獲得日、月與年份，因為控制項有Day、Month和Year屬性。很方便的是：這些屬性也可以被指定－例如，可以用程式來顯示下個月，如下：
If MonthView1.Month < 12 Then
MonthView1.Month = MonthView1.Month + 1
Else
MonthView1.Month = 1
MonthView1.Year = MonthView1.Year + 1
End If
DayOfWeek屬性傳回所選擇的日期是星期幾。同樣地，這個屬性是可以被寫入的，所以只要透過下列的程式碼，便可以選擇當周的星期一：
MonthView1.DayOfWeek = vbMonday
然而當MultiSelect為True時，Day、Month、Year和DayOfWeek屬性便無法加以設定。
注意
在使用MonthView控制項時，筆者發現一個意外的行為：如果現在控制項擁有駐點，而您點選同一個表單內的其他控制項時，這個被點選的控制項會獲得駐點，但卻沒引發Click事件，這可能會使您的使用者感到困惑。筆者發現這是因駐點在MonthView控制項時，在按鈕上按一下將不會發生預期的效果，這個錯誤可能會在以後的Service Pack中修復。在此時，這個問題的確難以處理，最後只能依靠MouseDown事件而非Click事件了，做法如下：
Dim MousePressed As Boolean ' A form-level variable
Private Sub cmdTryMe_MouseDown(Button As Integer, _
Shift As Integer, X As Single, Y As Single)
MousePressed = True
Call DoSomething
End Sub
Private Sub cmdTryMe_MouseUp(Button As Integer, _
Shift As Integer, X As Single, Y As Single)
MousePressed = False
End Sub
Private Sub cmdTryMe_Click()
' This event might be called as a response to a hot key
' or a click when the focus isn't on the MonthView control.
If Not MousePressed Then Call DoSomething
End Sub
Private Sub DoSomething()
' The code that must execute when the button is clicked
MsgBox "Button has been clicked!"
End Sub
回應範圍的選取
可以藉由MinDate和MaxDate屬性來限制使用者能選擇的日期範圍。如果MultiSelect屬性為True，則能選擇連續的日期。也可以用SelStart和SelEnd屬性來取得選擇的範圍（這些屬性傳回Data值。）而所能選擇日期的最大範圍取決於MaxSelCount屬性。
每一次使用者選擇新的日期，就會引發SelChange事件。這個事件接收選擇範圍的起始日期和結束日期，然後可以讓程式設計者取消運作。舉例來說，您可以拒絕假日的選取：
Private Sub MonthView1_SelChange(ByVal StartDate As Date, _
ByVal EndDate As Date, Cancel As Boolean)
Dim d As Date
' A Date variable can be used to control a For loop.
For d = StartDate To EndDate
If Weekday(d) = vbSunday Or Weekday(d) = vbSaturday Then
' Cancel the selection if the day is Sunday or Saturday.
Cancel = True
Exit For
End If
Next
End Sub
注意
MonthView控制項有個錯誤：除非使用者選擇三個或更多的日期，否則即使設定Cancel參數為True仍不會取消運作。這個錯誤將會在新版的控制項中修正，但目前並沒有什麼簡單的解決方法。（目前筆者使用的MsComCt2.ocx版本為6.00.8177。）
另外兩個事件－ateClick和DateDblClick，在使用者選擇新日期時會引發。當使用者點選日期，Visual Basic應用程式會接收SelChange事件和DateClick事件。如果在日期上按兩下，程式會依照順序接收SelChange、DateClick、DateDblClick和DateClick事件，所以要注意按兩下日期會引發兩次DateClick事件。兩個事件都會接收一個參數，若日期被點一下或點兩下：
Private Sub MonthView1_DateDblClick(ByVal DateDblClicked As Date)
Dim descr As String
descr = InputBox("Enter a description for day " & _
FormatDateTime(DateDblClicked, vbLongDate))
If Len(descr) Then
' Save the description (omitted) ...
' ...
End If
End Sub
尋找最理想的大小
MonthView控制項提供幾個方法來改變控制項的外貌，除了許多的顏色屬性外。例如，可以藉由指定適合的值給MonthRows和MonthColumns屬性以顯示12個月。然而在執行時改變這些屬性會發生一個問題，那就是無法控制MonthView的大小（因這端視月數、字形、線框和其他設定來決定）。為了幫助您決定MonthRows和MonthColumns屬性的最佳值，MonthView控制項支援ComputeControlSize方法。此方法以行和列的數目為第一個與第二個參數，並以第三個和第四參數作為計算後長與寬的傳回值。
' Evaluate the size of a MonthView control with 2 rows and 3 columns Dim wi As Single, he As Single MonthView1.ComputeControlSize 2, 3, wi, he
當您想在表單中展示最多月數時，會用到ComputeControlSize。下面的例子摘錄在隨書光碟的範例程式中：
Private Sub cmdTile_Click()
' Find the best value for MonthRows and MonthColumns.
Dim rows As Integer, cols As Integer
Dim wi As Single, he As Single
For rows = 6 To 1 Step -1
' Note how we avoid creating more than 12 months.
For cols = 12 \ rows To 1 Step -1
MonthView1.ComputeControlSize rows, cols, wi, he
If wi <= ScaleWidth _ MonthView1.Left And _
he < ScaleHeight _ MonthView1.Top Then
MonthView1.MonthRows = rows
MonthView1.MonthColumns = cols
Exit Sub
End If
Next
Next
End Sub
強調日期
MonthView控制項可讓設計者藉由粗體顯現的方式來強調某個日期。您可以使用GetDayBold事件函數來改變控制項的內容，如下範例：
' Display all Sundays and major holidays in boldface.
Sub MonthView1_GetDayBold(ByVal StartDate As Date, _
ByVal Count As Integer, State() As Boolean)
Dim i As Long, d As Date
d = StartDate
For i = 0 To Count - 1
If Weekday(d) = vbSunday Then
State(i) = True ' Mark all Sundays.
ElseIf Month(d) = 12 And Day(d) = 25 Then
State(i) = True ' Xmas time.
Else
' Deal here with other holidays...
End If
d = d + 1
Next
End Sub
GetDayBold事件接受三個參數：StartDate為控制項中的第一天（包含前個月的天數）、Count是可見的天數，而State為一個以零為底的布林陣列，包含Count元素值。因此要讓某個日期成為粗體，只需要設定State陣列中相對的值為True即可。
另一種方法並不透過GetDayBold事件函數：修改控制項中當前日期的bold屬性，可使用VisibleDays和DayBold屬性來達成這種方法。VisibleDays屬性接收一個從1到可見天數的索引值，並會傳回符合的Date值。這個屬性的問題是不容易知道控制項中有多少天數可見以及何者是索引的最大值。Visual Basic文件錯誤地說明索引值必定在1到42之中，卻沒考慮到MonthView控制項顯示多重月份的能力。最簡單的解決方法就是建立一個錯誤的處理機制，如同下面的敘述：
Dim tmpDate As Date
' Exit the loop when the index isn't valid any longer.
On Error GoTo EndTheLoop
For i = 1 To 366
' Visit each day.
tmpDate = MonthView1.VisibleDays(i)
Next
EndTheLoop:
' Get here when the index becomes invalid.
VisibleDays屬性傳回部分日期等於現在系統時間的Date值。當您要比較傳回的時間值是日期常數或變數時，此非正式的方法蠻有用的。
DayBold屬性以一個日期為參數，其關連到一個可視的日子並且可以設定或傳回該日子的粗體屬性。這個屬性可以用來同時設定許多日子，即使並未處理GetDayBold事件。一般會使用DayBold屬性搭配VisibleDays屬性，如同下面的程式：
Private Sub cmdMark_Click()
Dim i As Integer
On Error GoTo EndOfLoop
For i = 1 To 999
' Mark all Fridays.
If Weekday(MonthView1.VisibleDays(i)) = vbFriday Then
MonthView1.DayBold(MonthView1.VisibleDays(i)) = True
End If
Next
EndOfLoop:
End Sub
實作拖曳
MonthView控制項可以是拖曳的來源，因為它允許您透過此機制，複製日期到任何可接受字串的控制項。正確拖曳實作的關鍵是HitTest方法，其語法如下：
Area = MonthView1.HitTest(X, Y, HitDate)
Area是個數字，指向控制項中x與y座標所關連的某區域。（關於所有可能的傳回值，請參閱Visual Basic文件或隨書光碟所附的程式原始碼）。當函式傳回4-mvwCalendarDay時，HitDate變數值會是月曆中x和y座標所指向的日期。藉由這個方法，將會發現很容易實作一個有效率的拖曳程序。下述範例程式結果如圖11-6：
' Start a drag-and-drop operation.
Private Sub MonthView1_MouseDown(Button As Integer, Shift As Integer, _
X As Single, Y As Single)
' Exit if the right button isn't clicked.
If Button <> vbRightButton Then Exit Sub
' Exit if mouse isn't over a valid date.
If MonthView1.HitTest(X, Y, DraggedDate) <> mvwCalendarDay Then
Exit Sub
End If
' Now DraggedDate contains the date to be dragged,
' and we can start the drag operation.
MonthView1.OLEDrag
End Sub
Private Sub MonthView1_OLEStartDrag(Data As MSComCtl2.DataObject, _
AllowedEffects As Long)
' When this event fires, DraggedDate contains a valid date.
Data.SetData Format(DraggedDate, "long date")
AllowedEffects = vbDropEffectCopy
End Sub
上述的程式假定被滑鼠按鍵放開的控制項OLEDropMode屬性為2-Automatic。
DateTimePicker控制項
DateTimePicker控制項是針對日期和時間設計的文字方塊。這個文件方塊可以細分為幾個小區域，每個都是獨自的部分（日、月、年、時、分和秒）。這個控制項支援所有常用的日期和時間格式（包括自訂的格式）和傳回Null值的能力（如果使用者沒有選擇日期），甚至可以定義自訂的區域。
在執行時，使用者可以用左右箭頭來切換區域，並且可用上下箭頭增加和減少它們的值。還可以顯示下拉式的日曆（如果UpDown屬性為False）或使用附屬的旋鈕修改選取部分的值（若UpDown值為True時）。
設定設計階段屬性
預設情形下，一個向下的箭頭會在控制項的右方，如同標準的ComboBox控制項：點選箭頭會出現一個日曆，可讓使用者選擇日期而不用敲任何鍵。如果將UpDown屬性設為True，向下箭頭會被一對旋鈕取代，而只能讓使用者用滑鼠來增加或減少獨立區域的值。
CheckBox屬性若為True，在控制項左方會顯示一個核選方塊：如果使用者不想選擇任何日期，可以取消該方塊。（參考
圖11-7 ）DateTimePicker控制項有些屬性與MonthView控制項相同，例如，它包含Value屬性，能傳回使用者輸入的日期，而MinDate和MaxDate屬性定義日期的範圍。
下拉的月曆其實就是MonthView控制項，只是此MonthView一次只能顯示一個月。所以DateTimePicker控制項也包含MonthView控制項的所有顏色屬性，只不過在此每個屬性的名稱都改變了： CalendarForeColor、CalendarBackColor、CalendarTitleForeColor、CalendarTitleBackColor和CalendarTrailingForeColor。另外，控制項沒有顯示標準的ForeColor和BackColor屬性，因此雖然更改下拉式選單的外貌，卻無法以程式來改變控制項編輯區的預設顏色！
Format屬性影響在控制項顯示的資料，其可為下述值之一：0-dtpLongDate、1-dtpShortDate、2-dtpTime或3-dtpCustom。如果選擇自訂的格式，則可以指定適當的字串給CustomFormat屬性，此屬性接受與Format函數相同的格式化字串來顯示日期或時間資料。如下：
'Date is' dddd MMM d, yyy
上述程式的顯示結果如下：
Date is Friday Nov 5, 1999
如您所見，可以包含文字字串，只要用單引號括起來即可。而CustomFormat屬性也可以被用來建立自訂的區域。
| 圖11-7 DateTimePicker控制項的不同形式。 |
DateTimePicker控制項能連結到某資料來源，所以它還有DataSource、DataMember、DataField和DataFormat等屬性。當控制項連結到標準資料或RemoteData控制項時，並不支援DataFormat屬性；但在其他方面，可以使用Format和CustomFormat屬性修改顯示值的格式。
執行階段的運作
執行時，可藉由Value屬性或Year、Month、Day、DayOfWeek、Hour、Minute和Second屬性來設定和取得DateTimePicker的內容。例如，可以用程式來增加DateTimePicker控制項中某日期的月份，程式如下：
DTPicker1.Month = (DTPicker1.Month Mod 12) + 1 If DTPicker1.Month = 1 Then DTPicker1.Year = DTPicker1.Year + 1
如果CheckBox為True且使用者已取消選取方塊，所有相關的日期屬性會傳回Null。
DateTimePicker控制項涵蓋許多標準TextBox控制項所支援的事件，包括Change、KeyDown、KeyPress、KeyUp、MouseDown、MouseMove、MouseUp、Click和DblClick。所有的鍵盤與滑鼠事件都只跟控制項的編輯區有關，所以當月曆被拉出時，並不會引發這些事件。
當使用者點選向下箭頭時，DropDown事件會在下拉式月曆顯示前引發妰o表示UpDown屬性為False（預設值）。當使用者選擇下拉式日曆的日期時，CloseUp事件將會引發。不過這些事件並沒什麼用處，因為除了日曆外，幾乎沒什麼控制項可以拿來使用，當然改變顏色也可以。當使用者選擇下拉式日曆的日期，Change事件會在CloseUp事件前引發。
注意
DateTimePicker控制項有個錯誤，那就是在執行時無法同時指定值給MinDate和MaxDate屬性。當指定其中的某個屬性值時，另一個會被設定為12/31/1999。這奇特行為的原因和可能解決的方法請參閱Microsoft Knowledge Base的Q198880一文。
管理callback欄位
DateTimePicker最詭異的特色是具有定義自訂區域的能力，也叫做callback欄位。為了定義callback欄位，須使用由一個以上的X字元所構成的字串，將之指定給CustomFormat屬性。可以定義多個callback欄位，只要藉由使用不同個X數目的字串。舉個例子，下述定義一個日期欄位，有兩個callback欄位：
DTPicker1.CustomFormat = "MMM d, yyy '(week 'XX')' XXX"
在下面程式裡，XX區被定義為從一月1號起的週數，而XXX區則是假日的名稱（如果該日是假日的話）。
當定義callback欄位後，還必須定義它的最大長度、目前值和它的運作（這是當這個欄位取得輸入焦點時，按下按鍵會產生的反應）。在FormatSize事件中決定callback欄位的最大長度，而此事件會因每個callback欄位而引發。如果有多個區域，就必須使用Select Case結構，如下面的程式：
Private Sub DTPicker1_FormatSize(ByVal CallbackField As String, _
Size As Integer)
Select Case CallbackField
Case "XX"
' The number of weeks since January 1st (max 2 digits)
Size = 2
Case "XXX"
' The name of a holiday, if any
Size = 16
End Select
End Sub
當DateTimePicker控制項要顯示日期時，每個callback欄位皆會引發Format事件。藉由FormattedString屬性可傳回callback欄位值：
Private Sub DTPicker1_Format(ByVal CallbackField As String, _
FormattedString As String)
Select Case CallbackField
Case "XX"
' The number of weeks since January 1st (max 2 digits)
FormattedString = DateDiff("ww", _
DateSerial(DTPicker1.Year, 1, 1), DTPicker1.Value)
Case "XXX"
' The name of a holiday, if any
If DTPicker1.Month = 12 And DTPicker1.Day = 25 Then
FormattedString = "Christmas"
Else
' Deal here with other holidays.
End If
End Select
End Sub
當callback欄位取得輸入焦點時，可藉由在CallbackkeyDown事件函數中撰寫程式來處理所有的按鍵處理。這個事件接收按鍵的資訊、shift鍵的狀態，和callback欄位的名稱。一般而言，會藉由指定一個新日期給CallbackDate參數來處理按鍵：
Private Sub DTPicker1_CallbackKeyDown(ByVal KeyCode As Integer, _
ByVal Shift As Integer, ByVal CallbackField As String, _
CallbackDate As Date)
If CallbackField = "XX" Then
' Move to the previous/next week when the Up/Down key is pressed.
If KeyCode = vbKeyUp Then
CallbackDate = DTPicker1.Value + 7
ElseIf KeyCode = vbKeyDown Then
CallbackDate = DTPicker1.Value - 7
End If
Else
' No keyboard support for the Holiday field
End If
End Sub
CoolBar控制項
CoolBar控制項因為Microsoft Internet Explorer而廣為人知，由能收納其他控制項的band集合所組成，band可收納的東西包括浮動Toolbar、TextBox和ComboBox控制項等。使用者能在執行時使用滑鼠調整和移動band的大小，還能改變其順序。在雙擊band的分隔線之後，會儘可能的展開band於其所屬的列上。
CoolBar控制項包含Band集合，其包含一個以上的Band物件。每一個Band物件只能容納一個控制項，當使用者移動或調整Band容器大小時，所容納的控制項也會自動移動和調整大小。不能讓無視窗的控制項成為Band物件的子控制項，但可以將無視窗控制項放在另一個容器控制項中秄狾pPictureBox控制項秄藷𦶡嶊怞足蚪and物件的子控制項。同樣地，不能在每個Band物件中擁有一個以上的子控制項，但可以在Band物件的子PictureBox中放置多個控制項。（在這種情況下，必須在PicutreBox的Resize事件函數中撰寫調整控制項大小的程式。）
CoolBar控制項是唯一包含在ComCt332.ocx檔案的控制項。Visual Basic 6是第一個包含此控制項的版本，不過Visual Basic 5的設計者可以從Microsoft網站下載使用此控制項。
設定設計階段屬性
CoolBar控制項是複雜的，而且包含許多設計階段的屬性，您可能需要時間才能熟悉。
一般屬性
放置CoolBar控制項於表單之後，首先將它對齊到表單的邊緣。於一般屬性視窗中，設定Align屬性為1-vbAlignTop便能達成，而所有的設計階段屬性都能在屬性頁中做修改。
Orientation屬性決定控制項的方向，其值可以為0-cc3OrientationHorizonal（預設值）或1-cc3OrientationVertical。若不想讓每個Band的邊緣有水平線的話，可以將BandBorder屬性設為False，但一般會設為True。
使用者能夠在執行時移動或拖曳它的最左方邊緣線來調整Band物件的大小，如果設FixedOrder屬性為True，則保證使用者無法改變Band物件的順序。VariantHeight布林屬性決定Band物件能否有不同的高度：如果為True（預設值），則每列高度由該列Band物件之MinHeight屬性的最大值決定；如果為False，表示所有的列都同高，因此高度由CoolBar控制項內所有Band物件的MinHeight屬性最大值決定。
Band物件
預設情況下，CoolBar控制項有三個Band物件，但可以在屬性頁的Bands頁籤中增加或移除Band物件，如圖11-8所示。每一個Band都能調整大小（如果Style屬性為0cc3BandNormal）或不能（如果Style為1cc3BandFixedSize）。固定寬度後的Band不會顯示最左方調整大小的把手。
Band物件可顯示字串（Caption屬性）；而且它有初始的寬度（Width屬性），最小寬度（MinWidth屬性）和最小高度（MinHeight屬性）。它也包含Key屬性，可以讓您從Bands集合中找到某個Band物件，還有Tag屬性，可用來儲存與Band本身有關的任何資訊。
| 圖11-8 CoolBar控制項屬性頁的Bands頁籤。注意背景圖片與其子Toolbar搭配上有問題。 |
Band物件最重要的屬性是Child，其指向在特定Band中的子控制項。要移動控制項到Band物件內，首先必須讓控制項成為CoolBar的子控制項。最簡單的方法是從CoolBar控制項建立Toolbox，之後，會在控制項列表中（可成為Band的子物件）找到此控制項名稱。
預設情況下，擁有Bands的可包含許多Band，而每個Band物件的位置由Bands的順序和它們的最小寬度決定。要改變Band的位置，可以設NewRow屬性為False來把Band移到下一列的起始位置。最後當CoolBar控制項改變它的方向為cc3OrientationVertical，可以設AllowVertical屬性為False使得Band看不見。
圖像和顏色管理
CoolBar控制項支援顏色和圖片的進階管理。如果Picture屬性沒有值的話，控制項的顏色會由標準的ForeColor和BackColor屬性決定。如果指定一個點陣圖給CoolBar的Picture屬性時，這個圖像放大至所有控制項內的Bands，且BackColor屬性會被忽視。
為了讓設計者建立與Microsoft Internet Explorer相同的使用者介面，CoolBar控制項還包含三個附加的屬性。EmbossPicture布林屬性決定圖像是否被分成兩種顏色；如果屬性值為True，其凸起的顏色將由EmbossHighlight和EmbossShadow屬性決定。CoolBar控制項使用dithering演算法來決定原始圖像的哪些顏色應該變亮或變暗。
預設情況下，所有的Band物件會繼承父CoolBar控制項所設的圖片，而這些圖片會並列顯示於所有的Bands，無論Bands被調整大小或移動。設定Band物件的FixedBackground屬性為False，會造成圖片大小固定，即使特定的Band被移動或改變大小時亦然。
另一方面，藉由設定UseCoolBarPicture屬性為False和指定合法的值給Picture屬性，可設定所有或部分Band物件；也可以藉由設定受影響Bands的EmbossProperty為True和指定適合的值給EmbossHighlight和EmbossShadow屬性來使圖片凸起，如同主CoolBar控制項的做法般。
Band物件也繼承父CoolBar的顏色屬性，除非設定Band的UseCoolBarColors為False。如果這樣做的話，可藉由設定ForeColor和BackColor屬性來選擇用在某特定Band的顏色。（但後者只有在Band沒有顯示圖片時，才會真正被使用。）
很意外地，無論CoolBar控制項或Band控制項都沒有Font屬性，所以Band的標題外貌完全取決於系統設定，除了其文字顏色外（這可被ForeColor屬性所影響）。若要對文字特性有較大的控制，可以使用Label控制項並將其放置在PictureBox控制項內，然後將此控制項作為CoolBar的子控制項。（記住Label控制項和其他輕量的控制項不能為Band物件的子控制項。）
執行階段的運作
在大部分的執行階段下，無須處理CoolBar控制項：CoolBar知道當使用者移動它們到另一列時，要如何調整Bands大小，以及如何調整在每個Band內的子控制項。然而在少數特定情況下，還是需要用程式來手動處理CoolBar控制項。
處理Resize事件
當使用者在執行時移動Band物件，而因為此動作造成Band列被建立或消除時，CoolBar控制項會引發Resize事件。如果想要重新排列表單上其他控制項的位置或隱藏（顯示）Band物件，可善用此事件。
但有時您不應該在Resize事件中寫程式，例如，假若CoolBar控制項本身包含在其他控制項內，則CoolBar的Height屬性可能傳回錯誤的值，或Resize事件可能不會被引發。基於此，更好的方法是將程式撰寫在HeightChanged事件函數中。當水平CoolBar的Height屬性或垂直CoolBar的Width屬性被修改時會引發此事件。
若表單包含其他的控制項，則對這些事件做出反應是重要的。除非事先預防，否則當CoolBar變高時，其他在表單上的控制項可能會被覆蓋。因此，可能把所有其他的控制項全放在某個容器控制項如PictureBox，如此一來只要移動這個容器即可。如果採用這種方法，也應該在表單的Resize和PictureBox的Resize事件函數中撰寫程式。下列程式片段（如圖11-9所示，完整程式附在隨書光碟中）說明這個解決方法：
' Resize the PictureBox when the form resizes.
Private Sub Form_Resize()
Picture1.Move 0, CoolBar1.Height, ScaleWidth, _
ScaleHeight - CoolBar1.Height
End Sub
' Resize and move the PictureBox when the CoolBar's height changes.
Private Sub CoolBar1_HeightChanged(ByVal NewHeight As Single)
' Assumes this CoolBar is aligned to the form's top border
Picture1.Move 0, NewHeight, ScaleWidth, ScaleHeight - NewHeight
End Sub
' Resize the controls inside the PictureBox when the latter is resized.
Private Sub Picture1_Resize()
Label1.Move 0, 0, Picture1.ScaleWidth, Label1.Height
Text1.Move 0, Label1.Height, Picture1.ScaleWidth, _
Picture1.ScaleHeight - Label1.Height
End Sub
| 圖11-9 展示程式顯示如何處理可變動的CoolBar控制項。 |
增加Band物件
有時可能需要在執行時用程式來增加Band物件，您可以使用Band集合的Add方式來做到，如下列語法：
Add([Index],[Key],[Caption],[Image],[NewRow],[Child],[Visible]) As Band
每個參數影響同樣名稱的Band屬性，Child屬性會繼承Band中的控制項。當使用這個技巧建立Band物件時，可能需要動態地建立子控制項。在此情況下，指定它成為Band物件的Child屬性前，應先要讓它成為CoolBar控制項的子控制項：
' Create a new ComboBox control.
Dim cb As ComboBox
Set cb = Controls.Add("VB.ComboBox", "NewCombo")
' Make it a child of the CoolBar1 control.
Set cb.Container = CoolBar1
' Create a new Band object, assigning the ComboBox to its
' Child property.
CoolBar1.Bands.Add , "NewBand" , cb.Name, , , cb
可以使用Bands集合的Remove方式來移除Band物件：
' Remove the Band object created with the previous code snippet. CoolBar1.Bands.Remove "NewBand"
使用Toolbar控制項作為子控制項
當使用圖片作為CoolBar控制項的背景圖時，要注意某些類型的子控制項並不能配合得很好，尤其是Toolbar控制項。事實上，在Toolbar控制項內，背景圖並不會顯現，反而造成不好的結果（見 圖11-9 ）。幸運地，有個解決辦法，不過它可能沒您想像中的簡單。
筆者找到的解決方法是架構在一個筆者寫的檔案上，此檔案可以在Microsoft網站的Visual Studio Owner區的CoolBar Sample專案中找到。這個範例專案說明如何在CoolBar控制項中包含Toolbar控制項，以及使用一個輔助的模組TransTBWrapper來建立浮動有著透明背景的Toolbar，如圖11-10。這個技術是必需的，因為這個版本的Toolbar（為Visual Basic 5版本）並不支援浮動樣式。
如您所知，Visual Basic 6 Toolbar控制項已支援浮動樣式，所以可以把它包在CoolBar控制項內，而看起來仍跟原本的一樣。然而，新版Toolbar仍不支援透明背景。修改TransTBWrapper模組讓它可與新版的Toolbar控制項相互運作花了筆者不少時間，但終究是有價值的。現在可以在您的應用程式中使用新版的模組，不過請記得該檔案並不會被Microsoft所支援。
| 圖11-10 較佳的展示程式使用TransTBWrapper模組來包含有著透明背景的Toolbar控制項。 |
為了做到圖11-10所示的透明背景，先準備好正常執行的程式，然後把TransTB.Ctl檔案加到專案中。這個檔案包含TransTBWrapper ActiveX控制項，所以可以把此控制項的實體放到包含CoolBar和Toolbar控制項的表單。至此，您只需要一些在表單的Load和Unload事件函數的程式：
Private Sub Form_Load()
' Put the toolbar wrapper controls in the CoolBar band.
Set TransTBWrapper1.Container = CoolBar1
' This must be the same Band that hosts the toolbar.
Set CoolBar1.Bands(1).Child = TransTBWrapper1
' Put the toolbar into the toolbar wrapper.
Set TransTBWrapper1.Toolbar = Toolbar1
End Sub
Private Sub Form_Unload(Cancel As Integer)
' It is VERY important to set the wrapper's Toolbar property
' to Nothing before the form is unloaded.
CoolBar1.Visible = False
Set TransTBWrapper1.Toolbar = Nothing
End Sub
注意
要保證Form_Unload永遠會被執行到；否則可能會導致應用程式當掉。基於這個原因，在Visual Basic整合環境中測試應用程式時，請經由Unload主表單來結束程式，而絕不要執行End敘述。（End敘述導致Unload事件不會引發。）
本章結束了所有Visual Basic通用控制項的介紹，另外還有一些Visual Basic設計師可以使用的控制項將在下一章說明。