6. 類別與物件
就筆者個人對這問題的想法：Visual Basic並不是真正的OOP語言，因為VB並不具備某些oop語言的特性，例如繼承。不過這不代表程式設計人員不需要物件與類別的使用細節。以下是本章所要傳達及此書所要闡述提示的地方：
若您對OOP完全陌生，本章節(應該也是本書中最困難的章節)可以幫助您理解。以較少的篇幅瞭解如何以物件幫忙寫出更好的程式，同時您必須準備改變您的觀念，不要像許多程式設計者從早期的MS-DOS語言如QuickBasic轉到以事件為導向的設計環境，如Visual Basic時所花費的一樣。但是一旦瞭解OOP的基本概念後，您大概會同意從Visual Basic的第一版到現在，物件是一件最讓人感到興奮的事。進入OOP領域後，將會發現自己能很快地規劃、設計出對於舊問題的新的、簡潔的解決方法，通常花費時間少且程式碼也短。做為一個Visual Basic程式設計者，對於許多有關事件、資料庫設計及使用者介面的議題的精進程式撰寫技術已經精通。OOP就並不困難了，他只是不同罷了但卻極度有趣。
若曾經閱讀有關OOP的書籍或文章，無疑地會發現許多對於物件的不同定義。大多數的定義都是對的，因此您會感到困惑。筆者傾向於以下的定義：
物件是個結合資料和處理資料的程式碼的一個實體。
讓我們看看實際的例子。
基本概念
許多程式設計師第一次接觸OOP時，對於類別和物件會感到困惑。因此，在此作簡短的解釋。類別（Class）是程式（Visual Basic的原始程式碼）的一部份，定義了屬性、方法和事件䪖疏奶均A在執行期間會有一個或多個物件被建立的行為。物件（Object）是在執行時被建立的實體，需要記憶體還有其他可能的系統資源，當不再需要或當應用程式結束時，將被釋放。就某種意義來說，類別是設計階段的實體，而物件是執行階段的實體。
使用者從來不會看到類別；然而。也許在螢幕上會看到且接觸到從類別所產生的物件，譬如發票、客戶資料或圓圈。身為一個程式設計者，觀念必須反過來，因為當撰寫應用程式時，大部分在您面前的有形的事情都是類別，其在Visual Basic環境中以類別模組的形式存在著。直到執行應用程式時，在程式碼中物件比以 Dim 敘述宣告的變數還不實際。以我的看法，這二分法造成許多Visual Basic設計者對OOP的錯誤認識。我們已經被最愛的RAD工具所寵壞，且通常認為物件是可視的物件，例如表單、控制項等等。而Visual Basic也可以創造此類可視的物件-包括微軟ActiveX控制項-直到您瞭解了在程式碼中幾乎從有形的且可視的實體中如發票、產品、顧客及員工等等，到許多抽象的如確認程序或兩個資料表之間的關連，所有的事情都是一個物件，才知道物件導向的威力。
OOP主要的優勢
觀看實例之前，先提示您OOP必須提供的東西。底下將會列出OOPL(object-oriented programming languages)的關鍵特性並解釋一些觀念。這些觀念的瞭解對本章節稍後介紹的部分有一定的幫助。
封裝
在OOP中，封裝或許是程式設計師最欣賞的特性。概略地說，物件是資料本身的唯一擁有者。所有的資料皆儲存在應用程式中的某部份，且無法直接存取的記憶體中，並且所有工作及取得動作需透過物件本身的方法及屬性來運作。此一簡單的概念至少有以下兩種結果：
與大部分的OOP特性相同，確認類別具有完美的封裝是您的責任。使用類別的事實無法保證封裝的目標能夠有效達到。本章及下一章會講到一些簡單的規則及常識幫助您如何完成健全的類別。一個完美的類別是個可以自動防範內部資料被竄改的類別。若有一個從擁有有效資料的類別所產生的物件，且在物件上所有執行的動作只是把資料轉換進其他有效的資料中（或當動作無效時提出錯誤），那便可以絕對確定此物件是在有效的狀態，且從未增添錯誤值給程式。這是一個例子，但也是個重要的概念，讓您對程式的偵錯過程有相當概念。
每個設計者應該達到的第二目標是程式再利用，藉由建立易維護且可再利用的類別，可以達到在其他應用程式中重複使用。可以減少開發時間和花費是關鍵因素。在此概念下類別的功用更多，但是相對地仍需要您的配合。當開始撰寫一個新類別時，應該要告訴自己：在其他的應用程式上是否可以重複使用。從一個特定的軟體中立即開發一個類別要花費多久？大部分的情況下，這表示新增少數屬性或少數引數給方法，便可達到非常好的效果。別忘了總是給定屬性的預設值和方法選擇性引數，因此大部分情況下，這些增強功能不會讓類別的使用便得很複雜，但又能達成所需。
自我封裝的概念也是與程式碼再利用和封裝嚴密地相關連。若想建立一簡單可再利用的類別模組，絕對不允許類別依存在任一外在的實體，例如全域變數上。這會破壞封裝（因為在應用程式的其他地方的程式碼允許改變變數值為某些無效的資料）。且最重要地，會避免再使用在他處沒有複製全域變數的類別。基於同一理由，應該嘗試製造一個獨立於其他模組的一般用途規則的類別。一般情況下，我較喜歡在每一個類別模組中複製簡短的規則，可以使得類別容易移往其他地方。
多態性
非正式地，多態性（Polymorphism）是不同類別對外顯示在相似（或相同）介面的能力。在Visual Basic中最重要的多態性種類是表單和控制項。TextBox 控制項和PictureBox控制項是完全不同的物件，但是他們有一些共有的屬性和方法，例如：Left、BackColor 和 Move。這一相似處簡化程式設計者的工作，因為不必記住上百個不同名字和語法的格式。更重要的，它讓您使用單一變數管理一群組的控制項（如控制項、變數、物件型態），且可建立運用於表單上所有控制項的通稱程序，因此明顯減少此一種類的程式碼。
繼承
繼承（Inheritance）是許多OOP語言提供的一種能力，從一個類別中取得一個新的類別（derived或inherited 類別）。Derived類別自動繼承基礎類別的屬性和方法。例如，可以定義一般的 Shape 類別為有如 Color 和 Position 的屬性，然後對許多繼承所有屬性的特別類別（譬如 Rectangle、Circle 等等）使用如同基礎類別般。然後可以增加特別的成員，例如對 Rectangle 類別增加 Width 和 Height，對Circle 類別增加 Radius。注意這些是有趣的，多態性傾向於減少需要使用類別的程式碼的數量，繼承減少類別本身內部的程式碼，因此簡化類別建構者的工作。遺憾地，Visual Basic沒有支援繼承，至少在它的多數表單是如此。下一章，會告知如何寫程式手動地模擬繼承，並解釋何時且為何繼承如此有用。
第一個類別模組
在Visual Basic中建立類別是很簡單的：只要從專案表單中執行新增類別模組命令。一個新的程式碼編輯視窗會呈現出來。預設情況下，第一個類別模組命名為 Class 1，所以應該要做的第一件事是改變成適合的名稱。在第一個例子，顯示如何將關於人的個人資料封裝，所以將第一個類別命名為Cperson。
說明
微軟建議在類別名稱前面加上 cls，但我並不遵從，因為覺得它使得程式碼減少可讀性。我通常較喜歡使用 C 作為辦別類別的字首，有時候甚至沒有加上字首，特別是當物件階層。當然這是個人呈現的方式，並沒有強調筆者的系統比任何其他人有理。
我們第一版本的類別只包括少數的屬性。這些屬性在類別模組本身中以Public作為宣告，可以參考原始碼，如圖6-1所示：
' In the declaration section of the CPerson class module Public FirstName As String Public LastName As String
| 圖6-1 建立一個類別模組，在屬性視窗中給定類別名稱，在程式編輯視窗中加入一些廣域變數。 |
這是一個非常簡單的類別，但對於體驗有趣的主題上也是個好的開始，可以先避開詳細的細節。若曾經建立一個類別模組，可以參照此一類別宣告一物件變數：
' In a form module
Private Sub cmdCreatePerson_Click()
Dim pers As CPerson ' Declare.
Set pers = New CPerson ' Create.
pers.FirstName = "John" ' Assign properties.
pers.LastName = "Smith"
Print pers.FirstName & " " & pers.LastName ' Check that it works.
End Sub
此程式碼並非讓人很了解。但是記住這裡僅僅要傳達這些概念，物件真正的力量怎當我們將之應用於實際的應用程式時方會呈現。
Auto-instancing物件變數
不像一般宣告後快速使用的變數，在尋求物件的屬性和方法之前，一個物件變數必須明確指派給物件參照。實際上，當物件變數尚未分派時，是為一個特別的 Nothing 值：換句話說，並沒有任何有效值給實際的物件參考。為了瞭解實際的意義，請參照以下程式碼：
Dim pers As CPerson ' Declare the variable,
' Set pers = New CPerson ' but comment out the creation step.
Print pers.FirstName ' This raises an error 91 _ "Object variable
' or With block variable not set"
多數情況下，這一行為是正確的，因印出實際上不存在的物件屬性是不具意義的。避免此一錯誤的方法是使用 Is Nothing 測試物件變數目前的內容：
' Use the variable only if it contains a valid object reference If Not (pers Is Nothing) Then Print pers.FirstName
然而，其他情況下，只想建立一個物件，任一物件，然後指派它的屬性。此種情況下，可以發現使用 As New 宣告 auto-instancing 物件變數是滿有用的：
Dim pers As New CPerson ' Auto-instancing variable
當執行階段，Visual Basic遇到auto-instancing變數的參照，首先確定其是否指向存在的物件，當有需要時會建立類別的新實體。您應要知道Auto-instancing變數有哪些需注意的地方：
總而言之，auto-instancing變數通常並非是最好的選擇，一般來說奉勸不要使用它。本章節中大部分的程式碼沒有使用auto-instancing變數，通常在自己的應用程式上也可以不要用。
屬性程序
回到Cperson類別，並且看看此類別如何避免自己接收到無效的引數，例如FirstName 或 LastName 屬性出現空字串。為了達到這一目的，必須改變類別模組的內部架構，因在目前的表單中無法補抓指定值程序。所要做的是轉換這些值到Private成員，並將他們封裝進一對Property程序。以下為 Property Get 和 Let FirstName 程序的程式碼，而對於 LastName 的程式碼也是相似的。
' Private member variables
Private m_FirstName As String
Private m_LastName As String
' Note that all Property procedures are Public by default.
Property Get FirstName() As String
' Simply return the current value of the member variable.
FirstName = m_FirstName
End Property
Property Let FirstName(ByVal newValue As String)
' Raise an error if an invalid assignment is attempted.
If newValue = "" Then Err.Raise 5 ' Invalid procedure argument
' Else store in the Private member variable.
m_FirstName = newValue
End Property
說明
從工具列中可以使用Add程序命令儲存某些形式，自己建立暫時的 Property Get 和 Let 程序。不過，應要編輯結果，因為經由此方法建立的所有屬性是Variant型態。
加入這程式碼，並撰寫處理 LastName 的程序；然後執行程式，可以看到每件事皆如前所題般地運作。然而，所要做的是使類別變得更齊全，因為現在拒絕指派無效的值給其屬性。要了解筆者的意思，請執行這一命令：
pers.Name = "" ' Raises error "Invalid procedure call or argument"
若按下F8逐行的來追蹤程式，將會瞭解這兩屬性程序實際上在做什麼。每次指派一個新的值給一屬性，Visual Basic會確認是否有相關的 Property Let 程序，並且轉換新的值給它。若程式碼不能使新的值有效，會產生錯誤並把執行權藉由指派值給獨立變數 m_FirstName 還給呼叫者。請同時習慣使用 m_ 字首維持屬性名稱並和獨立屬性作區別，這只是個人的意見；可自由使用或建立自己的規則。當呼叫者程式碼要求屬性值時，Visual Basic 執行相對的 Property Get 程序，單純第傳回個別變數的值。由 Property Let 程序產生的型態必須符合由 Property Get 程序所傳回的值之型態。實際上，就目前Visual Basic所及，屬性型態是 Property Get 程序所傳回的型態。（當解釋變數屬性時這區分會更有意義。）
使一屬性值有效的真正意義是什麼並非很清楚。有些屬性在類別之外您所沒考慮到的是無效的。譬如，沒有連接到資料庫的Products不能使Product有效。簡單地說，新增一個新的 BirthDate 屬性，在合理情況下有效：
Private m_BirthDate As Date
Property Get BirthDate() As Date
BirthDate = m_BirthDate
End Property
Property Let BirthDate(ByVal newValue As Date)
If newValue >= Now Then Err.Raise 1001, , "Future Birth Date !"
m_BirthDate = newValue
End Property
方法
類別模組也可以包含Sub和Function程序。在其他型態的模組中，Function方法和Sub只有一個不同，就是Function方法可以傳回值，而Sub方法則不傳回值。既然Visual Basic可使用不傳回值的Function，所以筆者通常喜歡建立傳回第二種值的Function方法：當類別的使用者實際上不需要傳回值時，程序內還是可加入值的。
在這簡單的Cperson類別中什麼方法是有用的？當開始處理許多人的記錄時，可以輕易發現一而再再而三列印出所有人的完整姓名。因此也許想要設計出一個快速簡單列出全名的方法。要解決此一簡單工作的思考程序法，可在全域BAS模組中建立一個Function：
' In a BAS module
Function CompleteName(pers As CPerson) As String
CompleteName = pers.FirstName & " " & pers.LastName
End Function
當此一程式碼運作，它並非是執行此一工作最好的方法。事實上，全名概念對類別來說是內部的，所以缺乏一個機會使得類別更聰明更容易來使用。除此之外，會使類別本身變成很難再利用，因為現在您將它的功用散佈在所有的應用程式中。最好的方法是在Cperson類別中新增一個新的方法：
' In the CPerson class
Function CompleteName() As String
CompleteName = FirstName & " " & LastName
End Function
' In the form module, you can now execute the method.
Print pers.CompleteName ' Prints "John Smith"
當在類別模組範圍內，不需要以點符號來參照目前例子的屬性。換句話說，若在類別模組範圍中，並且參照一公開的屬性名稱（FirstName）而非相對的個別的群組變數(m_FirstName)，假若此屬性是外部的類別所參照，則Visual Basic會執行 Property Get 程序。事實上，應該嘗試去堅持以下的法則：只有從相對的 Property Let / Get 程序的類別中參照區域的群組變數。假若之後修改屬性內部的結果，只必須修正類別模組中一小部分的程式碼。有時無法避免程式碼的修正，但是應該全力以赴來應用此一規則。一旦瞭解此一作用，可以對您的類別增加許多能力，如以下程式碼所示：
Function ReverseName() As String
ReverseName = LastName & ", " & FirstName
End Function
記得您剛剛增加程式碼，並且在執行階段中沒有額外的記憶體來儲存完全和相反名稱的值。
對類別增加越多的能力，使用這一類別的設計師越高興。有關類別最重要的一件事是增加的所有方法和屬性會立即在物件瀏覽器上看到，還有他們完整的語法。假設小心地選擇您的屬性和方法的名稱，則對每個不同的工作選到對的程序可說變成較有趣的。
Class Initialize事件
當開始建構類別，您將發現常需要在物件本身建立時，即指定一個定義好的值給屬性，而非在呼叫者程式碼中指定。例如，假設處理Employee物件，可合理的認為，在大部分的例子中，它的 Citizenship 屬性是American（或者任何居住的區域）。類似地，大多數在假定的發票物件中，AddressFrom 屬性將可能符合所工作的公司地址。當建立物件時，想要指定這些預設值，而不是必須在使用到類別的程式碼中手動地指定。
Visual Basic提供一個不錯的方法來達到這個目標。事實上，所必須要做的是在類別模組的 Class_Initialize 事件上寫一些敘述。用編輯器對此事件程序建立一個模子，在程式編輯區中選擇做左邊combo box控制項的Class選項。Visual Basic自動從最右邊的下拉式控制項中選擇初始選項，並且新增樣版到編輯視窗中。 Citizenship 屬性的預設值為American：
' The Private member variable
Private m_Citizenship As String
Private Sub Class_Initialize()
m_Citizenship = "American"
End Sub
' Code for Public Property Get/Let Citizenship procedure ... (omitted)
假若現在要執行到目前為止所建立的的程式並且追蹤之，會看到Visual Basic立即建立物件（在表單模組的 Set 命令），Class_Initialize 事件被觸發。物件會被傳回給呼叫者，並將所有屬性正確初始化，不必指定他們。Class_Initialize 事件有一個相對應的 Class_Terminate 事件，當物件被Visual Basic被摧毀時會觸發。在這一程序中，通常會關閉打開的檔案和資料庫並執行其他清除工作。在本章後面會講到 Class_Terminate 事件。
偵錯類別模組
大部分的觀點上，對類別模組內部的程式碼偵錯並非與程式碼（表單模組中）偵錯有何不同。但是當有數個相互影響的物件，則可能會迷失在程式碼中。所給定的這一瞬間，看到的是哪個特定實體？目前屬性是什麼？當然，可以使用所有的偵錯工具-包括 Debug.Print 敘述、data tips、Instant Watch等等。如圖6-2所看到的是Locals視窗。只要開著這個視窗，可以知道任何時間所在的位置，程式碼如何影響物件屬性等等。
| 圖6-2 當處理多個物件時，區域變數視窗是一個不錯的偵錯工具。 |
Me關鍵字
有時類別必須參照本身的程式碼。例如當一個物件必須從自身傳第一個參照給其他程序時，這是有需要的。這可以使用 Me 關鍵字。以下簡單的程式中，在BAS模組中準備兩個一般用途的程序，其幫助紀錄物件何時被建立且被釋放。
' In a Standard BAS module
Sub TraceInitialize (obj As Object)
Debug.Print "Created a " & TypeName(obj) _
& " object at time " & Time$
End Sub
Sub TraceTerminate (obj As Object)
Debug.Print "Destroyed a " & TypeName(obj) _
& " object at time " & Time$
End Sub
底下為如何從CPerson類別模組來使用這些程序：
Private Sub Class_Initialize()
TraceInitialize Me
End Sub
Private Sub Class_Terminate()
TraceTerminate Me
End Sub
Me關鍵字還有其他用法，在這邊還有下一章可以看到。
屬性、方法和事件
這邊要指出如何正確使用到目前為止的所有能力。我會繼續發展Cperson類別做為例子，以它來介紹新概念：
唯讀和唯寫屬性
若看到Visual Basic定義自己本身的物件（表單、控制項等等），可注意到並非所有的屬性都可以讀取和寫入。舉例來說，在執行階段中無法修正ListBox控制項的 MultiSelect 屬性，甚至在設計階段無法修正ComboBox的高度。根據您類別的狀況，可以有許多好理由來限制存取屬性，使它們唯讀或唯寫（較少出現）。
唯讀屬性
講到想要在Cperson類別新增一個Age屬性。根據 BirthDate 屬性，因此應該是唯讀屬性。在Visual Basic中省略 Property Let 程序可使得屬性成為唯讀。
Property Get Age() As Integer
Age = Year(Now) - Year(BirthDate)
End Property
為了證實現在有一個唯讀屬性，嘗試執行此段程式碼：
pers.Age = 50
一旦嘗試執行程式會造成Visual Basic編譯錯誤，直到改正或刪除此段敘述才能編譯程式。
唯寫屬性
偶爾，可能甚至想要建立一個唯寫屬性。典型的例子是虛構的登入物件的Password 屬性。此一屬性可被指定去認證登入處理，但不應該是可讀的以便不與應用系統本身的安全性相妥協。在Visual Basic中，像這樣的唯寫屬性可以藉由撰寫 Property Let 程序同時忽略相對的 Property Get 程序來實現。
Private m_Password As String
Property Let Password(ByVal newValue As String)
' Validate the password, raise error if not valid.
' ...
' If all is OK, assign to Private member variable.
m_Password = newValue
End Property
老實的說，這特別的Visual Basic特性通常沒有什麼用途，但為了完整性筆者才告知。唯寫屬性通常令人感到困惑，且多數開發者覺得不自然。若需要一個唯讀屬性，我比較喜歡建立一個可接受值作為參數的方法（在此可為 SetPassword）。
寫一次／讀多次的屬性
寫一次／讀多次（Write-once/read-many）屬性比起純粹的唯寫屬性要來的有趣且有用。例如，先前描述的LoginDialog物件可能有此類型態的 UserName 屬性。一旦一個使用者登入，您的程式碼指派他或她的名字給此屬性，然後應用系統的其他部分可以讀取它但不能修正它。這裡有另一個實例：在 Invoice 類別，Number 屬性可被當作一個write-once/read-many屬性，因為一旦您指定一個數字給發票後，任意改變它可能造成在會計系統嚴重的問題。
Visual Basic沒有提供適當的系統來執行像這樣write-once/read-many屬性，但是用一些額外的程式碼便可容易地達成。假設要讓Cperson類別有個 ID 屬性，此屬性只可被指定一次但可被讀取多次。這有個可能的解決方法，依靠一個靜態的邏輯變數。
Private m_ID As Long
Public Property Get ID() As Long
ID = m_ID
End Property
Public Property Let ID(ByVal newValue As Long)
Static InitDone As Boolean
If InitDone Then Err.Raise 1002, , "Write-once property"
InitDone = True
m_ID = newValue
End Property
這裡有另一個解決方法，騰出額外的靜態變數但在記憶體中使用一些額外的位元組（16位元組替代6位元組）。
Private m_ID As Variant
Public Property Get ID() As Long
ID = m_ID
End Property
Public Property Let ID(ByVal newValue As Long)
If Not IsEmpty(m_ID) Then Err.Raise 1002, , "Write-once property"
m_ID = newValue
End Property
這兩個情況，類別對外的介面是一樣的（ID 是一長屬性）。這是個好的封裝架構，其讓您改變類別的內部實作而不影響使用它的程式碼。
唯讀屬性和方法
從用戶端程式觀點來看（實際使用您的類別的程式碼），唯讀屬性相似於函數。事實上，所有情況下，唯讀屬性只可在陳述句中使用，且從不出現在指派符號的左邊。所以這引發許多語法的問題：何時時做唯讀屬性是最好的，且何時使用函數是更好的？筆者無法提供規則，以下是一些建議：
說明
當您嘗試指派值給唯讀屬性跟嘗試指派值給函數所發生的事是有些微不同。對於前一個例子，會接收到一個錯誤訊息-"不能指派到唯讀屬性"-在後面的例子，則會得到更多錯誤訊息─"呼叫左側的函數必須傳回變數或物件"。這奇怪訊息的真正意思當您讀到本章後面物件屬性時將會更清楚。
現在取Cperson類別的 CompleteName 成員做為例子。它已經被當作方法來實作，但多數的程式設計師將肯定地認為他是一個唯讀屬性。再來，這是非常重要的一點，沒有任何東西阻止您認為他是一個可讀寫的屬性。
Property Get CompleteName() As String
CompleteName = FirstName &; " " &; LastName
End Property
Property Let CompleteName(ByVal newValue As String)
Dim items() As String
items() = Split(newValue)
' We expect exactly two items (no support for middle names).
If UBound(items) <> 1 Then Err.Raise 5
' If no error, assign to the "real" properties.
FirstName = items(0): LastName = items(1)
End Property
藉由以自然的方式讓用戶端程式指派 FirstName 和 LastName，便增加了類別的可用性，例如直接自表單欄位來得到資料：
pers.CompleteName = txtCompleteName.Text
當然您仍然可以指派獨立的FirstNmae 和 LastName 屬性，而不需要用 CompleteNmae 屬性建立不一致的工作。這是一個您可以使用的可愛小技巧。
有引數的屬性
到目前為止，講到的 Property Get 程序都沒有任何的引數，他們相對的Property Let 程序只有一個引數，此引數被指派給此程序。Visual Basic也可讓您建立接收無數個任何型態引數的屬性程序。這概念也被Visual Basic控制項所使用：例如，ListBox控制項的 List 屬性接受一個數字型態的索引。
讓我們瞧瞧此概念如何應用到Cperson這個簡單的類別。假設您需要一個 Notes 屬性，但同時您不想要限制自己只有一個項目。第一個解決方法是使用一個陣列字串。遺憾地，若您如下宣告一個公開陣列在類別模組中。
Public Notes(1 To 10) As String ' Not valid!
編譯器會出現以下的訊息，“常數、固定長度字串、陣列、自行定義型態和宣告敘述不允許當作物件模組的公開成員"。但您可以建立一個Private陣列成員，並對外使用一組Property程序來公開他。
' A module-level variable
Private m_Notes(1 To 10) As String
Property Get Notes(Index As Integer) As String
Notes = m_Notes (Index)
End Property
Property Let Notes(Index As Integer, ByVal newValue As String)
' Check for subscript out of range error.
If Index < LBound(m_Notes) Or Index >UBound(m_Notes) Then Err.Raise 9
m_Notes(Index) = newValue
End Property
注意
您可能不會去確認在先前程式碼中 Property Let 程序的Index 引數，而依靠Visual Basic的預設行為，這可能會引發錯誤。再次考慮之，並試著想像若您之後決定藉由設定Remove Array Bounds Checks來最佳化您的程式碼時會發生什麼事您。
現在您可以指派且取得對相同人的最多十個不同的紀錄，如下列程式：
pers.Notes(1) = "Ask if it's OK to go fishing next Sunday" Print pers.Notes(2) ' Displays "" (not initialized)
藉用讓 Index 作為選擇性引數，且預設為陣列的第一個項目可以改善此機制，程式碼如下：
Property Get Notes(Optional Index As Integer = 1) As String
' ... (omitted: no need to change code inside the procedure)
End Property
Property Let Notes(Optional Index As Integer = 1, _
ByVal newValue As String)
' ... (omitted : no need to change code inside the procedure)
End Property
' In the client code, you can omit the index for the default note.
pers.Notes = "Ask if it's OK to go fishing next Sunday"
' You can always display all notes with a simple For-Next loop.
For i = 1 To 10: Print pers.Notes(i): Next
也可以使用選擇性Variant引數和 IsMissing 函數，如同在表單或標準模組的一般程序般做法。在實作上，這很少被要求，但若需要時，您可知道是可以這樣做的。
在類別中作為公開變數的屬性
我已經敘述使用 Property Get 和 Let 程序的方便性，替代類別的公開變數：您獲得更多控制，可以驗證使指派給屬性的資料，可以追蹤執行流程等等。但是這裡有一個更有趣的情形，您應該意識到即使宣告一個公開變數，Visual Basic實際上所做得是為您建立一對隱藏式的屬性程序，不論何時您從類別外部參照到這一屬性時均會呼叫他們。
' Inside the CPerson class Public Height As Single ' Height in inches ' Outside the class pers.Height = 70.25 ' This calls a hidden Property Let procedure.
除了小小的執行效率外-觸及一個程序比存取一個變數確定還慢-這Visual Basic行為並不值得提起。遺憾地，這並不通用。假設想要把所有您的測量法改成公分，得準備一個簡單的程序，用 ByRef 引數來運作。
' In a standard BAS module
Sub ToCentimeters (value As Single)
' Value is received by reference, therefore it can be changed.
value = value * 2.54
End Sub
您認為可對物件屬性的簡單轉換有個合法地期望：
ToCentimeters pers.Height ' Doesn't work!
先前方法失敗的理由應該很清楚，現在您知道公開變數被當作隱藏的程序來執行。事實上當您傳遞 pers.Height 值給 ToCentimeters 程序時，表示正傳遞表示式的結果，而不是實際的記憶體位址。因此，程序工作沒有記憶體來指示傳遞新的值到何處，轉換結果會遺失。
注意
Microsoft改變類別模組內公開變數被執行的方式。在Visual Basic 4，這些變數沒被隱藏式屬性程序所封裝；因此，若透過 ByRef 引數傳遞給程序，他們可被修改。當Visual Basic 5出現，實作過程改變了，許多Visual Basic 4設計師必須對他們程式碼重新製作，藉由建立實際接收新值的暫存變數。
' The fix that VB4 developers had to apply when porting to VB5 Dim temp As Single temp = pers.Height ToCentimeter temp pers.Height = temp
這段程式碼不漂亮也沒有效率。更糟的是，既然此技巧沒有清楚的文件說明，許多程式設計師必須自己理解。若您將從Visual Basic 4轉向第五版或第六版，不得不提防。
無論如何，這裡有另一個未透露的事件。到目前為止我說講的是當從類別外部參照公開變數所發生的事。若您從類別模組內部觸及外面的程序，傳給您的變數，每一個事情如預期般發生。換言之，您可以在Cperson寫這程式碼：
' Inside the CPerson class ToCentimeter Height ' It works!
Height 屬性將會正確地更新。此情況下，被傳遞的值是變數的位址，而不是隱藏式程序的傳回值。若想要從類別外部將程式碼移到類別內部（或者相反），這一點是重要的，因為必須準備處理像這樣難捉摸的議題。
注意
最後一點需注意的：若在類別模組中用 Me 關鍵字加在屬性前作為字首，他們再度看起來像是屬性而非變數，則Visual Basic會採用隱藏程序而非變數位址。因此，此一程式在類別模組內部無法運作。
ToCentimeter Me.Height ' It doesn't work!
Method的進階使用
您已經知道許多關於Method的事。然而，這裡還有些更有趣的事，您應該了解關於Method如何在一個類別模組中使用的狀況。
儲存連串呼叫的結果
假設有個函數傳回一個複雜的值－例如，發票的總額－且不想要每次用戶端程式作一個要求時便計算一次。換句話說，您不想要在某處儲存它，且因為發票的某些屬性改變時導致其值變成無用。這很像資料庫開發者要做的決定：建立一個包含真正值的 GrandTotal 欄位（可能破壞資料庫的完整性且浪費硬碟空間）或每次需要時計算總額（如此做會浪費CPU時間），哪個是較好的？
類別模組提供一個簡單可選擇的方法，對所有相關連值的應用相當好，被當作函數或唯讀屬性在執行。舉例來說，再想想Cperson類別的 ReverseName 函數，且假設花費太多處理時間來計算它的值。這裡教您如何修正此函數以保持最低成本，而非修正類別對外的介面（增加的敘述以粗體表示）。
' A private member variable
Private m_ReverseName As Variant
Property Let FirstName(ByVal newValue As String)
' Raise an error if an invalid assignment is attempted.
If newValue = "" Then Err.Raise 5 ' Invalid procedure argument
' Else store in the Private member variable.
m_FirstName = newValue
m_ReverseName = Empty
End Property
Property Let LastName(ByVal newValue As String)
' Raise an error if an invalid assignment is attempted.
If newValue = "" Then Err.Raise 5 ' Invalid procedure argument
' Else store in the Private member variable.
m_LastName = newValue
m_ReverseName = Empty
End Property
Function ReverseName() As String
If IsEmpty(m_ReverseName) Then
m_ReverseName = LastName &; ", " &; FirstName
End If
ReverseName = m_ReverseName
End Function
換言之，傳回到用戶端之前，將值儲存在Private Variant變數，且可在後來的呼叫中再利用這一個值。因為每次不論 Firstname 或 Lastname 被指派一個新的值、Private變數被清除，其導致下次 ReverseName 函數被觸發會強迫再重新計算。檢查這簡單用戶端程式，並嘗試說明使用其他技術實作相同邏輯有多困難：
' This line takes some microseconds the first time it is executed.
If pers.ReverseName <> "Smith, John" Then
' If this line is executed, it internally resets m_ReverseName.
pers.FirstName = "Robert"
End If
' In all cases, the next statement will be as fast as possible.
Print pers.ReverseName
當然，我們可能也可在 FirstNmae 或 LastNmae 的 Property Let 程序中重新計算 m_ReverseName 值，但那會破壞我們主要的目標（避免不必要的成本與延誤）。在實際應用上，差別是可能牽涉不必要的資料庫開啟、再建立遠端連接等等，所以此技巧的優點可能會被掩蓋掉了。
模擬類別建構函式
我之前曾解釋過如果有一個類別一定包含有效資料時，此類別則被視為強固的。達成此目標的主要方法是提供一個Property程序和方法，此Property程序和方法允許外部的程式碼只將內部資料由一個有效狀態改變成另一個有效狀態。然而這種方式有一個危險的缺失：如果一個物件在建立之後立即的被使用則會發生什麼狀況呢？你可以在Class_Initialize事件程序中提供一些有用的初始值及有效值，但如此卻無法確定所有的程序都在有效的狀態下：
Set pers = New Cperson Print pers.CompleteName ' Displays an empty string.
在許多健全的OOPL中就像C++，這個議題可藉由定義建構者（constructor）所解決。建構者是個特別的程序，被定義在類別模組中，且當新的實體被建立時便執行。因為定義建構者的語法，可以強迫用戶端程式傳遞從一開始的健全狀態需要建立物件所需要的值，或者若值被省略或無效時，拒絕建立物件。
Visual Basic完全缺少建構者，且您無法預防類別使用者建立物件後即使用它。所要做的最好的是建立一個 pseudo-constructor 方法，正確地初始化所有的屬性，且讓其他設計者知道他們可以簡要的和健全的方式來初始化物件：
Friend Sub Init(FirstName As String, LastName As String)
Me.FirstName = FirstName
Me.LastName = LastName
End Sub
您的要求應會很高興被接受，因為現在用戶端程式可以用較少的步驟來初始化物件：
Set pers = New Cperson pers.Init "John", "Smith"
在之前的程式中有兩個議題值得注意。第一，方法的範圍是Friend：在此情況下並沒有任何不同，但當且若類別變成公開且從外面可進入它時將變成重要的，第16章會說到。在標準EXE專案，友善和公開是相同的；使用前者並沒關係，且若稍後決定轉換專案為ActiveX元件時，將會節省許多工作。
第二點值得注意的是，引數與其指向的屬性有著相同的名稱，使得已經知道每屬性意義的設計師能更簡單地使用pseudo-constructor。為了避免名稱的衝突，在程序內部使用 Me 關鍵字指向實際的屬性。這稍微沒有效率，但可保存資料的一致性，且確保任何有效的程式碼將被適當執行，當建構者指定值給屬性時。
建構者還可以使用選擇性引數。Cperson類別的關鍵屬性是 FirstName 和LastName，但在許多例子中用戶端程式也設定 BirthDate 和 ID。所以對於使用類別的設計師為什麼不讓工作變得簡單些呢？
Friend Sub Init(FirstName As String, LastName As String, _
Optional ID As Variant, Optional BirthDate As Variant)
Me.FirstName = FirstName
Me.LastName = LastName
If Not IsMissing(ID) Then Me.ID = ID
If Not IsMissing(BirthDate) Then Me.BirthDate = BirthDate
End Sub
在這個情況下，您必須使用Variant型態的選擇性引數，因為對於使用 ISMissing 函數和略過用戶端未提供的值來說是必要的。
pers.Init "John", "Smith", , "10 Sept 1960"
您可以作更多的事情來改善類別的可用性，並被其他設計師接收。這真的很重要，因為若能能夠說服類別使用者來呼叫您提供的建構者－並且您必須採取柔軟姿態，因為無法強迫他們－您的程式碼和完整的應用程式將會更健全。我建議的技巧是在應用程式的BAS模組內寫一個建構者函數。
Public Function New_CPerson(FirstName As String, LastName As String, _
Optional ID As Variant, Optional BirthDate As Variant) As CPerson
' You don't even need a temporary local variable.
Set New_CPerson = New CPerson
New_CPerson.Init FirstName, LastName, ID, BirthDate
End Function
這一類型的程序有時叫做 factory 方法。現在看一下這如何可以建立一個類別實體的部分用戶端程式碼：
Dim pers As Cperson
' Creation, initialization, and property validation in one step!
Set pers = New_CPerson("John", "Smith", , "10 Sept 1960")
小秘訣
當使用這些建構者時，可以減少打字和猜測，若將他們聚集在BAS模組內，並且給這模組一個簡易的名稱，例如 Class 或 Factory（抱歉，無法使用 New）。然後當需要輸入建構者名稱時，只要打入 Class，讓Microsoft IntelliSense透過包含在此模組中的建構者的一串列表來指引您。您可在不記得在模組內程序名稱時使用這一個方法。
藉由明顯的建構者來建立所有的物件還有其他好處。譬如，可以簡單地在New_Cperson 程序中增加一些追蹤敘述來紀錄多少物件被建立、屬性初始值和其他等等。不要低估這個功能，若您正在寫使用許多類別模組和物件實體的複雜應用程式時。
屬性的進階使用
筆者要告訴您更多有關可以使類別更有用更有力的屬性。
指明屬性
某些屬性是預期將傳回一組定義好的整數值。例如，可以實作 MaritalStatus 屬性，此屬性有下列幾種值：1 (NotMarried)、2 (Married)、3 (Divorced)和 4 (Widowed)。在Visual Basic4一個最可能的解決方法是定義一組常數，且在類別內部和外部一致地在程式碼中使用它。然而，這個實作強迫開發者放置 CONST 指令在BAS模組，破壞類別的封鎖。
Visual Basic 5新增一個新的 Enum 關鍵字（其能夠建立指明值），解決了此議題。Enum 架構只不過是個自動取得單一值的一群相關常數值。
' In the declaration section of the class
Enum MaritalStatusConstants
NotMarried = 1
Married
Divorced
Widowed
End Enum
不需要指定明確的值給 Enum 結構的所有項目：對於所有省略的值，Visual Basic僅僅遞增先前的值（所以在先前的程式碼中Married是 2， Divorced是3等等）。若省略第一個值，Visual Basic預設為0。但因為當類別被建立時，0對任何整數屬性來說是預設值，筆者總是喜歡使它很明確以便於往後可捕捉未初始的值。
定義一個 Enum 結構後，可以建立一個相關型態的公開屬性：
Private m_MaritalStatus As MaritalStatusConstants
Property Get MaritalStatus() As MaritalStatusConstants
MaritalStatus = m_MaritalStatus
End Property
Property Let MaritalStatus(ByVal newValue As MaritalStatusConstants)
' Refuse invalid assignments. (Assumes that 0 is always invalid.)
If newValue<= 0 Or newValue > Widowed Then Err.Raise 5
m_MaritalStatus = newValue
End Property
使用指明屬性的好處是變成一切變得表面化，當您使用他們來撰寫程式碼時。事實上，幸虧IntelliSense，一旦您按下等號鍵時，Visual Basic編輯器會列出所有可用的常數列表，如圖6-3。再者，所有定義的指明屬性直接在物件瀏覽器中出現，所以在此您可以確認每個獨立項目的實際值：
| 圖6-3 當用指明屬性時，使用IntelliSense來加快打字。 |
當處理 Enum 值時，這裡有些您必須知道的細節：
| 圖6-4 在一個公開的類別中並無法使用 Enum 值，若 Enum 區塊位於表單模組、一個私有類別，或一個標準的BAS模組內時。 |
最後一點尤其重要，我強烈建議您有個對所有指明常數產生唯一名稱的方法。若失敗的話，編譯器會拒絕編譯您的應用程式，並產生 "察覺不清楚的名稱："<itemname>" 的錯誤。避免此一問題的簡單方法是對所有指明常數增加獨特的2至3個字首。
Enum SexConstants
sxMale = 1
sxFemale
End Enum
避免問題的另一個方法是使用完整的 enumname.constantname 語法，當要表示一個不清楚的 Enum 成員時，程式碼如下：
pers.MaritalStatus = MaritalStatusConstants.Married
Enum 值不需要照順序遞增。事實上，可以提供脫離順序的特別值給某些特殊條件，如下：
' In a hypothetical Order class
Enum OrderStatusConstants
osShipping = 1
osBackOrder
osError = -9999 ' Tip: use negative values for such special cases.
End Enum
另一個沒有連續性的指明屬性的常見範例是位元欄位屬性，如下：
Enum FileAttributeConstants
Normal = 0 ' Actually means "no bit set"
ReadOnly = 1 ' Bit 0
Hidden = 2 ' Bit 1
System = 4 ' Bit 2
Directory = 16 ' Bit 3
Archive = 32 ' Bit 4
End Enum
雖說指明屬性非常有用，且允許儲存一些描述性資訊在4位元組的記憶體，您不該忘記遲早必須取出和解譯此資訊，且有些時候甚至在您的使用者面前顯示它。基於此，筆者通常新增一個唯讀屬性給筆者的類別，此屬性傳回指明屬性的描述。
Property Get MaritalStatusDescr() As String
Select Case m_MaritalStatus
Case NotMarried: MaritalStatusDescr = "NotMarried"
Case Married: MaritalStatusDescr = "Married"
Case Divorced: MaritalStatusDescr = "Divorced"
Case Widowed
If Sex = Male Then ' Be precise for your users.
MaritalStatusDescr = "Widower"
ElseIf Sex = Female Then
MaritalStatusDescr = "Widow"
End If
Case Else
Err.Raise 5 ' Defensive programming!
End Select
End Property
對於這少數資訊似乎得做許多事，但是您會很高興於必須每次在螢幕或報表中顯示這些資訊。您可能想知道為何我增加一個 Case Else 區塊（以粗體顯示）。畢竟 m_MaritalStatus 變數無法被指派超出範圍的值，因為它被 Property Let MaritalStatus 程序所保護，對吧？但您應該從未忘記類別通常是逐步發展，今天是對的明天可能會改變。用來測試屬性的有效範圍的所有驗證程式碼可能變成廢棄的，一旦沒有注意它的話。舉例來說，若稍後增加第五個 MaritalStatus 時會發生什麼事。每次增加一個新的指明值，您確實透過程式碼尋找可能的錯誤？明顯地測試 Select Case 區域中的所有值，並拒絕那些無法達到的值。 Case Else 語法是種防禦性的程式碼，若不想要之後花費太多時間來偵錯程式碼的話，應要常用此種方式。
這裡有個簡單的技巧，讓您安全地增加一個新的常數，無須需在相對的 Property Set 程序中修正驗證程式碼。只要在定義 Enum 架構中明白定義最大的常數，取代測試是否違反最大常數。
Enum MaritalStatusConstants
NotMarried = 1
Married
Divorced
Widowed
MARITALSTATUS_MAX = Widowed ' Uppercase is easier to spot.
End Enum
Property Let MaritalStatus(ByVal newValue As MaritalStatusConstants)
' Refuse invalid assignments. (Assumes that 0 is always invalid.)
If newValue <= 0 Or newValue > MARITALSTATUS_MAX Then Err.Raise 5
m_MaritalStatus = newValue
End Property
然後當您在 Enum 區塊添加常數，需要使MARITALSTATUS_MAX項目指向新的最大值。若增加一段註解，如先前的程式碼中，您幾乎不會忽略它。
可傳回物件的屬性
Visual Basic自己的物件可能有可傳回物件值的屬性。例如，表單和所有看的到的控制項有個 Font 屬性，此屬性依序可傳回Font物件。您了解這是個特殊的情況，因為您可以在屬性名稱增入“ . ”，IntelliSense會告知物件的屬性名稱：
Form1.Font.Bold = True
Visual Basic處理自己的物件的方式也可用在您自訂的類別中。這對於您OOP的可能性大增。例如，CPerson類別仍然缺少 Address 屬性，那麼這是增加的時機。在多數的情況下，一個單一的Address字串無法確切指出一個人的居住地，通常還需要一些相關的資訊。建立一個新的CAddress類別來替代新增多數屬性給Cperson物件。
' The CAddress class module
Public Street As String
Public City As String
Public State As String
Public Zip As String
Public Country As String
Public Phone As String
Const Country_DEF = "USA" ' A default for Country property
Private Sub Class_Initialize()
Country = Country_DEF
End Sub
Friend Sub Init(Street As String, City As String, State As String, _
Zip As String, Optional Country As Variant, Optional Phone As Variant)
Me.Street = Street
Me.City = City
Me.State = State
Me.Zip = Zip
If Not IsMissing(Country) Then Me.Country = Country
If Not IsMissing(Phone) Then Me.Phone = Phone
End Sub
Property Get CompleteAddress() As String
CompleteAddress = Street &; vbCrLf &; City &; ", " &; State &; " " &; Zip _
&; IIf(Country <> Country_DEF, Country, "")
End Property
簡易起見，所有屬性皆宣告為Public，因此這類別不是健全的。在實際的例子中，還可做許多不錯的事使類別成為好的程式碼，例如確認 City、State 和 Zip 屬性與其他相容。（您可能需要在資料庫進行對照查詢）。甚至可以自動提供一區域碼給 Phone 屬性。我欣然地留下這些機制給讀者做為練習。現在，讓我們回到如何讓此新類別與Cperson互動。增加一個新的 HomeAddress 屬性給CPerson類別，只需要在模組宣告區域中寫一行程式碼。
' In the CPerson class module Public HomeAddress As Caddress
現在可以建立Caddress物件，初始化它的屬性，然後將它指派給剛建立的HomeAddress 屬性。幸虧 Init 虛擬建構者，您可以減少實際在用戶端需要的程式碼數量：
Dim addr As Caddress Set addr = New CAddress addr.Init "1234 North Rd", "Los Angeles", "CA", "92405" Set pers.HomeAddress = addr
雖說這種方法是很功能化且邏輯上正確的，但就是有點不自然。此問題起源於必須在指派它給 HomeAddress 屬性前明白地建立一個Caddress物件。為何不直接使用 HomeAddress 屬性？
Set pers.HomeAddress = New Caddress pers.HomeAddress.Init "1234 North Rd", "Los Angeles", "CA", "92405"
當應用巢狀物件屬性時，您可使用 With...End With 語法：
With pers.HomeAddress
.Street = "1234 North Rd"
.City = "Los Angeles"
' etc.
End With
如先前所示，在標準的BAS模組可以提供一個獨立的建構方法，而不需要分開的 Set 敘述：
Set pers.HomeAddress = New_CAddress("1234 North Rd", "Los Angeles", _
"CA", "92405")
Property Set程序
有個必須面對的小問題是缺乏對指派到 HomeAddress 屬性的控制。如何能確認指派一個不健全或無效的Caddress物件給 HomeAddress 屬性時，沒有問題會發生呢？且若是需要讓 HomeAddress 屬性為唯讀時呢？
一如您所看到的，當處理一般，非物件的屬性時，您也面對相同的問題，由於Property Get 和 Property Let 程序可解決這些問題。所以了解可以像物件屬性的做法相同時，不該感到訝異。唯一不同的是您使用屬性程序的第三種類型，Property Set 程序，而非 Property Let 程序。
Dim m_HomeAddress As CAddress ' A module-level private variable.
Property Get HomeAddress() As CAddress
Set HomeAddress = m_HomeAddress
End Property
Property Set HomeAddress(ByVal newValue As CAddress)
Set m_HomeAddress = newValue
End Property
因為正處理物件參照，您必須在這兩個程序中使用 Set 關鍵字。確認Caddress物件被指派給 HomeAddress 屬性是否有效的簡單方法是用所有需求的屬性來試驗其 Init 方法。
Property Set HomeAddress(ByVal newValue As CAddress)
With newValue
.Init .Street, .City, .State, .Zip
End With
' Do the assignment only if the above didn't raise an error.
Set m_HomeAddress = newValue
End Property
遺憾地，保護物件屬性不接受無效的指派不是那麼簡單。若最內部的類別-在此為 Caddress-無法以健全的方法來保護自己，那最外層的類別也很難做什麼。為了解釋為什麼，追蹤這顯然不正確的敘述：
pers.HomeAddress.Street = "" ' An invalid assignment raises no error.
首先，對於看到未執行 Property Set HomeAddress 程序可能感到驚訝；相反地是執行 Property Get HomeAddress 程序，其似乎沒有意義，因為我們是指派值，而非讀取它。但若我們從編譯看法來看此程式碼，事情就變成不一樣了。編譯器從此行的左邊掃到右邊：首先發現到CPerson類別的屬性參照（就是pers.HomeAddress），嘗試去決定它指向什麼地方。基於此，它必須計算相對的 Property Get 程序。結果是無法有效地使用 Property Get HomeAddress 程式來防止CPerson類別模組成為無效位址：您必須保護CAddress依賴自己的類別。就某種意義來說，這是公平的，因為每個類別應該對自己負責。
讓我們看看如何使用Cadress類別改善Cperson類別。現在已經使用了HomeAddress 屬性，但是還有其他可能的應用：
' In the declaration section of Cperson Private m_WorkAddress As CAddress Private m_VacationAddress As CAddress ' Corresponding Property Get/Set are omitted here....
您已是用最少的力氣可以達到許多機能，但這只是表面的。您不只是戲劇性地減少Cperson類別的大量程式碼（只需要三對 Property Get/Set 程序），也簡化了它的結構，因為沒有大量令人困惑的相似屬性名稱（HomeAddressStreet、WorkAddressStree等等）。但最重要，您只在一個地方決定CAddress的邏輯，而它會在應用系統其他地方會自動衍生，而不需要對每個地址屬性的不同型態設定不同的驗證規則。當要指派有效的地址時，看看顯示其所有是多麼簡單的事：
On Error Resume Next ' The error handler skips unassigned (Nothing) properties. Print "Home: " &; pers.HomeAddress.CompleteAddress Print "Work: " &; pers.WorkAddress.CompleteAddress Print "Vacation: " &; pers.VacationAddress.CompleteAddress
Variant屬性
傳回Variant值的屬性與其他屬性並沒有不同：只需要宣告一個公開Variant成員就完成了。但若屬性可以接收正常的值或物件值時，事情就有點複雜。舉例來說，假設想要實作 CurrentAddress 屬性，但想要保持有彈性，且能夠儲存Caddress物件或簡單字串時，如下所示：
' The client code can assign a regular string pers.CurrentAddress = "Grand Plaza Hotel, Rome" ' or a reference to another CAddress object (requires Set). Set pers.CurrentAddress = pers.VacationAddress
雖說彈性的排序對類別增加許多力量，但它也減少它的健全性，因為無法阻止程式設計者增加非字串值或有別於CAdress的類別物件。想要控制中實際分派給此屬性的東西，需要透過屬性程序調停所有對於它的存取。但在此情況下，需要三個不同的屬性程序：
Private m_CurrentAddress As Variant
Property Get CurrentAddress() As Variant
If IsObject(m_CurrentAddress) Then
Set CurrentAddress = m_CurrentAddress ' Return a CAddress object.
Else
CurrentAddress = m_CurrentAddress ' Return a string.
End If
End Property
Property Let CurrentAddress(ByVal newValue As Variant)
m_CurrentAddress = newValue
End Property
Property Set CurrentAddress(ByVal newValue As Variant)
Set m_CurrentAddress = newValue
End Property
當一般值被分派給屬性時，Property Let 屬性會被引發，而當用戶端用 Set命令指派物件時，Property Set 程序會起作用。記住，Property Get 程序如何傳回值給呼叫程式碼：它必須測試私有變數是否目前包含一個物件，然後若是物件的話，必須使用 Set 命令。Property Let 和 Set 讓您強化成為更好的驗證架構：
Property Let CurrentAddress(ByVal newValue As Variant)
' Check that it is a string value.
If VarType(newValue) <> vbString Then Err.Raise 5
m_CurrentAddress = newValue
End Property
Property Set CurrentAddress(ByVal newValue As Variant)
' Check that it is a CAddress object.
If TypeName(newValue) <> "CAddress" Then Err.Raise 5
Set m_CurrentAddress = newValue
End Property
這裡有個技巧讓您節省一些程式碼並稍微改進執行期間的效能。此技巧是宣告所期望的物件類別，在 Property Set 程序的參數列中，程式碼如下：
Property Set CurrentAddress(ByVal newValue As CAddress)
Set m_CurrentAddress = newValue
End Property
並不能使用這個方法在所有情況下；例如，當可接受兩個或更多不同型態的物件時，不能使用它。在這個例子中，使用 As Object 參數是最好的：
Property Set CurrentAddress(ByVal newValue As Object)
If TypeName(newValue) <> "CAddress" And TypeName(newValue) <> _
"COtherType" Then Err.Raise 5
Set m_CurrentAddress = newValue
End Property
對Visual Basic而言，真正的型態是被宣告在 Property Get 程序中的值所決定。事實上，那也是在物件瀏覽器顯示的型態。
在BAS模組中的屬性
也可以在標準的BAS模組中建立屬性程序，不過Visual Basic手冊中這個事實並沒有記載。這個功能使一些不錯的技巧變成有可能實現。可以使用一對屬性程序來封裝全域變數且調停對全域變數所有的存取。底下為一範例：
' In a standard BAS module Public Percent As Integer
對於實際健全的程式碼而言，要確認指派給全域變數的所有值是在0到100的範圍，但是不想在程式碼中測試所有的指派敘述。這個解決方法很簡單，在下一章節就會介紹。
Dim m_Percent As Integer
Property Get Percent() As Integer
Percent = m_Percent
End Property
Property Let Percent(newValue As Integer)
If newValue < 0 Or newValue > 100 Then Err.Raise 5
m_Percent = newValue
End Property
這技巧其他有趣的變化是唯讀和寫一次／讀多次的全域變數。也可用這一技巧來彌補Visual Basic的不足，宣告包含 Chr$ 函數與連續運算元的字串常數。
' You can't do this with a CONST directive.
Property Get DoubleCrLf() As String
DoubleCrLf = vbCrLf &; vbCrLf
End Property
最後，在BAS模組可以使用Property程序來追蹤在程式碼中全域變數會發生什麼事。假設程式不正確地指派錯誤值給全域變數，而您想要瞭解這是何時發生的。只要用一對Property程序替代變數，加上 Debug.Print 敘述（或輸出至檔案）。當修正所有問題後，刪除這程序並且還原成原本的全域變數。關於此最好的是不需要在應用系統中編輯單一行的程式碼。
CallByName函數
Visual Basic 6的VBA語言包含一個受歡迎的附加功能，此以 CallByName 函數的形式存在。這一關鍵字可參照一個物件的方法或屬性，藉由在參數中傳遞物件的名稱，語法如下：
result = CallByName(object, procname, calltype [,arguments..])
其中 Procname 是屬性或方法的名稱，而 calltype 值如下：1-vbMethod、2-vbGet、4-vbLet、8-vbSet。您必須傳遞方法所期待的任何參數，且應該避免擷取傳回值，若引入Sub方法或 Property Let/Get 程序時。這裡有個例子：
Dim pers As New Cperson ' Assign a property. CallByName pers, "FirstName", vbLet, "Robert" ' Read it back. Print "Name is " &; CallByName(pers, "FirstName", vbGet) ' Invoke a function method with one argument. width = CallByName(Form1, "TextWidth", vbMethod, "ABC")
這裡有些有關此函數值得注意的資訊，兩者皆影響函數的可用性：
就一般規則來說，當使用正規的“ . ”語法可以達到相同效果時，應該不要使用 CallByName 函數。然而，當這函數允許您撰寫簡潔和高度參數的程式碼時還是可用的。一個有趣的應用程式多能在表單中快速設定控制項的許多屬性。當要讓使用者有能力來訂做表單，然後在 Form_Load 事件中需要還原最後的配置時，這可能是有用的。我準備兩個做此工作的可再利用的程序：
' Returns an array of "Name=Values" strings
' Supports only nonobject properties, without indices
Function GetProperties(obj As Object, ParamArray props() As Variant) _
As String()
Dim i As Integer, result() As String
On Error Resume Next
' Prepare the result array.
ReDim result(LBound(props) To UBound(props)) As String
' Retrieve all properties in turn.
For i = LBound(props) To UBound(props)
result(i) = vbNullChar
' If the call fails, this item is skipped.
result(i) = props(i) &; "=" &; CallByName(obj, props(i), vbGet)
Next
' Filter out invalid lines.
GetProperties = Filter(result(), vbNullChar, False)
End Function
' Assign a group of properties in one operation.
' Expects an array in the format returned by GetProperties
Sub SetProperties(obj As Object, props() As String)
Dim i As Integer, temp() As String
For i = LBound(props) To UBound(props)
' Get the Name-Value components.
temp() = Split(props(i), "=")
' Assign the property.
CallByName obj, temp(0), vbLet, temp(1)
Next
End Sub
當使用GetProperties時，必須提供一串您所感興趣的屬性，但當用SetProperties呼叫恢復屬性時則不需要此列表。
Dim saveprops() As String saveprops() = GetProperties(txtEditor, "Text", "ForeColor", "BackColor") ... SetProperties txtEditor, saveprops()
特性
透過程式碼視窗並無法完全地定義一個類別。事實上，您必須用一種不同的方式詳細說明一些重要的特性。這些特性可能與類別模組的全部或個別成員有關（亦即其屬性和方法）。
類別模組特性
觀念上，類別模組本身的特性是單純的，因為可以透過屬性視窗來編輯他們，就像在Visual Basic環境中的其他原始程式碼模組般。但與表單和標準模組相比，當按下F4鍵後，依據專案類型的不同，屬性視窗所看到的也不一樣（參考圖6-5）。這裡有六個特性：Name、DataBindingBehavior、DataSourceBehavior、Instancing、MTSTransactionMode 以及 Persistable。在之後的章節會依序提到。
| 圖6-5 只有在ActiveX DLL專案的公開類別模組才會在屬性視窗中顯示所有可能的類別特性。 |
類別的預設成員
大多數Visual Basic控制項和內建物件都有個預設的屬性或方法。舉例來說，TextBox控制項的預設屬性是 Text；Error物件的預設屬性是 Number，Collections有個預設的 Item 方法等等。這些項目稱為預設成員，因為若在表示式中省略他們的話，Visual Basic會假設指向特定的成員。藉由以下程序，可以在您的類別中實作相同的機制：
| 圖6-6 從物件瀏覽器選擇屬性選項 |
| 圖6-7 展開的Procedure Attributes對話框 |
一個類別不能有多個預設屬性或方法。若嘗試建立第二個預設值，Visual Basic會抱怨並會確認您的決定。一般而言，改變類別的預設成員並非好主意，因為這修正可能破壞先前所寫的所有用戶端程式碼。
筆者相當同意提供預設屬性給類別模組會讓它更簡單使用，我想要警示您使用此特性導致某些可能的問題。回到Cperson類別與他的 HomeAddress 及 WorkAddress 屬性。如您所知道的，可以指派一個物件屬性給另一個：
Set pers.HomeAddress = New Caddress Set pers.WorkAddress = New CAddress pers.HomeAddress.Street = "2233 Ocean St." ... Set pers.WorkAddress = pers.HomeAddress ' This person works at home.
由於此程式碼使用 Set 命令，兩者的屬性實際上正指向相同的CAdress物件。這很重要，因為這暗指沒有配置額外的記憶體來儲存重複的資料，且也因為您可以自由地透過兩個Cperson屬性的其中一個來修正Address屬性，而不會發生不一致：
pers.HomeAddress.Street = "9876 American Ave" Print pers.WorkAddress.Street ' Correctly displays "9876 American Ave"
若錯誤的省略 Set 關鍵字，看看會發生什麼事：
pers.WorkAddress = pers.HomeAddress ' Error 438 "Object doesn't support
' this property or method"
別被錯誤訊息所驚嚇：在您的程式碼中有個邏輯錯誤，執行時Visual Basic會指出它，這是件好事。若類別有個預設屬性，這個有用的錯誤將消失。想看看怎麼回事嗎？讓 Street 成為類別的預設項目，然後執行以下程式碼：
Set pers.HomeAddress = New Caddress Set pers.WorkAddress = New CAddress pers.HomeAddress.Street = "2233 Ocean St." pers.WorkAddress = pers.HomeAddress ' No error! But has it worked?
這時沒有錯誤發生，看看現在這兩個屬性如何關連：
'Change the Street property of one object. pers.HomeAddress.Street = "9876 American Ave" Print pers.WorkAddress.Street ' Still displays "2233 Ocean St."
換言之，這兩個屬性不再指向相同的物件。沒有 Set 命令的指派欺騙了編譯器＜使之以為我們是要指定 Street 預設屬性的值（這是一個合法的動作），而並沒有要建立相同物件新的參照。
簡短的說，加入預設屬性後，您會忽略掉有關程式碼正當性的重要提示。筆者個人的經驗是忽略 Set 命令是個難以捉摸的Bug，且很難檢查到。當決定建立預設屬性時，千萬要記得這件事。且若決定建立他們，總要再次檢查程式碼中的 Set 關鍵字。
注意
您可能注意到若在一指定式中，左邊的物件屬性為Nothing時，Visual Basic會產生錯誤號碼91，即時我們省略Set關鍵字。然而這不會發生，若目標屬性已經被宣告為一個auto-instancing，因為如此Visual Basic會建立一個物件。這僅是進一步的證明，auto-instancing物件應該總是要被懷疑的。
有用的範例
雖說已警告您使用預設屬性，但現在筆者要展示一個例子來證明他們是非常有用的。但是首先筆者需要介紹 sparse matrices 概念。一個稀少陣列（Sparse matrices）是一個大的二維（或者是多維的）陣列，包括相對地少數的非零項目。一個只有500非零項目的1000X1000陣列可以是稀少陣列的絕佳例子。稀少陣列在數學和代數上並不常用到，但在商業應用系統上有個用途。例如，您可能有個1000個城市的列表，且有一個二維陣列來儲存任兩個城市的距離。假設我們使用0（或某些其他特殊值）來表示沒有直接連接的城市距離。大的稀少陣列會引發嚴重的記憶體負荷問題：一個有1000列和1000行（包含Single或Long值）的二維陣列需要將近4MB，所以您可以預期到它將會明顯地使應用程式變慢。
對此問題簡單的解決方法是只儲存非零的元素，連同期行列註標。對每個元素，需要8個額外的位元組，但最後將會節省一堆記憶體。例如，若只有10,000項目為非零（填滿率為1:100），您的稀少陣列將只需要小於120KB－這大概比原本的陣列小33倍-所以看來是個可能的解法。您可以會以為在Visual Basic實作稀少陣列需要相當多的程式碼，所以當使用類別模組時，您會驚訝它竟是如此簡單：
' The complete source code of the CSparseArray class
Private m_Value As New Collection
Property Get Value(row As Long, col As Long) As Single
' Returns an item, or 0 if it doesn't exist.
On Error Resume Next
Value = m_Value(GetKey(row, col))
End Property
Property Let Value(row As Long, col As Long, newValue As Single)
Dim key As String
key = GetKey(row, col)
' First destroy the value if it's in the collection.
On Error Resume Next
m_Value.Remove key
' Then add the new value, but only if it's not 0.
If newValue <> 0 Then m_Value.Add newValue, key
End Property
' A private function that builds the key for the private collection.
Private Function GetKey(row As Long, col As Long) As String
GetKey = row &; "," &; col
End Function
確保 Value 屬性－此類別的唯一公開成員－也是它的預設屬性，戲劇性地簡化用戶端使用者如何使用此類別。看看使用全新的、資源能力資料結構來代替正規陣列是多簡單的事：
Dim mat As New CSparseArray ' The rest of the application that uses the matrix isn't unchanged. mat(1, 1) = 123 ' Actually using mat's Value property!
換言之，幸虧預設屬性，藉由只改變用戶端程式碼的一行敘述可以改變應用系統的內部運作（這是被期望，同時也是最佳化的）。這應是對於贊同預設屬性令人信服的言論了。
實際上，CsparseArray類別比它所顯示的更強。事實上，其原本的實作是使用Long型態來表示其 row、col 參數，且傳回值為Single型態，您可能使用Variant型態來表示這兩個註標與其傳回值。第一個修允許您建立使用字串作為註標的陣列，如下列程式：
' The distance between cities
Dim Distance As New CSparseArray
Distance("Los Angeles", "San Bernardino") = 60
使用Variant傳回型態不會比之前的浪費太多的記憶體，因為內部的 m_Values集合無論如何皆對每個值配置一個Variant。
在本節結束前，提示另一個特別的陣列型態，稱為對稱陣列（symmetrical array）。此型態是二維陣列，m(i,j) 總是等於 m(j,i) ，所以值可以只儲存一次來節省記憶體。Distance 陣列是個不錯的對稱陣列例子，因為兩個城市的距離跟城市的順序無關。當用正規的Visual Basic陣列處理時，記得它的對稱性，且因此必須儲存兩次相同的值，這表示需要更多的程式、記憶體和導致錯誤的機會。幸好，現在可以將所有事情封裝進類別模組內，只需要編輯一個私有程序：
' Note that row and col are now Variants.
Private Function GetKey(row As Variant, col As Variant) As String
' Start with the lesser of the two--a case-insensitive comparison
' is needed because collections search their keys in this way.
If StrComp(row, col, vbTextCompare) < 0 Then
' Using a nonprintable delimiter is preferable.
GetKey = row &; vbCr &; col
Else
GetKey = col &; vbCr &; row
End If
End Function
這樣就夠讓使用戶端程式碼如預期般運作：
Dim Distance As New CsparseMatrix
Distance("Los Angeles", "San Bernardino") = 60
Print Distance("San Bernardino", "Los Angeles") ' Displays "60"
其他特性
您可能注意到在
圖6-7 Procedure Attributes 對話方塊還包含許多到目前為止未提及的欄位。大多數的屬性都是進階的，在本章中無法備及，但有三個值得額外解釋的。Description 可以用文字來描述定義在類別模組的屬性和方法。然後這描述會出現在物件瀏覽器，並提供類別模組的使用者有關每個成員如何使用。描述文字是可視的，即使當類別編譯成COM元件時亦然，以便讓其他程式設計者可從外部來瀏覽其介面。
HelpContextID 您可以提供一個說明檔，內容為對在專案內的所有類別、屬性、方法、事件等等的描述。倘若如此做的話，也應該指定一個特定的ID給專案中的每個項目。當物件瀏覽器最右邊的項目被選取時，按下？按鈕會自動帶您到相對的說明頁面。說明檔的名稱可以在專案屬性對話框中輸入。
Hide This Member 若選擇此一選項，當類別從專案外部被瀏覽時，類別模組內的屬性或方法在物件瀏覽器中是看不到的。此設定在目前專案中並沒有效果，且只在除標準EXE專案外的其他專案型態才有意義。記住：「 隱藏」一個項目不表示對其他程式設計者絕對無法看到。實際上，甚至在Visual Basic內的簡單物件瀏覽器也包括一個「顯示隱藏成員」選項（如圖6-6）。隱藏給定項目的決定應該只是對您類別使用者的建議，意思類似「不要使用此項目，因為他沒有被支援，且在產品未來的版本可能不會出現。」。
注意
所有的類別屬性-包括在本節中提及的及其他章節要提的-皆未儲存在原始程式碼內，所以當您要複製其所連結的程式碼時，他們並未在不同的類別模組間被複製和貼上。更糟的是，當您使用剪下貼上動作來重新安排在相同類別模組內的方法和屬性的順序時，他們甚至無法保存。若您想要在類別模組中移動程式碼而不遺失所有隱性連接的屬性時，首先必須複製想要放置的程式碼，然後從原來的位置刪除它。當重新命名屬性或方法時這就不在議題內了。
小秘訣
奇怪地，Visual Basic文件並沒有提及類別模組也支援它自己的DescriptionHelp 和 HelpContenID 特性，因此沒有解釋如何修改他們。這技巧是簡單的：在物件瀏覽器最左邊的面板以滑鼠右鍵按下類別名稱，並從pop-up選單中選擇Properties命令。
物件的內部運作
現在您對於如何撰寫與組織類別模組以及屬性跟方法如何運作有一個具體的了解，學習更多有關在Visual Basic中物件是需要時間的。
物件變數實際上是什麼
這看起來似乎是愚蠢的問題，但卻不是的。第一個回答是：物件變數是個持有物件資料的記憶體區域。此定義明顯地起源於對UDT架構（也持有組合資料）物件的相似，但遺憾地完全錯誤。事實是若建立兩個指向相同物件的物件變數，這是兩個不同的概念，例如：
Dim p1 As New CPerson, p2 As Cperson p1.CompleteName = "John Smith" Set p2 = p1 ' Both variables now point to the same object. Print p2.CompleteName ' Displays "John Smith" as expected. ' Change the property using the first variable. p1.CompleteName = "Robert Smith" Print p2.CompleteName ' 2nd variable gets the new value!
若物件和UDT行為舉止相同的話，最後一段敘述仍然傳回P2的原始值（"John Smith"），但倒數第二行給P1的指定也影響其它變數。此行為的理由是物件變數是實際指向物件資料被儲存的記憶體區域的指標。這是一個更令人關注的、有點訝異的重要概念。
最後提到一個問題：一個物件何時實際被釋放？結果是當沒有任何物件變數指向該物件時，Visual Basic會釋放此物件：
Sub TryMe()
Dim p1 As CPerson, p2 As CPerson
Set p1 = New CPerson ' Creates object "A"
p1.LastName = "Smith"
Set p2 = p1 ' Adds a 2nd reference to "A"
Set p1 = New CPerson ' Creates object "B", but doesn't
' release "A", pointed to by p2
p1.LastName = p2.LastName ' Copies a value, not an object ref
Set p2 = Nothing ' Destroys the original "A" object
End Sub ' Destroys the second "B" object
如您所見，紀錄許多變數如何指向一個物件可以簡單到變成讓人氣餒的工作。幸運地，這是Visual Basic的問題，而不是您的。Visual Basic使用所謂的reference計數器來解決此問題，下一節會作說明。
物件領域
圖6-8顯示一個典型物件被如何安排在記憶體中。Visual Basic程式設計師只看到一些物件變數：在這個例子中，我們有兩個變數，P1和P2，指向CPerson類別的實體，而第三個變數P3指向相同類別但與其他不同的實體。任何時候Visual Basic建立一個新的類別實體，分配一個區隔開的、定義好的區塊的記憶體（實體資料區域）。這一區域的結構和大小對於任何所給的類別是固定的，並依賴於物件有多少屬性、屬性的型態，以及其他本文中未提及的因素。這一區域的結構在Microsoft中並沒有被記載，但幸運地您不需要瞭解資料被儲存在哪裡或它如何被管理。
| 圖6-8 物件的結構可能比您所預期的更複雜。 |
然而，有一段資訊是對所有的開發者特別重要：一個四位元組記憶體位置，總是取得物件變數指向那特別實體資料區塊的數字。舉例來說，John Smith物件有一個參考計數等於2，而Anne Brown物件有一個參考計數等於1。對於計數器來說包含小於1的值是不可能的因為意即沒有變數指向一個特別的物件，且物件立即被釋放。無論如何，將這個記在心裡，一如程式設計師所關心的，參考計數器是一個絕對的實體，因為它不能用任何方法被讀取或修改（至少，使用orthodox設計技巧）。可以合法地使參考計數器唯一的改變是間接地使用 Set 命令遞增或遞減它。
Set p1 = New CPerson ' Creates an object and sets
' its reference counter to 1
Set p2 = p1 ' Increments the reference counter to 2
Set p1 = Nothing ' Decrements the reference counter back to 1
Set p2 = Nothing ' Decrements the reference counter to 0
' and destroys the object
' (Or you can let p2 go out of scope....)
在資料區塊實體的尾端是所有類別模組的變數的值，包括所以模組層次變數和在程序中的靜態變數（但不包括動態變數，此變數是在每一次呼叫的期間分配在Stack中）。當然，這些值在實體中變化，即使他們的外觀對類別的所有實體來說是相同的。
在資料區塊實體中另個未提及的資訊是非常重要的：它包含 Vtable 指標。32位元記憶體位址可以在資料區塊實體的前端被發現，是一個指向名為 Vtable 的其他關鍵記憶體的指標。屬於相同類別之所有物件指向相同 Vtable；在資料區塊實體前四個位元組總是符合。當然，對於不同類別的物件的前四個位元組是不同的。
Vtable 是個類別行為的實際特性，但它本身是非常明顯的小型架構。事實上，它只是 jump table 的一類，指向實際以編譯程式碼的一系列的長指標。每一指標相對於一個函數、或一個屬性程序，並指向在編譯處理期間每一程序所產生的已編譯程式碼之第一個位元組。讀／寫屬性在 Vtable 有兩個不同的進入點，且變數屬性可能會有三個進入點，若您也提供一個 Property Set 程序。因為在編譯期間知道應用程序可以在哪裡發現一個免費的記憶體區塊給已編譯程式下載進去是不可能的，每次編譯規則的位址只有在執行階段才知道。基於此，Vtable 結構也是在執行期間動態建立。
物件實體化過程
第一次Visual Basic建立一個已給類別的物件，它的執行期間模組表現有以下連續的運作：
這一串動作只在第一次程式碼建立一個所給定類別的物件時必須執行。對於相同類別的所有一系列物件，第一和第二步驟可以省略因為 Vtable 已經在適當的地方。當簡單地分配物件變數，第三步驟也可以省略，全部的動作變成只有32位元值被分配。
物件用法
讓我們瞧瞧當用戶端程式碼觸及一個物件的方法或屬性時會發生什麼事情。這裡只解釋許多可能情況下的一個，就是從屬於同一專案的類別使用一個物件。既然編譯器知道類別如何被安排，也知道類別的 Vtable 看似哪一種。當然，不能知道在編譯期間類別的已編譯程式碼將會落在何處，但是當類別被編譯時，至少它的結構可以被決定。因此，編譯器可以安全地轉換參照的屬性或方法到 Vtable 的區間中。因為在 Vtable 的首要七個項目通常被其他位址取得（本內容並不會提及），第一個定義在類別中的屬性或方法有一個等於28的區間（7 items * 4 bytes each）。以我們所提的類別來講，相對於 Property Get FirstName 程序的區間。當用戶端程式碼執行這敘述：
Print p1.FirstName
在這之後多多少少會發生的情況有：
取得一個值的過程是很漫長的，這是物件運作的事情。知道所有的事情不會幫助您寫出更好的程式碼，至少不能立即的。但是我確定在未來您將很少需要這些資訊。
小秘訣
通常，對物件分派和釋放實體資料塊是相當緩慢的動作。若類別模組在 Class_Initialize 事件執行太多程式碼-例如，必須從資料庫、Registry或INI檔案中取得資料，這成本會變成危急的。基於此，嘗試指派物件為全域變數來保持實體存活，只當確定不再需要物件時才釋放（或當應用程式即將達到終止讓Visual Basic自動設定變數為Nothing）。也可能提供一個特別的方法-例如，ReSet─重新出始化所有區域變數而不需建立新的實體。
物件結束過程
當不再有物件變數指向一個給定實體的資料塊時，物件將被釋放。釋放記憶體前，Visual Basic會在類別模組觸發 Class_Terminate 事件程序-若程式設計者有建立的話。這是個放置清除程式碼的程序。
Visual Basic沒有管到這麼多，舉例來說，根本即使沒有任何物件指向 Vtable，Visual Basic不會釋放 Vtable。這是一個重要的細節，因為它確保下一次這類別的其他物件被建立，成本將會最小。這裡有兩件有關終止階段的事應該知道：
Binding技巧
前面的章節，強調應用系統使用在 Vtable 的抵銷值及方法和屬性。這使得所有物件參照為有效率的，因為CPU必須只能執行一些附加和其它的基本步驟。從 Vtable 的區間取得屬性或方法名稱的過程就是binging。如同所看到的，這個過程通常是被編譯器所執行，然後在執行期間編譯器傳遞準備被執行的有效程式碼，並非所有物件參照如此有效率。讓我們看看如何阻礙編譯器。
Dim obj As Object
If n > = 0.5 Then
Set obj = New CPerson
Else
Set obj = New CCustomer
End If
Print obj.CompleteName
Visual Basic編譯器無法決定在執行期間，obj變數將完全地控制哪一方面的事情，事實上，物件內容完全不可預知的。此問題是即使Cperson和Ccustomer類別支援相同的 CcompleteName 方法，在Vtable的相同區間很難出現。因此編譯器無法完全連接處理過程，且儲存在執行期間必須被觸發的方法名稱中的可執行程式碼。當執行最後一行，Visual Basic查詢 obj 變數，決定控制哪一個物件，最後呼叫它的 CompleteName 方法。
之前所看到的情況有很大的不同，當我們知道在編譯期間哪一個完整的的規則將會被呼叫。有三種不同型態的binging。
Early VTable Binding Early binding過程在編譯期間就完成。編譯器產生Vtable 區間，此區間於執行階段被有效用來存取物件屬性和方法。若此屬性或方法不被支援，編譯器可以立即提出錯誤，意旨early binding暗喻傳遞健全的應用。不論是否使用已定義好的變數型態，Early binding都會被使用。當在物件名稱上加上小數符號物件將會使用early binding，而您將會有此間接的資訊：Visual Basic編輯器能夠給所有可能的方法和屬性列表。若編輯器能夠做到這樣，編譯器可以稍後完成binding。
Late Bindin 當使用 As Object 或 As Variant 宣告物件變數，編譯無法推演物件是何種型態，這樣的變數將包含並且可能因此只儲存有關屬性的或方法的名稱和引數資訊。Binding過程在執行期間完成，且變數被參照的任何期間被執行。想像一下，這會花費很多時間，此外對變數包含支援所想要的方法沒有任何保證。若實際上的物件不支援此方法，執行期間的錯誤將會發生。若有個通用的 As Object 變數，在程式模組中名字上加上小數點符號並不會出現屬性和方法的下拉式選單。
Early ID Binding 為了完整性，必須知道第三種binding，此binding行為會落在先前提到的兩者之間。early ID binding情況下，在 Vtable 中編譯器無法取得實際補償，但至少可以確認屬性或方法有在。若如此，編譯器在執行的程式碼中儲存特別的ID值。執行期間，Visual Basic使用這個ID在物件的一串方法中做快速的觀看。比early VTable binding速度慢，但仍然比late binding更有效率。它也確保沒有錯誤發生因為我們毫無疑問地知道這個方法是被支援的。這一類型的binding對某些被應用程式使用的外部物件有用的，例如，所有ActiveX控制項。
因此簡單的法則是總是應該努力在程式碼中使用early binding。除健全的考慮之外，late binding增加效率負載，多數情況中幾乎無法負荷。僅給您一個想法，使用late binding存取簡易的屬性大約是最有效率early binding的兩百倍慢。當呼叫程式碼越複雜。這差距會降低，因為early binding只影響呼叫期間，不是在方法中的程式碼執行期。即便如此，可幾乎不考慮無關緊要的差別。
最後記住宣告一個物件變數的方法影響Visual Basic使用early binding或late binding與否，但沒有辦法決定Visual Basic使用哪一種early binding型態。然而可以確認的是總是使用最便利的一個。若物件在目前應用系統中被定義或其有關的 Vtable 輸出資訊的library是結構化的，Visual Basic使用更有效率的 Vtable binding；否則，使用early ID binding。
再談物件關鍵字
熟之所有關於物件的知識後，應該對於一些VBA關鍵字後的真實機制就不難了解了。
New關鍵字
New關鍵字（在 Set 命令中使用）告知Visual Basic建立一個全新的給定類別。然後關鍵字傳回資料剛剛被分配的位址。
Set命令
Set 命令簡易地將等號右邊的東西複製一份給等號左邊的物件變數。譬如，這值可以是 New 關鍵字的結果，另一個已經存在的變數的內容，或為計算一個物件的結果。Set 命令執行的唯一工作是遞增相對於資料區塊的reference計數器和遞減原本指向左手邊變數的物件的參照計數（若變數沒有包含Nothing值）。
Set P1 = New CPerson ' Creates an object, stores its address
Set P2 = P1 ' Just copies addresses
Set P2 = New CPerson() ' Lets P2 point to a new object, but also
' decrements the reference counter
' of the original object
Nothing值
Nothing 關鍵字是Visual Basic中對物件變數說 Null 或 0 的方法。敘述如下：
Set P1 = Nothing
在 Set 語法下這並非特殊例子，因為它只遞減由P1指向的資料區塊參照數，然後在P1本身變數中儲存為0，如此從物件中分離它。若P1是目前指向這實體的唯一變數，Visual Basic也會釋放此實體。
Is運算子
Is 運算子被Visual Basic用來確認兩個物件是否指向同一資料區塊。在最低的層次下，Visual Basic沒有做任何事，但會比較包含在兩個運算元的實際位址，若符合則傳回True。只有唯一可能的變化是當使用 Is Nothing 檢測時，Visual Basic會比較包含0值之變數。需要特別的運算子，因為等號有完全不同意義，其會觸發物件預設屬性的計算。
' This code assumes that P1 and P2 are CPerson variables, and that ' Name is the default property of the CPerson class. If P1 Is P2 Then Print "P1 and P2 point to the same CPerson object" If P1 = P2 Then Print "P1's Name and P2's Name are the same"
TypeOf...Is敘述
可使用 TypeOf...Is 敘述檢驗物件變數的型態：
If TypeOf P1 Is CPerson Then
Print "P1 is of type CPerson"
ElseIf TypeOf P1 Is CEmployee Then
Print "P1 is of type CEmployee"
End If
您應該要知道兩個限制。首先，在同一時間內只能檢驗一個類別，且甚至不可直接檢測物件是否並非某特定類別。在此情況下，請見下例：
If TypeOf dict Is Scripting.Dictionary Then
' Do nothing in this case.
Else
Print "DICT is NOT of a Dictionary object"
End If
第二，只有Scripting library（一般稱為參照函數）被包含在參照對話框中，則先前的程式才能運作。若沒有，Visual Basic將會拒絕編譯這程式碼。當想要撰寫可再利用的程序時，有時候這是件麻煩的事。
小秘訣
當指定物件變數通常使用 TypeOf...Is 敘述來避免錯誤，程式碼如下：
' OBJ holds a reference to a control.
Dim lst As ListBox, cbo As ComboBox
If TypeOf obj Is ListBox Then
Set lst = obj
ElseIf TypeOf Obj Is ComboBox Then
Set cbo = obj
End If
但是這裡還有更快更簡要的方法：
Dim lst As ListBox, cbo As ComboBox On Error Resume Next Set lst = obj ' The assignment that fails will leave Set cbo = obj ' the corresponding variable set to Nothing. On Error Goto 0 ' Cancel error trapping.
TypeName函數
TypeName 函數傳回在表單字串中物件類別的名稱。意即可發現多數精簡的表單中物件的型態，如下：
Print "P1 is of type " &; TypeName(P1)
多數情況下，使用 TypeName 函數檢驗物件型態是優於使用 TypeOf...Is敘述，因為物件不需要在目前應用程式下或參照對話方塊中出現。
ByVal和ByRef關鍵字
物件變數僅僅是指標的事實可能會使程式設計者感到迷惑，當物件變數以ByVal 引述被傳遞給程序。兩者的差異在於𡢃{序可更改一個 ByVal 值，而不會影響呼叫者的原始值。也就是說，您可以簡易地建立一個複製的指標，而不是實體的資料區域。原本的和新的物件參照兩者是指向相同的地方，因此呼叫的程序可以自由地讀取和修正所有物件的屬性。若要避免對原始物件的修改，必須傳遞一份複製的物件給程序。如此做，我們必須自己建立新的物件。Visual Basic並不提供此捷徑。
這表示您需要瞭解當使用 ByRef 或 ByVal 宣告一個物件參數有些不同，以下程式碼可些微看出不同：
Sub Reset(pers As Cperson) ' ByRef can be omitted.
Set pers = Nothing ' This actually sets the original
End Sub ' variable to Nothing.
Sub Reset2(ByVal pers As CPerson)
Set pers = Nothing ' This code doesn't do anything.
End Sub
使用 ByVal 傳遞物件，內部參照計算暫時遞增，當程序離開又再遞減。若以參照來傳遞物件則不會發生此事情。基於此，在物件中使用 ByRef 關鍵字會稍微快一點。
Class_Terminate事件
在釋放資料區塊和終止物件的檔案前，Visual Basic會觸發 Class_Terminate 事件。當需要取消在初始期間或在生命期所做的事情時，通常會在此事件內撰寫相關程式。一般在這事件程序內，會關閉任何開啟的檔案，且釋放從API呼叫獲取的視窗資源。若想要使物件屬性保持在資料庫內，以便未來可使用的話，通常也會在此做相關程序。然而，總而言之，幾乎很少對這事件撰寫程式，或至少相對於 Class_Initialize 事件來說是少多了。舉例來說，CPerson類別模組實際上在它的 Class_Terminate 事件程序中是不需要程式的。
換句話說，撰寫可執行的程式，並且確定當物件被釋放時仍可被執行的事實開啟了不需要任何其他，非OOP技巧的可能性。為了確保您瞭解筆者的意思，筆者準備了在這概念下幾乎完整的三個範例類別。這是個讓您瞭解可以使用物件所附與的能力把數個平常的程式工作設計完成的時機。
注意
只當物件用依序的方式被釋放，當所有指向物件的參考被設為Nothing或超出範圍，或當應用程式達到終點，Visual Basic才呼叫 Class_Terminate 事件。這包括當應用程式因致命的錯誤而結束。只當從Run選單或工具列中的End按鈕突然結束程式，Visual Basich才不會引發 Class_Terminate 事件。這立刻停止程式碼中的所有動作，意指沒有任何Class_Terminate事件會被觸發。假若在 Terminate 事件中插入重要的程式碼秄狾p，釋放藉由API分配的視窗資源𨫀N會發生問題。有時候這是個大問題，包括系統損毀。因此，程式碼中決不要使用End命令來終止應用程式：因為這有著同樣的意思，但是在編譯應用程式後，於外界執行時才會發生問題。
範例1：管理滑鼠游標
程式設計師常會改變滑鼠游標的狀態，典型的有沙漏，告知使用者某些較長的動作正在進行。當然，也必須在離開目前程序前恢復游標；否則，沙漏會一直出現，而使用者則不瞭解等待已結束。這工作相當簡單，我發現在某些情況下，許多商業應用程式無法恢復原本的狀態。程序在沒有預期下離開是一個很清楚的症狀，因此喪失機會來恢復原本的狀態。類別和物件如何幫助我們避免相同的錯誤？看一下Cmouse類別模組吧！
' The CMouse class _ complete source code
Dim m_OldPointer As Variant
' Enforce a new mouse pointer.
Sub SetPointer(Optional NewPointer As MousePointerConstants = vbHourglass)
' Store the original pointer only once.
If IsEmpty(m_OldPointer) Then m_OldPointer = Screen.MousePointer
Screen.MousePointer = NewPointer
End Sub
' Restore the original pointer when the object goes out of scope.
Private Sub Class_Terminate()
' Only if SetPointer had been actually called
If Not IsEmpty(m_OldPointer) Then Screen.MousePointer = m_OldPointer
End Sub
不壞吧？只用八行程式碼永遠解決一再發生的錯誤！看一下在實際程式中如何簡單地使用此類別。
Sub ALengthyProcedure()
Dim m As New CMouse
m.SetPointer vbHourglass ' Or any other pointer shape
' ... slow code here ... (omitted)
End Sub
此技巧可運作，因為一旦變數脫離可用的範圍，物件會被釋放，且Visual Basic會引發其 Class_Terminate 事件。有趣的一點是若因為錯誤而導致離開程序，這一連串動作也會發生，Visual Basic會依序釋放程序的所有程序變數。
範例2：開啟和關閉檔案
另一個常用的程式化工作是開啟一個檔案來處理，然後在離開程序前關閉檔案。如在
第五章 所看到的，所有處理檔案的程序必須保護自身不受意外的錯誤干擾，因為若突然結束會導致無法正確地關閉檔案。再來，讓我們看看類別如何以精簡的方式幫助我們做好這件事。' The CFile class--complete source code
Enum OpenModeConstants
omInput
omOutput
omAppend
omRandom
omBinary
End Enum
Dim m_Filename As String, m_Handle As Integer
Sub OpenFile(Filename As String, _
Optional mode As OpenModeConstants = omRandom)
Dim h As Integer
' Get the next available file handle.
h = FreeFile()
' Open the file with desired access mode.
Select Case mode
Case omInput: Open Filename For Input As #h
Case omOutput: Open Filename For Output As #h
Case omAppend: Open Filename For Append As #h
Case omBinary: Open Filename For Binary As #h
Case Else ' This is the default case.
Open Filename For Random As #h
End Select
' (Never reaches this point if an error has occurred.)
m_Handle = h
m_Filename = Filename
End Sub
' The filename (read-only property)
Property Get Filename() As String
Filename = m_Filename
End Property
' The file handle (read-only property)
Property Get Handle() As Integer
Handle = m_Handle
End Property
' Close the file, if still open.
Sub CloseFile()
If m_Handle Then
Close #m_Handle
m_Handle = 0
End If
End Sub
Private Sub Class_Terminate()
' Force a CloseFile operation when the object goes out of scope.
CloseFile
End Sub
這類別解決大多數對於檔案處理的問題，包括發現下一個可用的檔案指標和在離開程序之前關閉檔案：
' This routine assumes that the file always exists and can be opened.
' If it's not the case, it raises an error in the client code.
Sub LoadFileIntoTextBox(txt As TextBox, filename As String)
Dim f As New CFile
f.OpenFile filename, omInput
txt.Text = Input$(LOF(f.Handle), f.Handle)
' No need to close it before exiting the procedure!
End Sub
範例3：建立程序的紀錄
筆者用一個簡單的類別來結束本章節：當偵錯許多一再呼叫其他巢狀程序時，您可能會發現滿有用的。在這樣的情況下，沒有任何事情可以比實際一串呼叫的紀錄更有效維持您的精神。遺憾地，說比做容易。因為在每個程序的第一行加入 Debug.Print 來追蹤程序何時離開是很複雜也是沒什麼意義的，尤其若程序有許多離開點或沒有任何錯誤處理時。然而，這棘手的問題可以用類別來解決，此類別只需要八行程式碼：
' Class CTracer - complete source code.
Private m_procname As String, m_enterTime As Single
Sub Enter(procname As String)
m_procname = procname: m_enterTime = Timer
' Print the log when the procedure is entered.
Debug.Print "Enter " &; m_procname
End Sub
Private Sub Class_Terminate()
' Print the log when the procedure is exited.
Debug.Print "Exit " &; m_procname &; " - sec. " &; (Timer - m_enterTime)
End Sub
使用類別很簡單，因為只必須在想要追蹤的任何程序前端增加兩行敘述：
Sub AnyProcedure()
Dim t As New Ctracer
t.Enter "AnyProcedure"
' ... Here is the code that does the real thing ...(omitted).
End Sub
CTracer類別顯示此程序所花費的總時間，所以它也像個簡單的Profiler。增加此特性是如此簡單以致於無法抗拒。
本章介紹Visual Basic的OOP，但還有些關於類別和物件的其他事情必須知道，例如：事件、多態性以及繼承。在下一章會提到這些主題，附帶提到對於建立更好的Visual Basic應用程式所需的技巧。