如何區分ActiveX執行檔和ActiveX DLL？
　

Visual Basic提供了兩種ActiveX元件（Component）：ActiveX執行檔和ActiveX DLL。Visual Basic讓你把物件放在ActiveX執行檔或是ActiveX DLL元件裡，透過ActiveX執行檔或ActiveX DLL，可以讓其他的應用程式（用戶端應用程式）使用你的物件。當一個應用程式使用ActiveX執行檔所提供的物件時，它會產生一份ActiveX執行檔的執行實體（Instance），應用程式是以"out-of-process"的方式執行ActiveX執行檔的程式碼，換句話說，ActiveX執行檔會在它自己的執行緒（Thread）和工作區（Workspace）中進行處理，不會和用戶端應用程式共用一個程式碼空間（Code Space）。

在另一方面，ActiveX DLL並不是一個可以獨立執行的應用程式，但它提供了包含著物件的動態連結程式庫（Dynamic Link Library, DLL）給應用程式，應用程式以"in-process"的方式把連結的物件放在自己的process裡執行。這表示ActiveX DLL裡的程式碼是在應用程式所擁有的單一執行緒程式碼空間（Single-threaded Code Space）裡執行，因此，整個應用程式執行起來會更快速，更有效率。

這兩種ActiveX元件都很有用，Visual Basic讓你能產生這兩種元件。

如何在外部的ActiveX元件中建立所有的自訂物件?
　

如果只是要在應用程式裡使用你自己產生的物件，不需要把物件放在ActiveX元件裡。建立和使用自訂物件最簡單的方法就是在「標準執行檔」專案裡加入物件類別模組。

對你的應用程式而言，由你的物件類別模組所定義的物件，是這個應用程式的私有物件（如果要讓其他的應用程式也可以使用這個物件，就必須使用ActiveX元件）。你的應用程式可以用同一個物件類別模組來產生一個以上的物件執行實體，每一個物件都有它自己的資料。使用物件有一個好處：當物件被捨棄不用之後，由這個物件所佔用的記憶空間立刻會由系統收回；但使用物件最大的好處應該是：物件強化了程式的組織結構，讓程式更易於被了解。

以下這兩節介紹一個相當簡單的例子來說明如何在標準執行檔中產生物件。

如何產生新物件？
　

對於這個問題最簡單的答案就是：建立一個物件類別模組。在這裡我們提供一個很簡單的範例，讓你對建立物件類別有基本的認識。

如何使用新物件？
　

Loan物件類別模組本身並不會產生一個物件，它只是提供了一個物件的藍圖，讓你的應用程式可以使用物件類別模組來產生真正的物件。在這一節裡我們將要完成一個應用LOAN.CLS的專案。

首先請建立一個只有一張表單的「標準執行檔」專案，改變表單的Caption屬性為"Please Click on This Form"，加入LOAN.CLS物件類別模組到你的專案裡，然後加入以下的程式碼到表單裡。圖5-1顯示的是設計階段中的表單。

Option Explicit

Private Sub Form_Click()
    Dim loanTest As New Loan
    Dim intCount As Integer
    Dim curBalance() As Currency

    'Clear the face of the form
    Cls
    'Set loan parameters
    loanTest.Reset
    loanTest.Principal = 1000
    loanTest.Months = 12
    loanTest.AnnualInterestRate = 8.5
    'Display parameters used
    Print "Principal: ", , Format(loanTest.Principal, "Currency")
    Print "No. Months: ", , loanTest.Months
    Print "(Years:) ", , loanTest.Years
    Print "Interest Rate:", , Format(loanTest.AnnualInterestRate _
        / 100, "Percent")
    Print "Monthly Payment: ", Format(loanTest.Payment, "Currency")
    Print
    'Get array of monthly balances
    curBalance() = loanTest.Balance()
    'Display payment schedule
    For intCount = LBound(curBalance) To UBound(curBalance)
        Print "Month: "; intCount,
        Print "Balance: "; Format(curBalance(intCount), "Currency")
    Next intCount
End Sub

在表單的Form_Click事件程序中，我們產生了一個Loan物件，將這個Loan物件指定給物件變數loanTest，這個Loan物件正如同其他的變數一樣，當程序執行完畢後，物件就會被破壞掉：

Dim loanTest As New Loan

以下三行程式碼指定三個值給三個Loan物件的屬性。

loanTest.Principal = 1000
loanTest.Months = 12
loanTest.AnnualInterestRate = 8.5

當Form_Click程序輸出其計算的結果時，如下所示，Loan物件中的許多屬性都被用到了；當程式讀取Principal、Months和AnnualInterestRate時，物件變數loanTest只是很單純的把屬性的現存值傳出，而Payment屬性被讀取時，複雜的計算就被啟動了，原呼叫程式並不知道這些計算是如何進行的。

Print "Principal: ", , Format(loanTest.Principal, "Currency")
Print "No. Months: ", , loanTest.Months
Print "(Years:) ", , loanTest.Years
Print "Interest Rate:", , Format(loanTest.AnnualInterestRate _
    / 100, "Percent")
Print "Monthly Payment: ", Format(loanTest.Payment, "Currency")
Print

叫用Balance屬性，如下所示，等於是告訴loanTest在內部計算每月應付金額，然後把這些金額放在一個陣列中：

'Get array of monthly balances
curBalance() = loanTest.Balance()

最後這幾行程式碼用來將每月應付金額顯示在表單上。

Display payment schedule
For intCount = LBound(curBalance) To UBound(curBalance)
    Print "Month: "; intCount,
    Print "Balance: "; Format(curBalance(intCount), "Currency")
Next intCount

當Form_Click程序結束時，所有的變數以及Loan物件中的程式碼和資料都會被系統破壞。

圖5-2顯示了這個程式執行的結果。你可以改進輸出結果並且加強這個程式的功能，但是你不用動到Loan物件類別模組裡的程式碼。物件設計好了之後，在你要提供給使用者的文件中就只要說明這個物件有什麼樣的界面（Interface）─公共屬性和方法──就足夠了，物件內部運作的細節就當作一個"黑箱"，可予以省略。你可以把物件想像成一個具有外部包裝的物體，外面的世界只看得到它可見的外表，物件本身負責執行它該執行的工作，而呼叫物件的程式則負責了解如何正確地使用這個物件，這就是物件導向程式設計裡所謂的資料封裝（Encapsulation）。這種資料封裝的技術讓我們可以很容易地發展大型的應用程式，也更易對程式進行偵錯，這就是物件導向程式設計的迷人之處。

我們除了可以很單純地把Loan物件模組加到一個應用程式裡之外，還可以把這個物件類別模組和ActiveX元件結合，稍後我們會討論這個主題。

參考資料：

如何在物件中設定預設屬性？
　

什麼是預設屬性（Default Property）？舉文字方塊控制項（TextBox Control）為例，屬性Text就是文字方塊控制項的預設屬性，意思就是你可以明確指出要存取的屬性是Text，但也可以不要指明Text屬性，而主角同樣都是Text這個屬性。下面這兩行陳述式是一樣的：

Text1.Text="This string is assigned to the Text property."
Text1="This string is assigned to the Text property."

筆者本身比較喜歡把屬性名稱都明確地寫在程式中，因為這樣可以增加程式的可讀性，但是有許多人卻比較喜歡使用預設屬性，而且Visual Basic也提供了這個特性讓你可以為你的物件設定預設屬性。

我們來看看如何幫Loan物件設定它的預設屬性。打開Loan物件類別的「程式碼視窗」，從「工具」功能表項目中選擇「程序屬性」，從「程序屬性」對話方塊的「名稱」下拉式清單中選擇Principal，然後按一下「進階」按鈕。再從在「程序識別碼」下拉式清單裡選取（預設值），最後按「確定」，這樣，Principal就成了Loan的預設屬性了。

為了檢查Principal有沒有被設定成預設屬性，請改變一下我們用來測試Loan物件的程式──把testLoan.Principal = 1000改為testLoan = 1000，然後執行測試程式，看看能不能得到正確的結果。

如何建立和使用ActiveX執行檔﹖
　

如何建立一個可以顯示表單的物件？
　

前面我們提到的Loan和Dice物件本身都不具備可以讓使用者看到的界面，例如表單；事實上有些時候，我們需要物件本身就能夠提供視覺界面，以便讓使用者輸入資料。

把表單加到ActiveX執行檔或ActiveX DLL並不是一件難事，但是這裡有個陷阱。你必須謹慎管理從物件裡面產生的表單。用戶端應用程式沒有辦法和這些表單互動（這些表單是屬於物件的私有元件），因此，物件本身的程式碼不但必須負責產生表單，更要負責銷毀這些表單，否則程式結束後，你的物件還會留在記體裡，浪費資源，有時候甚至會造成不可預期的結果。

以下的程式碼定義一個叫做User物件類別模組，這個物件將會顯示一張表單，表單上有兩個文字方塊控制項（txtName和txtPassword）和一個指令按鈕控制項cmdOK，可以讓使用者輸入名字和密碼。

'USER.CLS
'~~~.Name
Property Get Name()
    Name = frmPass.txtName
End Property

'~~~.Password
Property Get Password()
    Password = frmPass.txtPassword
End Property

'~~~.Show
Sub Show()
    frmPass.Show vbModal
End Sub

Private Sub Class_Terminate()
    'Unload form when object is destroyed
    Unload frmPass
End Sub

這張叫做frmPass的表單只有一個事件程序，如下所示。當使用者按下「確定」按鈕後，這個事件程序會把表單隱藏起來，我們可以用另一個程序來驗證使用者的名字和密碼，如果資料不正確，把這張表單再顯示出來，要求使用者重新輸入，我們把文字方塊控制項收到的資料保留起來，目的在於方便使用者局部修改輸入的名字或密碼。

'FRMPASS.FRM
Private Sub cmdOK_Click()
    Hide
End Sub

如果要使用這個物件，另一個應用程式只要產生一個User物件，然後用Show方法就可以了。以下的程式告訴你，如何在應用程式裡以一個指令按鈕控制項來叫用這個物件。

請注意我們如何引用在PasswordSample專案裡的User物件類別。

Private Sub cmdSignOn_Click()
    'Create an instance of the object
    Dim usrSignOn As New PasswordSample.User
    'Loop until user enters Guest password
    Do While usrSignOn.Password <> "Guest"
        'Display dialog box
        usrSignOn.Show
    Loop
End Sub

從圖5-6你可以看到User物件顯示表單的情形。

如果要了解表單的建立及銷毀的重要性，你可以把物件類別模組裡的Class_Terminate事件程序刪掉，然後再執行你的測試程式。當cmdSignOn_Click事件程序執行完畢後，usrSignOn所引用的物件就被破壞了，但是frmPass表單卻仍然留在記憶體裡，這表示有一個隱藏的物件實體還在執行著。

如果這個物件的應用程式是一個執行檔，你可以同時按--叫出Windows 95的「關閉程式」視窗，從視窗找到這個隱藏的物件，然後你必須用「結束工作」按鈕來解決這個問題。切記，不要讓你的物件產生這種問題，隱藏的物件實體有時很難偵查得出來。

一般而言，你要用Class_Initialize和Class_Terminate來做表單產生和銷毀的工作。因為我們介紹的範例十分簡單，我們直接呼叫物件方法來產生表單。

一般而言，較正規的做法是加入一個Class_ Initialize事件程序：

'Add to USER.CLS to be explicit
Private Sub Class_Initialize()
    'Create form when object is created
    'by calling Show method
    Show
End Sub

注意：

用最明確清楚的方式來產生和銷毀表單是一個好習慣，因為這樣子會省下你很多偵錯的時間。

事件、WithEvents和RaiseEvent
　

Visual Basic裡面有幾個新指令可以讓你把你自行定義的事件放到物件裡。在這裡提出這個話題是因為ActiveX執行檔中物件的私有表單可以運用"事件"和應用程式互動。這種表單可以驅動一些事件影響它專屬的物件，物件又可以因此而產生另一個事件來影響應用程式。

「線上手冊」裡的主題"Adding a Form To the ThingDemo Project"運用了許多事件、WithEvents和RaiseEvent指令，這是個很好的範例。

如何使用物件的集合？
　

Visual Basic的集合物件（Collection Object）讓你可以把多個物件或任何型態的資料項合併成一個單一的元件。Collection物件最常見的用途是用以管理數目不確定而屬於同一個物件類別的物件群。你可以把集合物件想像成一個無所不包（包括物件和其他集合物件）的陣列。

在你的物件裡使用集合物件的方式有很多種，端看你對你自己或別人的程式保護的程度，你可以用很簡單的方式也可以用較奇特卻又不失安全的方式，當然有些方式會比較"危險"一點，我們建議你徹底的研讀一下「線上手冊」裡有關於這方面的主題，了解Microsoft建議的方法之後再試試本書所建議的方法。

（在「線上手冊」中，請找下列這些主題：House of Straws，House of Sticks，以及House of Bricks）

在以下的範例中，筆者要介紹一個簡單的方法，讓你應用集合物件到你的物件裡，這個方法相當的可靠，而且裡面技巧很容易模仿、複製和修改。

我們要建立一個太陽系結構：其中包含一個最上層的Star物件，Star物件裡包含了一個Planets集合物件，Planets集合物件裡的每一個Planet物件又包含了一個Moons集合物件，而在Moons集合物件裡的每一個Moon物件則是一個只有Name屬性的簡單物件。

Collection實例──SolarSys
　

首先建立一個標準執行檔專案，把表單的Name屬性設為SolarSys，而Caption屬性改為"Collections Example"；加入一個指令按鈕控制項cmdBulildSolarSystem，把它的Caption屬性改為"Build Solar System"；把表單存成SOLARSYS.FRM，專案則存成SOLARSYS.VBP。加入下列程式碼到表單後，再存檔一次。

Option Explicit
Public starObject As New Star
Private Sub cmdBuildSolarSystem_Click()
    'Prepare working object references
    Dim planetObject As Planet
    Dim moonObject As Moon
    'Add planets and moons to the solar system
    With starObject.Planets
        'Create first planet
        Set planetObject = .Add("Mercury")
        'Set some of its properties
        With planetObject
            .Diameter = 4880
            .Mass = 3.3E+23
        End With
        'Create second planet
        Set planetObject = .Add("Venus")
        'Set some of its properties
        With planetObject
            .Diameter = 12104
            .Mass = 4.869E+24
        End With
        'Create third planet
        Set planetObject = .Add("Earth")
        'Set some of its properties
        With planetObject
            .Diameter = 12756
            .Mass = 5.9736E+24
            'Add moons to this planet
            With .Moons
                'Create Earth's moon
                Set moonObject = .Add("Luna")
                'Set some of its properties
                With moonObject
                    .Diameter = 3476
                    .Mass = 7.35E+22
                End With
            End With
        End With
        'Create fourth planet
        Set planetObject = .Add("Mars")
        'Set some of its properties
        With planetObject
            .Diameter = 6794
            .Mass = 6.4219E+23
            'Add moons to this planet
            With .Moons
                'Create Mar's first moon
                Set moonObject = .Add("Phobos")
                'Set some of its properties
                With moonObject
                    .Diameter = 22
                    .Mass = 1.08E+16
                End With
                'Create Mar's second moon
                Set moonObject = .Add("Deimos")
                'Set some of its properties
                With moonObject
                    .Diameter = 13
                    .Mass = 1.8E+15
                End With
            End With
        End With
    End With
    'Disable the command button
    cmdBuildSolarSystem.Enabled = False
    'Display the results
    Print "Planet", "Moon", "Diameter (km)", "Mass (kg)"
    Print String(100, "-")
    For Each planetObject In starObject.Planets
        With planetObject
            Print .Name, , .Diameter, .Mass
        End With
        For Each moonObject In planetObject.Moons
            With moonObject
                Print , .Name, .Diameter, .Mass
            End With
        Next moonObject
    Next planetObject
    'Directly access some specific properties
    Print
    Print "The Earth's moon has a diameter of ";
    Print starObject.Planets("Earth").Moons("Luna").Diameter;
    Print " kilometers."
    Print "Mars has";
    Print starObject.Planets("Mars").Moons.Count;
    Print " moons."
End Sub

圖5-7顯示的是設計階段的SolarSys表單。

我們首先把要用到的物件和集合物件定義完畢。然後再回頭討論程式內容。

Star物件類別
　

現在我們來定義Star物件類別。從「專案」功能表中選取「新增物件類別模組」，然後點選兩下「物件類別模組」圖像，將這個物件類別模組的Name屬性設定為Star，加入以下這段程式碼，然後將這個模組存成STAR.CLS。

Option Explicit

Public Name As String

Private mPlanets As New Planets

Public Property Get Planets() As Planets
    Set Planets = mPlanets
End Property
The Star

Star物件包含了一個Planets集合物件，這個集合物件則是定義了多個Planet物件，我們待會兒會介紹Planets和Planet物件。

請注意，在上面的程式中，Planets物件變數mPlanets是一個Private變數，外界無法直接取得它，而另一方面，Property Get Planets程序則提供了一個唯讀界面，讓外界只能讀出mPlanets中的資訊。( 因為沒有Property Let Planets程序，故外界的程式不能寫入任何資料到mPlanets中。)

Planets物件類別
　

在這個模擬太陽系中，所有的行星都以獨立的Planet物件作為代表，而這些Planet物件由Planets物件來管理 ( 請注意Planet和Planets單複數的差別 )。現在讓我們來建立Planets物件。加入另一個物件類別模組到專案中，命名為Planets，加入下面這段程式碼，將模組存成PLANETS.CLS。

Option Explicit
Private mcolPlanets As New Collection
Public Function Add(strName As String) As Planet
    Dim PlanetNew As New Planet
    PlanetNew.Name = strName
    mcolPlanets.Add PlanetNew, strName
    Set Add = PlanetNew
End Function

Public Sub Delete(strName As String)
    mcolPlanets.Remove strName
End Sub

Public Function Count() As Long
    Count = mcolPlanets.Count
End Function

Public Function Item(strName As String) As Planet
    Set Item = mcolPlanets.Item(strName)
End Function

Public Function NewEnum() As IUnknown
    Set NewEnum = mcolPlanets.[_NewEnum]
End Function
When I first started

把每一個物件和其物件集合放在同一個物件類別模組裡，程式雖然也能運作，但卻隱藏著一些問題，這些問題和陷阱可以藉由將二者分開而避免。因此，在這個範例中，我們分別定義了Planet和Planets物件類別，同樣地，你會在後面看見我們也以同樣的方式定義Moon物件類別和Moons物件類別。

在本例中，Planets集合物件將Planet物件封裝在其中，並負責掌管每一個Planet物件。真正Collection物件mcolPlanets被定義為Private變數，以防止外界程式任意存取其資料，而Add、Delete、Count、Item和NewEnum等物件方法則提供物件的界面，以供外界程式操控Planets物件內含的所有Planet物件。

Add物件方法的功用在於建立集合內新的Planet物件。在本例中，我們把行星的名稱傳給Add物件方法，以便設定該Planet物件的Name屬性，並以這個名稱做為這個Planet物件在物件集合中的鍵值。每個物件集合中的元素都必須有一個獨一無二的字串鍵值，若要維持這些鍵值的唯一性，最好的辦法就是讓集合物件自動產生並維護它所有的鍵值。在本例中，如果用同樣的名稱去建立不同的物件，你會遇到程式錯誤。你可以在Add方法中加上一些防錯的程式碼，避免這種錯誤。

Count物件方法負責傳回Planets內含的Planet物件數目，而Delete物件方法則負責將指定的Planet物件從Planets中移除，當然，你可以自己加入防錯的動作，以避免刪除不存在的Planet物件。 Item物件方法負責將某個指定的Planet物件傳回給原呼叫程式。說到這裡，我們要特別提出一點來多作討論。如果把Item程序設定為Planets的預設屬性，那麼，在取得某個指定物件時，程式的語法會更自然。舉例而言，你可以用starObject.Planets.Item("Earth") 來取得Earth這個物件，但如果Item是預設屬性，語法就簡單多了：

注意：

如果要把某個程序設定為預設屬性，首先從「工具」功能表中選取「程序屬性」，在「名稱」下拉式清單中選取你想要的程序，點選「進階」按鈕，然後從「程序識別碼」中選取 ( 預設值 )。在每一個物件類別中只能有一個程序可以設定為預設程序。

此外，在這裡我們要告訴你另一個在Planets物件類別中的重要技巧。這個技巧讓你可以在外部程式中用For Each迴圈的方式存取集合物件內的每一個物件。這部分不太容易懂，請仔細地往下看。第一步，先在你的類別中加入一個特別的NewEnum IUnknown程序。在NewEnum函式中，我們使用了Collection物件的隱藏列舉集合屬性。因此，程式中的方括號和底線符號是規定的語法，一定要這樣寫。第二步，將NewEnum函式隱藏後啟用。請看以下的注意事項：

注意：

如果要把物件類別中的特殊函式NewEnum加以隱藏後啟用，首先，點選「工具」功能表中的「程序屬性」，在「名稱」中選取NewEnum程序，再點選「進階」按鈕。在「特性」中選取「隱藏此成員」，然後在「程序識別碼」中填入 -4。這樣就可以讓集合物件以For Each迴圈來存取了。

Planet物件類別
　

現在加入另一個物件類別模組，加入以下的程式，把它的Name屬性設定為Planet，存檔為PLANET.CLS。這個物件類別定義了在Planets中的Planet物件。

Option Explicit

Public Name As String
Public Diameter As Long
Public Mass As Single

Private mMoons As New Moons

Public Property Get Moons() As Moons
    Set Moons = mMoons
End Property
Each Planet

每一個Planet物件都有幾個簡單的屬性 (Name、Diameter和Mass) 以及一個Moons集合物件，Moons裡面則包含著零個以上的Moon物件。

再提醒你一次，Moons物件集合被宣告為Private是為了防止外界程式任意地直接存取Moons物件，Planet物件提供了唯讀的Property Get Moons程序讓你取得有關Moons的資訊。

Moons物件類別
　

Moons物件是一個集合物件，它的結構很像Planets集合物件。現在在SolarSys專案中加入另一個物件類別模組，將它的Name屬性設為Moons，加入以下的程式碼，取後存成MOONS.CLS。

Option Explicit

Private mcolMoons As New Collection

Public Function Add(strName As String) As Moon
    Dim MoonNew As New Moon
    MoonNew.Name = strName
    mcolMoons.Add MoonNew, strName
    Set Add = MoonNew
End Function

Public Sub Delete(strName As String)
    mcolMoons.Remove strName
End Sub

Public Function Count() As Long
    Count = mcolMoons.Count
End Function

Public Function Item(strName As String) As Moon
    Set Item = mcolMoons.Item(strName)
End Function

Public Function NewEnum() As IUnknown
    Set NewEnum = mcolMoons.[_NewEnum]
End Function

Moon物件類別
　

這是個最簡單的物件類別模組，每一個Moon物件都包含Name、Diameter和Mass屬性。請在專案中加入一個新的物件類別模組，將它的Name屬性設為Moon，加入以下的程式碼後存檔為MOON.CLS。

Option Explicit

Public Name As String
Public Diameter As Long
Public Mass As Single

巢狀式Collection組織的運作方式
　

讓我們回頭看看SolarSys表單中的程式。當表單中的cmdBuildSolarSystem被按下時，系統中就產生了一個叫做starObject的Star物件。我們不用去設定Star的Name屬性，以區分所有的Star物件，因為我們只有一個Star物件。（如果我們要發展一個將星系予以分類的程式，就需要產生好幾個Star物件，而每個Star物件都要設定不同的Name屬性值。）

為了簡化程式、方便說明起見，我們只加了四個行星（Planet物件）和幾個衛星（Moon物件），如果你有興趣的話，你可以建造出整個完整的太陽系。以下這段程式產生一個叫做Mecury的Planet物件。Mercury並沒有任何衛星，因為我們並未替它加入任何Moon物件。

'Add planets and moons to the solar system
With starObject.Planets
     'Create first planet
     Set planetObject = .Add("Mercury")
     'Set some of its properties
     With planetObject
          .Diameter = 4880
          .Mass = 3.3E+23
End With

在程式中，我們會引用到好幾個層次的物件，因此，我們使用With指令來簡化存取物件屬和方法的陳述式，事實上，我們仍然可以用完整表達的陳述式來存取Mercury物件的Diameter屬性，如下例：

starObject.Planets("Mercury").Diameter = 4880

用一句話來解釋這個陳述式：把4800指定給Star物件裡的Planets物件裡的Mercury的屬性Diameter。好長的一句話，因此，你應該可以了解使用With有多麼方便了！With指令除了可以讓人易於了解程式之外，它更能減少在系統內部引用物件的步驟，增加了程式的執行速度。

第二段程式重複以上的處理步驟，加入第二個叫"Venus"的Planet物件。Venus也沒有Moon物件。我們先跳到第三個Star物件Earth，Earth有一個Moon物件，以下是把Moon物件加入的程式：

'Create third planet
Set planetObject = .Add("Earth")
'Set some of its properties
With planetObject
    .Diameter = 12756
    .Mass = 5.9736E+24
    'Add moons to this planet
    With .Moons
        'Create Earth's moon
        Set moonObject = .Add("Luna")
        'Set some of its properties
        With moonObject
            .Diameter = 3476
            .Mass = 7.35E+22
        End With
    End With
End With
Once again,

這裡請你注意我們是如何在巢狀式的Collection組織裡，引用特定的Planet的物件和Moon物件。

一旦這個簡化的太陽系建造完成之後，下一步我們就可以用以下這幾行程式顯示出所有在這個太陽系中的星體名稱了。

'Display the results
Print "Planet", "Moon", "Diameter (km)", "Mass (kg)"
Print String(100, "-")
For Each planetObject In starObject.Planets
    With planetObject
        Print .Name, , .Diameter, .Mass
    End With
    For Each moonObject In planetObject.Moons
        With moonObject
            Print , .Name, .Diameter, .Mass
        End With
    Next moonObject
Next planetObject

從以上的程式中可以看到，我們用For Each迴圈取得所有Planet物件和Moon物件的各個屬性，程式簡單明瞭。為了和上一段程式作比較，我們在以下這段程式中以完整的物件表示法取得特定的物件屬性：

'Directly access some specific properties
Print
Print "The Earth's moon has a diameter of ";
Print starObject.Planets("Earth").Moons("Luna").Diameter;
Print " kilometers."
Print "Mars has";
Print starObject.Planets("Mars").Moons.Count;
Print " moons."

圖5-8顯示了程式執行的結果。

以上這個建構物件的方式提供了一個堅固的觀念基礎，由此一觀念延伸，你可以建構出複雜但有脈絡可循的物件結構，也足以應付各種程式設計的需求。

如何使用同名異式？
　

OOP的世界充滿了新的名詞和觀念，現在讓我們來討論同名異式 (Polymorphism）──它的意義是什麼？它能帶給你什麼樣的助益？

簡單的說，當多個不同的物件類別提供完全相同的界面元素（Interface Element）時，我們便稱之為"同名異式"，而所謂的界面元素即是指可供用戶端程式使用的屬性和方法。

譬如說，你定義了幾個不同物件類別，每一個由這些物件類別所產生的物件都提供了一組"標準的"（相同的）檔案管理函式，這時你便可以應用同名異式的觀念到你專案裡。在每個不同物件類別裡，把和這些檔案管理函式相關的屬性和物件方法都取統一的名稱，如FileName, Read和Write，這樣就是應用了同名異式的特性。同名異式可以簡化、標準化以及協調這些物件，使物件更加地一致而且可以預測。

Visual Basic處理同名異式的方式與C++ 有些許不同。在OOP語言的發展歷程中，一個新物件可以"繼承"（Inherit）另一個既存物件的屬性和物件方法，也就是界面元素，新舊物件因而都擁有了相同的界面，而達成所謂的同名異式；在新物件裡，我們可以把界面元素原來的內容原封不動地提供給應用程式，也可以賦予這些界面元素新的行為及內涵，但重點是這些界面元素的"外觀"（屬性名稱和函式原型）不能改變。

在另一方面，Visual Basic則透過抽象物件類別（Abstract Class）來實踐同名異式的觀念，而不靠傳統OOP的繼承特性。所謂的抽象物件類別事實上是一些"空殼"的物件類別模組，它們只有屬性名稱和物件方法的原型，完全沒有內容定義。新的物件類別必須透過Implement關鍵字來告訴系統它要使用抽象物件類別的界面元素，但它可以定義專屬於自己的界面元素內涵。

我們可以把抽象物件類別想像成某種的"契約"，不同的物件類別模組透過Implement來表示大家都願意遵循這個"契約"（使用外觀相同的界面元素）。如果在一個應用程式中，我們用以上"願意遵守契約"的物件類別產生了許多不同的物件（包括由抽象物件類別直接宣告所產生的物件），那麼，當我們對其中一個物件存取其透過Implement得來的某個界面時，（雖然每一個物件的界面元素完全相同） 系統會根據被使用的物件是什麼而自動找出專屬於這個物件的界面元素定義，得到正確執行的結果。

如果你想完全精通這些觀念，最好的方法就是實作。另外，「線上手冊」提供了兩個讓你了解同名異式的好例子－ Tyrannosaur和Flea，這兩種物件彼此都同意Implement一個Bite方法。研究過這些例子之後，你會對Visual Basic的同名異式有更深入的了解。

如何使用Friend物件方法﹖
　

Visual Basic 4首先引進了物件類別模組、物件方法和屬性等新觀念，但是使用者很快就發現了一個小缺點：Visual Basic 4無法把某個的物件中的物件方法提供給另一個物件使用，同時又可以不將這個物件公佈給外界。

現在Visual Basic藉由Friend關鍵字修正了這個缺失。當我們在某個物件方法前加上了Friend關鍵字之後，這個專案裡的其他物件類別模組就可以叫用這個Friend物件方法，但是，外部的應用程式則仍無法叫用這個物件方法。

Friend物件方法，讓專案裡相關的物件得以相互溝通，而且這些物件方法不會被加入到ActiveX元件的程式庫裡，因此，這些作為物件間溝通管道的物件方法，無法讓用戶端應用程式叫用。